[RESOLVED] Media Keys for Media Keyboards (I know what to look for, but not how)

I would like to implement Media Keyboard support in my application.
Unfortunately i cannot find out what exactly i'm looking for.

I need to know how to check for, and react to the Media Key being pressed, "Play" for example.
I also, do not know what this key is called, therefore even if i could check for it, i couldn't :(

The keys i mean are on the Media Keyboards, and use a standard set of commands.
Keyboard such as the top of this one: http://solbu.com/E-Commerce/zencart/...920-000042.jpg

EDIT: For example as used in Winamp Media Player along with numerous others.
EDIT2: Found out how to register hotkeys, or so i think http://www.pinvoke.net/default.aspx/...terHotKey.html But no listing, and still no way of implementing Play, Pause, Stop Next, etc. etc..

Could be this actually: http://msdn.microsoft.com/en-us/library/ms646275.aspx

WM_APPCOMMAND's

Ok, now i found it, i have no idea how to implement it...

Ok, now i have found a working example of disabling or capturing windows keys.

vb Code:

Option Strict On
Imports System.Runtime.InteropServices
 
Public Class Form1
 
    Private Const KEYEVENTF_EXTENDEDKEY As Long = &H1
    Private Const KEYEVENTF_KEYUP As Long = &H2
    Private Const VK_LWIN As Byte = &H5B
    Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, _
    ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
 
    Private Const WH_KEYBOARD_LL As Integer = 13
    Private Const WM_KEYUP As Integer = &H101
    Private Shared _proc As LowLevelKeyboardProc = AddressOf HookCallback
    Private Shared _hookID As IntPtr = IntPtr.Zero
 
    Public Declare Auto Function SetWindowsHookEx Lib "user32.dll" ( _
        ByVal idHook As Integer, ByVal lpfn As LowLevelKeyboardProc, _
        ByVal hMod As IntPtr, ByVal dwThreadId As UInteger) As IntPtr
 
    Public Declare Auto Function UnhookWindowsHookEx _
    Lib "user32.dll" (ByVal hhk As IntPtr) As IntPtr
 
    Public Declare Auto Function CallNextHookEx _
    Lib "user32.dll" (ByVal hhk As IntPtr, ByVal nCode As Integer, _
                      ByVal wParam As IntPtr, ByVal lParam As IntPtr) As IntPtr
 
    Public Declare Auto Function GetModuleHandle Lib "kernel32.dll" ( _
    ByVal lpModuleName As String) As IntPtr
 
 
    Private Shared Function SetHook( _
        ByVal proc As LowLevelKeyboardProc) As IntPtr
 
        Dim curProcess As Process = Process.GetCurrentProcess()
        Dim curModule As ProcessModule = curProcess.MainModule
 
        Return SetWindowsHookEx(WH_KEYBOARD_LL, proc, _
                GetModuleHandle(curModule.ModuleName), 0)
 
    End Function
 
    Public Delegate Function LowLevelKeyboardProc( _
        ByVal nCode As Integer, ByVal wParam As IntPtr, _
        ByVal lParam As IntPtr) As IntPtr
 
    Public Shared Function HookCallback( _
        ByVal nCode As Integer, _
        ByVal wParam As IntPtr, ByVal lParam As IntPtr) As IntPtr
 
        If nCode >= 0 And wParam = CType(WM_KEYUP, IntPtr) Then
            Dim vkCode As Keys = CType(Marshal.ReadInt32(lParam), Keys)
            If vkCode = Keys.LWin Or vkCode = Keys.MediaPlayPause Then
                'keybd_event(CByte(Keys.Zoom), 0, KEYEVENTF_EXTENDEDKEY, 0)
                MsgBox("LOL WINDOWS KEY MON")
            End If
        End If
 
        Return CallNextHookEx(_hookID, nCode, wParam, lParam)
    End Function
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        _hookID = SetHook(_proc)
    End Sub
 
    Private Sub Form1_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
        UnhookWindowsHookEx(_hookID)
    End Sub
 
End Class

As you can see, i modified it to test, and it works!

I'll leave this here for anyone who has problems in the future.
I will learn from this code, but no now, too much Red Bull.

EDIT: What happened to the VBCODE tags?