[RESOLVED] Split Text File

Hi I have a text file which is about 700MB it is very difficult to open this file
but there are 5800 Chapters in the file every chapter is starting from "$$NEW$$" For example

Code:

---

"$$NEW$$"
Some Text
"$$NEW$$"
Some Text
"$$NEW$$"
Some Text
"$$NEW$$"
Some Text

---

I want to split the text file after every chapter ends any idea ?

try this:

vb Code:

Dim contents As String = IO.File.ReadAllText(filename)
Dim chapters() As String = contents.Split(New String() {"""$$NEW$$"""}, StringSplitOptions.RemoveEmptyEntries)
For Each c In chapters
    MsgBox(c.Trim)
Next

Using IO.File.ReadAllText with a 700MB file is not recommended. Instead, you use a streamreader and create a new output file every time you read a line that has "$$NEW$$" in it. Something like this:

vb.net Code:

Dim input As String = "full path to your input text file here"
        Using reader As New System.IO.StreamReader(input)
            Dim line As String = String.Empty
            Dim chapter As Integer = 1
            Dim outfile As String = String.Empty
            Dim sb As New System.Text.StringBuilder()
            While reader.Peek >= 0
                line = reader.ReadLine()
                If line.Contains("""$$NEW$$""") Then
                    If sb.Length > 0 Then
                        outfile = System.IO.Path.GetDirectoryName(input) & "\Chapter_" & chapter.ToString & ".txt"
                        System.IO.File.WriteAllText(outfile, sb.ToString)
                        chapter += 1
                        sb.Length = 0
                    End If
                End If
                sb.AppendLine(line)
            End While
            outfile = System.IO.Path.GetDirectoryName(input) & "\Chapter_" & chapter.ToString & ".txt"
            System.IO.File.WriteAllText(outfile, sb.ToString)
        End Using

Thank you very much guys

Code:

---

stanav

---

you get out me from a very big trouble Thanks