[RESOLVED] IE Proxy/IP Change

Alright I know that this question is asked all too often on vbForums but I am running into this problem and none of the posts have been clearly answered, a majority of them just redirect to some deprecated VB6 code that cannot be transferred easily to VB.Net. I was wondering if anyone would be able to help me find the code to refresh my Local Area Network settings on a windows seven computer.

I have code that will set all of the registry values that I need. (I have read on other posts that this is not the best way but then they just link to old non-.Net code that will not fit into my project.) I was wondering what exactly the 'Ok' button when you exit the LAN Settings window does, because this part is what actually refreshes the Ip of the computer to use proxy settings set by the registry values, I was hoping to have my program only be one button, that would do all of this without it opening the LAN Dialogue (requiring further human interaction.)

I would post my current code but the code works perfectly as I have already said (well in editing the registry) and as such I don't find a need to post the source, but if someone asks for it I would give it to them, I just don't like showing an unfinished product that needs some key feature fixed, I mean that is part of the whole 'debugging' method but due to the fact that I don't plan on editing the current code other than tacking on the refresh-code I never saw the need. (run on sentence for the win)

Hoping for help soon
~HunterWould

Don't edit the registry directly to change the proxy. That's (imho) a very bad thing.

Pass the full proxy including port as a parameter: 111.111.111.111:2222

I'm not taking credit for this code, I only added the code to disable the proxy. All credits go to the original author.

vb.net Code:

Imports System
Imports System.Runtime.InteropServices
 
Public Class IEProxy
    Public Enum Options
        INTERNET_PER_CONN_FLAGS = 1
        INTERNET_PER_CONN_PROXY_SERVER = 2
        INTERNET_PER_CONN_PROXY_BYPASS = 3
        INTERNET_PER_CONN_AUTOCONFIG_URL = 4
        INTERNET_PER_CONN_AUTODISCOVERY_FLAGS = 5
        INTERNET_OPTION_REFRESH = 37
        INTERNET_OPTION_PER_CONNECTION_OPTION = 75
        INTERNET_OPTION_SETTINGS_CHANGED = 39
        PROXY_TYPE_PROXY = &H2
        PROXY_TYPE_DIRECT = &H1
    End Enum
 
    <StructLayout(LayoutKind.Sequential)> _
    Private Class FILETIME
        Public dwLowDateTime As Integer
        Public dwHighDateTime As Integer
    End Class
 
    <StructLayout(LayoutKind.Explicit, Size:=12)> _
    Private Structure INTERNET_PER_CONN_OPTION
        <FieldOffset(0)> Dim dwOption As Integer
        <FieldOffset(4)> Dim dwValue As Integer
        <FieldOffset(4)> Dim pszValue As IntPtr
        <FieldOffset(4)> Dim ftValue As IntPtr
 
        Public Function GetBytes() As Byte()
            Dim b(12) As Byte
            BitConverter.GetBytes(dwOption).CopyTo(b, 0)
            Select Case dwOption
                Case Options.INTERNET_PER_CONN_FLAGS
                    BitConverter.GetBytes(dwValue).CopyTo(b, 4)
                Case Options.INTERNET_PER_CONN_PROXY_BYPASS
                    BitConverter.GetBytes(pszValue.ToInt32()).CopyTo(b, 4)
                Case Options.INTERNET_PER_CONN_PROXY_SERVER
                    BitConverter.GetBytes(pszValue.ToInt32()).CopyTo(b, 4)
            End Select
            Return b
        End Function
    End Structure
 
    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)> _
    Private Class INTERNET_PER_CONN_OPTION_LIST
        Public dwSize As Integer
        Public pszConnection As String
        Public dwOptionCount As Integer
        Public dwOptionError As Integer
        Public pOptions As IntPtr
    End Class
 
    <StructLayout(LayoutKind.Sequential)> _
    Private Class INTERNET_PROXY_INFO
        Public dwAccessType As Integer
        Public lpszProxy As IntPtr
        Public lpszProxyBypass As IntPtr
    End Class
 
    Private Const ERROR_INSUFFICIENT_BUFFER = 122
    Private Const INTERNET_OPTION_PROXY = 38
    Private Const INTERNET_OPEN_TYPE_DIRECT = 1
 
    <DllImport("wininet.dll")> _
    Private Shared Function InternetSetOption(ByVal hInternet As IntPtr, _
             ByVal dwOption As Integer, _
             ByVal lpBuffer As INTERNET_PER_CONN_OPTION_LIST, _
             ByVal dwBufferLength As Integer) As Boolean
    End Function
 
    <DllImport("kernel32.dll")> _
    Private Shared Function GetLastError() As Integer
    End Function
 
    Public Function SetProxy(ByVal proxy_full_addr As String) As Boolean
        Dim bReturn As Boolean
        Dim list As New INTERNET_PER_CONN_OPTION_LIST
        Dim dwBufSize As Integer = Marshal.SizeOf(list)
        Dim opts(3) As INTERNET_PER_CONN_OPTION
        Dim opt_size As Integer = Marshal.SizeOf(opts(0))
 
        list.dwSize = dwBufSize
        list.pszConnection = ControlChars.NullChar
        list.dwOptionCount = 3
 
        'set flags
        opts(0).dwOption = Options.INTERNET_PER_CONN_FLAGS
        opts(0).dwValue = Options.PROXY_TYPE_DIRECT Or Options.PROXY_TYPE_PROXY
 
        'set proxyname
        opts(1).dwOption = Options.INTERNET_PER_CONN_PROXY_SERVER
        opts(1).pszValue = Marshal.StringToHGlobalAnsi(proxy_full_addr)
 
        'set override
        opts(2).dwOption = Options.INTERNET_PER_CONN_PROXY_BYPASS
        opts(2).pszValue = Marshal.StringToHGlobalAnsi("local")
 
        Dim b(3 * opt_size) As Byte
        opts(0).GetBytes().CopyTo(b, 0)
        opts(1).GetBytes().CopyTo(b, opt_size)
        opts(2).GetBytes().CopyTo(b, 2 * opt_size)
 
        Dim ptr As IntPtr = Marshal.AllocCoTaskMem(3 * opt_size)
        Marshal.Copy(b, 0, ptr, 3 * opt_size)
 
        list.pOptions = ptr
        'Set the options on the connection
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_PER_CONNECTION_OPTION, list, dwBufSize)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        'Notify existing Internet Explorer instances that the settings have changed
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_SETTINGS_CHANGED, Nothing, 0)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        'Flush the current IE proxy setting
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_REFRESH, Nothing, 0)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        Marshal.FreeHGlobal(opts(1).pszValue)
        Marshal.FreeHGlobal(opts(2).pszValue)
        Marshal.FreeCoTaskMem(ptr)
        Return bReturn
    End Function
 
    Public Function DisableProxy() As Boolean
        Dim bReturn As Boolean
        Dim list As New INTERNET_PER_CONN_OPTION_LIST
        Dim dwBufSize As Integer = Marshal.SizeOf(list)
        Dim opts(0) As INTERNET_PER_CONN_OPTION
        Dim opt_size As Integer = Marshal.SizeOf(opts(0))
 
        list.dwSize = dwBufSize
        list.pszConnection = ControlChars.NullChar
        list.dwOptionCount = 1
 
        opts(0).dwOption = Options.INTERNET_PER_CONN_FLAGS
        opts(0).dwValue = Options.PROXY_TYPE_DIRECT
 
        Dim b(opt_size) As Byte
        opts(0).GetBytes().CopyTo(b, 0)
 
        Dim ptr As IntPtr = Marshal.AllocCoTaskMem(opt_size)
        Marshal.Copy(b, 0, ptr, opt_size)
 
        list.pOptions = ptr
        'Set the options on the connection
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_PER_CONNECTION_OPTION, list, dwBufSize)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        'Notify existing Internet Explorer instances that the settings have changed
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_SETTINGS_CHANGED, Nothing, 0)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        'Flush the current IE proxy setting
        bReturn = InternetSetOption(IntPtr.Zero, Options.INTERNET_OPTION_REFRESH, Nothing, 0)
        If Not bReturn Then
            Debug.WriteLine(GetLastError)
        End If
 
        Marshal.FreeCoTaskMem(ptr)
        Return bReturn
    End Function
