Get the program that will open a file

I want to find the full path of the program that will open a given file type. e.g. '.txt' is opened by c:\windows\system32\notepad.exe

I've done a bit of searching but i keep just finding how to create an association, not read one. I've also tried looking in the registery, but it looks like all that's there is a link to the program ID or something.

Try this:

vb.net Code:

Private Sub CheckExtensions()
    Dim extensions As String() = {".txt", ".dwg", ".doc", ".sln", ".gif", ".fake"}
    Dim exePath As String = String.Empty
    For Each extension In extensions
        Select Case Me.GetExecutablePath(extension, exePath)
            Case ExecutablePathResults.ExtensionNotFound
                MessageBox.Show("The named extension does not exist or a file association does not exist.", extension)
 
            Case ExecutablePathResults.Success
                MessageBox.Show(exePath, extension)
 
            Case ExecutablePathResults.UnexpectedKeyStructure
                MessageBox.Show("The expected key structure was incorrect.", extension)
 
            Case ExecutablePathResults.ExtensionDoesNotNameAType
                MessageBox.Show("Extension does not name a file classification.", extension)
 
            Case ExecutablePathResults.ExpectedExePathIsBlank
                MessageBox.Show("The expected exe path is blank.", extension)
 
        End Select
    Next
End Sub
 
Public Function GetExecutablePath(ByVal extension As String, ByRef result As String) As ExecutablePathResults
    Dim defaultKey As Microsoft.Win32.RegistryKey = _
                        My.Computer.Registry.ClassesRoot.OpenSubKey(extension, False)
    Dim defaultValue As String = String.Empty
 
    If defaultKey IsNot Nothing Then
        defaultValue = defaultKey.GetValue(String.Empty, String.Empty).ToString()
    Else
        Return ExecutablePathResults.ExtensionNotFound
    End If
 
    If defaultValue <> String.Empty Then
        Dim resultKey As Microsoft.Win32.RegistryKey = My.Computer.Registry.ClassesRoot _
                                        .OpenSubKey(String.Format("{0}\shell\open\command", _
                                                                  defaultValue))
        If resultKey IsNot Nothing Then
            result = resultKey.GetValue(String.Empty, String.Empty).ToString()
            If result = String.Empty Then
                Return ExecutablePathResults.ExpectedExePathIsBlank
            Else
                result = System.Text.RegularExpressions.Regex.Match(result, _
                                        "[A-Za-z]{1}:[^%""]+").Value
            End If
            Return ExecutablePathResults.Success
        Else
            Return ExecutablePathResults.UnexpectedKeyStructure
        End If
    Else
        Return ExecutablePathResults.ExtensionDoesNotNameAType
    End If
 
End Function
 
Public Enum ExecutablePathResults
    Success = 0
    ExtensionNotFound = 1
    UnexpectedKeyStructure = 2
    ExtensionDoesNotNameAType = 3
    ExpectedExePathIsBlank = 4
End Enum

I was trying to get you an answer, but then I disovered the answer that I knew worked wouldn't run on my new 64 bit system, which lead me into a whole flurry of emails to resolve that.

Anyways, there is a FindExecutable API call, which returns this information. It is more or less the same thing as ForumAccount's sample code, because FindExecutable does do a registry lookup for the value.

I was looking at the FindExectuable API and I was going to post it, but I realized it needed a file of the actual type to exist which I thought might not be wanted.

True. It depends on the intent of the code usage.