[RESOLVED] Passing an Array to Custom Messagebox

How do one pass an array to and from a custom messagebox/inputbox?

I'm trying to create a custom messagebox/inputbox where I can enter values into certain fields and then return those values as an array.

However...

The custom messagebox/inputbox must also return a string or integer so I can know whether Ok or Cancel has been selected.

So my thinking was;

1. Create the array in my form.
2. Pass that array to the custom messagebox/inputbox form by reference so that changing values in the array will be reflected in the original form after the custom messagebox/inputbox form are closed.
3. Enter the values into the array in the messagebox/inputbox form.
4. Return the button clicked as the return value of the custom messagebox/inputbox when the box is closed.

Is this possible? How do I declare/pass the array from one form to another and back again?

Quote:

---

Originally Posted by Bezzie

How do one pass an array to and from a custom messagebox/inputbox?

---

Not sure what you mean by "custom"... Do you already have some custom form?
If you don't then for what you want you'll need to design your own form that would act like Message and/or Input box.
If you have troubles designing your own forms search forum - there are many samples already posted.

Busy designing the form. I have done custom messageboxes before and know how to get one return value from the messagebox for the button clicked.

How do I pass an array to this custom form so that I can modify the values of the array and then return that array as well so the new values is available in the form that called the custom messagebox.

You can simply declare your array in the module so multiple forms can share it.

This is a very simplified proof of concept.

I'm assuming when you are talking about a custom messagebox you are talking about a form acting as a custom messagebox.

Assuming that is correct my form2 in my sample would be your custom messagebox and my form1 would be the calling form.

In form2 (acting as custom messagebox) I have the following code:

VB Code:

Private pMyArrayData() As String
 
Public Property Let MyArrayData(value() As String)
    pMyArrayData = value
End Property
 
Public Function ShowForm() As String()
    Me.Show vbModal
    ShowForm = pMyArrayData
End Function
 
Private Sub uiChangeArrayData_Click()
    ReDim pMyArrayData(10)
    Unload Me
End Sub

uiChangeArrayData is the name of a command button on Form2.

The puplic property will allow you to assign the array to modify from anywhere outside form2.

The reason I would do that rather than passing anything by reference is my personal preference and serves as one example of achieving what you intended to do.
This does not mean off course that you can't do it passing anything ByRef.

The code on Form1 which will show Form2 is as follows:

VB Code:

Private Sub uiShowCustomMessageBox_Click()
    Dim mySourceArray() As String
    ReDim mySourceArray(100)
    
    MsgBox UBound(mySourceArray)
 
    Load Form2
    
    Form2.MyArrayData = mySourceArray
    mySourceArray = Form2.ShowForm()
    
    Set Form2 = Nothing
    
    MsgBox UBound(mySourceArray)
End Sub

uiShowCustomMessageBox is the name of my command button on Form1.

The combined code above will declare an array in Form1 with 100 elements and display that count in a messagebox.

Form1 will then assign that array to the puplic property of Form2 and then call the ShowLoad method of Form2.

Form2 will show itself in vbModal to ensure the code will continue in the ShowForm method ones Form2 is closed by any means.

Form2 then changes the size of the array to demonstrate it has changed it before Form2 then unloaded which will return to Form1.
(I unload Form2 manually in the command button click event simply to demonstrate it can be done, clicking the X on form2 will achieve the same result).

Form1 then will show again the count of elements to show the changes done in Form2 have been applied to the local array in Form1.

I hope this helped in giving you some ideas of your own. This is simply one option of many on how to "pass" an array between forms.

Edit
Just read the post on declaring the array in a module.
Yes, you can do that and it will work.
Personally I always use modular or global declerations as very last choice if at all.
In a module I feel I have less control/oversight over who and what accesses the variable.

By making it part of the "object" though (form2) I feel more in control what is changing my variable.

That is just personal choice though.

I currently have the array declared as a global variable. It works but I'm not too keen on using too many global variables if it can be avoided. Simply because it's all too easy to accidentally change a variable and then try to track down why something that should work, doesn't.

Optional: This is exactly my idea. I'm going to look into your example. At first glance it looks to be what I'm after. The reason why I was thinking to pass the array by reference is that I also need to return a value to indicate what button the user selected e.g. Ok or Cancel. How would one go about to pass the array by reference? Would it be as simple as declaring it

Code:

---

Public Property Let MyArrayData(ByRef value() As String)

---

Or am I not that lucky?

In that case you could just pass the array to ShowForm and remove the puplic property, keep the private variable though for internal use.

Add another private variable for the user choice and make ShowForm of type vbMsgBoxResult.

Change you code in form2 to this:

VB Code:

Private pMyArrayData() As String
Private pUserChoice As VbMsgBoxResult
 
'-- Pass the array by reference and have the method return the result of the user's choice.
Public Function ShowForm(ByRef myArrayData() As String) As VbMsgBoxResult
    pMyArrayData = myArrayData
    
    Me.Show vbModal
    
    myArrayData = pMyArrayData
    
    ShowForm = pUserChoice
End Function
 
'-- First Command Button to simulate change of array data.
Private Sub uiChangeArrayData_Click()
    ReDim pMyArrayData(10)
End Sub
 
'-- Second Command button to deomnstrate User Choice being set.
Private Sub uiSetUserChoice_Click()
    pUserChoice = vbOK
End Sub
 
'-- Will unload the messagebox, naturally that would actually
'-- happen upon the user's choice but this is simply to demonstrate.
Private Sub uiCloseMessageBox_Click()
    Unload Me
End Sub

Again, the above is merely a demonstration of one of many options you have available. don't forget to think about validations, as in what should the default return value be. Use your Form_initialize to pre-load your defaults, etc....

Your Form1 would change to something like this:

VB Code:

Private Sub uiShowCustomMessageBox_Click()
    Dim mySourceArray() As String
    Dim userChoice As VbMsgBoxResult
    
    ReDim mySourceArray(100)
 
    MsgBox UBound(mySourceArray)
 
    Load Form2
 
     userChoice = Form2.ShowForm(mySourceArray)
 
    '-- If you do not set Form2 to nothing some events like Form_initialize will
    '-- not trigger next time you load Form2 as VB will keep
    '-- the code page of a form object alive in memory until you do so, even
    '-- if you have unloaded the form2 object.
    '-- Remember that.
    Set Form2 = Nothing
    
    MsgBox userChoice
    MsgBox UBound(mySourceArray)
End Sub

As you can see, the above would let you pass the array by reference and still receive the user's choice of the vbMsgBoxResult.
Again, this is simply one option and there might be many more ways to achieve the same.

Hope this helps though.

I'm going to look into this as soon as I get a chance. Thanks in advance Optional.