End Class

There is one problem with that though, I have no idea on how to implement that code. I am new to this language still. Could you help me?

Go to Project -> Add Class and add a Class.

Change the name of the Class to IEProxy.vb and remove the small piece of the code that is already in there. Then copy and paste the code from above in there.

Add two buttons to your form and paste the code below. Obviously 123.123.123.123:8080 needs to be a valid proxy.

vb.net Code:

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim clsProxy As New IEProxy
        If clsProxy.SetProxy("123.123.123.123:8080") Then
            MessageBox.Show("Proxy successfully enabled.", "Success", MessageBoxButtons.OK, MessageBoxIcon.Information)
        Else
            MessageBox.Show("Error enabling proxy.", "Failed", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
        End If
    End Sub
 
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim clsProxy As New IEProxy
        If clsProxy.DisableProxy Then
            MessageBox.Show("Proxy successfully disabled.", "Success", MessageBoxButtons.OK, MessageBoxIcon.Information)
        Else
            MessageBox.Show("Error disabling proxy.", "Failed", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
        End If
    End Sub

You my friend, deserve a cookie.

Chris, would it be possible to set an IP specific to a webbrowser? For example, use IP #1 with 1 webbrowser, and IP #2 with another webbrowser at the same time?

get outta my thread G-man, nah I'm just kidding but yes you can totally do that I have seen programs that can do it, heck I have one right now that can. (not made by me of course)

Well yeah, I know it's possible. The question was meant as a question of how to do it, not meant to ask if it can be done. Chris knows what I mean.

Sorry, I can't help you with that. I have no idea how to set a proxy for just one instance of Internet Explorer.

Alright, well thanks anyways Chris. Good job on finding this one.

Sorry for bumping an old(ish) thread.
I have been using this code example for a while and it works great.
However i would like to use it with a private proxy that requires authentication (username & pass)

Any idea how use this code with a private proxy, so the username and pass are set and stored when the proxy is set?