[RESOLVED] Uninitialized Arrays

Awhile ago I came across a neat trick to detect uninitialized arrays, e.g.

Code:

---

Dim foo() as string
If XXX = -1 Then Debug.Print "Array is uninitialized."

---

I can't remember what XXX is, I apparently didn't make a note of it in my Google Notebook of VBA tricks, and I can't remember which of the countless Excel apps I used this trick in.

It was really short, neat but unintuitive. I remember that whatever the test was, the value was supposed to be -1. I could always error trap a UBound call, but I'd like to know what the trick was.

Does anyone know?

Thanks!
Pete

This is one way to check... the API way...

Code:

---

Private Declare Function SafeArrayGetDim Lib "oleaut32.dll" _
(ByRef saArray() As Any) As Long

Sub Sample()
    Dim foo() As String
    If SafeArrayGetDim(foo) = 0 Then MsgBox "Array is uninitialized."
End Sub

---

Or maybe with the help of a helper function like this:

vb Code:

Sub Sample()
    Dim foo() As String
    If GetUbound(foo) = -1 Then Debug.Print "Array is uninitialized."
End Sub
 
Function GetUbound(arr) As Integer
    On Error Resume Next
    GetUbound = -1
    GetUbound = UBound(arr)
End Function

Awesome trick! That's going right into my Google notebook! :bigyello:

Quote:

---

Originally Posted by Pradeep1210

Or maybe with the help of a helper function like this:

vb Code:

Sub Sample()
    Dim foo() As String
    If GetUbound(foo) = -1 Then Debug.Print "Array is uninitialized."
End Sub
 
Function GetUbound(arr) As Integer
    On Error Resume Next
    GetUbound = -1
    GetUbound = UBound(arr)
End Function

---

The above trick has a flaw: Although not many people use it but it is legal for an array to have both Lbound() and Ubound() negative.

You can declare or redim like this:

Code:

---

Dim foo(-5 to -1) as String

---

or

Code:

---

Dim foo() as String
'...
Redim foo(-5 to -1)

---

In these cases, GetUbound(foo) will return -1 even foo has been initialized.

Instead of GetUbound(), perhaps this is better:

Code:

---

Function IsArrayInit(arr) as Boolean
    Dim n as Integer
    On Error Resume Next
    n = Ubound(arr)
    IsArrayInit = (Err = 0)
End Function

---

The XXX in the original question is:

Code:

---

If Not Not foo = -1 Then

---

However, people said this method may cause some problem in VB6-IDE and Debug.Assert need to be used to fix.