Snapping windows to the screen and to other windows

Hey there,

Here is a simple example on how to make windows snap both to the edges of any screen and to other windows. I think this is a feature that is quite common for some types of applications. The idea is that the user moves the window close enough to the edge of the screen or some other window, and the window will snap into place exactly besides the screen or other window.

Note that this is just a simple example. You may want to add more functionality (or I may do it if I get some more time), such as:

Store which side the window is snapped to,
Also match the height or width of the snapped window,
(Difficult) Add something to avoid the small amount of flickering

For now, this example will probably be a good base for whatever you need.

First, let me explain the idea.

Snapping to the screen(s)
If the user moves the window, we constantly check the position in relation to the bounds of all the screens. We can get the bounds of these screens by iterating through the Screen.AllScreens property and using the WorkingArea property of each Screen object.
vb.net Code:
For Each screen As Screen In screen.AllScreens
            Dim rect As Rectangle = screen.WorkingArea
 
        Next
We have to decide whether the window is 'in range' to snap, and when it is, we actually snap it. This sounds harder than it actually is, so here is a graphical representation of the code:
http://i46.tinypic.com/jhdnx3.jpg
I have depicted the top of a screen with a window hovering slightly beneath it. Two dotted lines denote the 'snapping region', defined by a constant SNAP_SIZE parameter (in my code that is 25 pixels).

Note that, in .NET, the y-axis points downward, so the y-coordinate of the top dotted line (above the screen) is Screen.Top - SNAP_SIZE. In the same way, the y-coordinate of the bottom dotted line is Screen.Top + SNAP_SIZE.

If the window's y-coordinate is between these two values, it will be snapped to the top of the screen.

But what does that mean exactly? When is the window between the two values? Well, take a look at the picture. The y-coordinate of the window (Form.Top property) should be below (= greater than!) the top dotted line, and above (= less than!) the bottom dotted line.

If that is the case, we simply set the Form.Top property to the Top of the screen (snapping!).

In code, that looks like this:
vb.net Code:
If Me.Top <= rect.Top + SNAP_SIZE AndAlso Me.Top > rect.Top - SNAP_SIZE Then
                Me.Top = rect.Top
            End If
Of course, the same goes for the other sides, with suitably modified code. If you apply this logic to all sides, the final code is:
vb.net Code:
Private Sub StickyWindow_Move(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Move
        For Each screen As Screen In screen.AllScreens
            Dim rect As Rectangle = screen.WorkingArea
 
            If Me.Left <= rect.Left + SNAP_SIZE AndAlso Me.Left > rect.Left - SNAP_SIZE Then
                Me.Left = rect.Left
            ElseIf Me.Right >= rect.Right - SNAP_SIZE AndAlso Me.Right < rect.Right + SNAP_SIZE Then
                Me.Left = rect.Right - Me.Width
            End If
 
            If Me.Top <= rect.Top + SNAP_SIZE AndAlso Me.Top > rect.Top - SNAP_SIZE Then
                Me.Top = rect.Top
            ElseIf Me.Bottom >= rect.Bottom - SNAP_SIZE AndAlso Me.Bottom < rect.Bottom + SNAP_SIZE Then
                Me.Top = rect.Bottom - Me.Height
            End If
        Next
    End Sub
Snapping to other windows
If you also want your windows to snap to other windows, you'll have to add another check in the same Move method. If you have just one window you want to snap to, you don't need another loop, but you just use the bounds of that window.

In my example however, I decided that I wanted all of the StickyWindows to be able to stick to each other. For that to work, obviously, I needed to keep a list of all StickyWindows that have been created. Since each StickyWindow needs to use this list, it needs to be in a common place, accessible from anywhere. I decided to create a class called Common, with a Shared 'StickyWindows' property, of type List(Of StickyWindow). When a StickyWindow is created, I add it to the list, and once it is closed, I remove it again.

Now, on to the actual snapping. Previously, we needed to snap to the inside of another rectangle (the screen's bounds). Now, we want to snap to the outside of each sticky window. It's only a slight difference, but an important one to keep in mind. I won't derive how I got the 'equations' in detail again, so here is the code:
vb.net Code:
For Each f As StickyWindow In Common.StickyWindows
            If Me IsNot f Then
                Dim rect = f.Bounds
 
                ' If the windows are exactly on top of each other, an infinite loop will occur 
                ' (one form moving the other, moving the other, moving the other, etc),
                ' so we'll ignore that case, since there is no docking to be done anyway.
                If Me.Bounds = rect Then Exit For
 
 
                If Me.Right <= rect.Left + SNAP_SIZE AndAlso Me.Right > rect.Left - SNAP_SIZE Then
                    Me.Left = rect.Left - Me.Width
                ElseIf Me.Left >= rect.Right - SNAP_SIZE AndAlso Me.Left < rect.Right + SNAP_SIZE Then
                    Me.Left = rect.Right
                End If
 
                If Me.Bottom <= rect.Top + SNAP_SIZE AndAlso Me.Bottom > rect.Top - SNAP_SIZE Then
                    Me.Top = rect.Top - Me.Height
                ElseIf Me.Top >= rect.Bottom - SNAP_SIZE AndAlso Me.Top < rect.Bottom + SNAP_SIZE Then
                    Me.Top = rect.Bottom
                End If
            End If
        Next
There are two notes to be made:

We don't want to dock to ourselves, so we add a check for that (line 2),
We don't want to snap if the forms coincide exactly. That would result in form 1 snapping to form 2, which in turn snaps to form 1, which snaps to form 2, etc...

Well, that's it. I've attached a sample project that includes the code here. Use it however you like :)