[RESOLVED] sort columns in listview

Hi Guys,

I'm trying to set something up where the user can sort each column by clicking on the header... i've looked at some other examples and they seem pretty longwinded.. just wondering the best way to do this..

so far i have the below...

VB Code:

Private Sub resultsListView_ColumnClick(ByVal sender As Object, ByVal e As System.Windows.Forms.ColumnClickEventArgs) Handles resultsListView.ColumnClick
        Dim oldsort As SortOrder
        oldsort = resultsListView.Sorting
        If resultsListView.Sorting = SortOrder.Ascending Then
            resultsListView.Sorting = SortOrder.Descending
        ElseIf resultsListView.Sorting = SortOrder.Descending Then
            resultsListView.Sorting = SortOrder.Ascending
        Else : resultsListView.Sorting = SortOrder.Ascending
        End If
        'resultsListView.
        Me.Refresh()
 
    End Sub

which works fine... but only for the first column in the list view.

Is there a way of specifying which column to sort based on which is clicked?

Dan

Did you do any search at all? This is the 2nd result returned from Google when searching for the term "listview sort" (the 1st one is the C# version).
http://msdn.microsoft.com/en-us/kb/kb00319399.aspx

yeah, i read that..

I'm asking because that is over 100 lines of code..

the code I'm currently using is less than 10 and the sort functionality works... ...a bit :p

I'm just trying to work out if i can expand what i currently have without using an extra 100 or so lines of someone elses code!

how many columns do you have?
what types of data do the columns contain?

try this. its a sorter class that sorts integer,string, or date columns:
(this is based on a 3 column listview that has a string in column 0, an integer in column 1, and a date in column 2)

vb Code:

Dim oldsort() As SortOrder = {SortOrder.None, SortOrder.None, SortOrder.None}
 
Private Sub ListView1_ColumnClick(ByVal sender As Object, ByVal e As System.Windows.Forms.ColumnClickEventArgs) Handles ListView1.ColumnClick
    If oldsort(e.Column) = SortOrder.Descending Or oldsort(e.Column) = SortOrder.None Then
        oldsort(e.Column) = SortOrder.Ascending
    Else
        oldsort(e.Column) = SortOrder.Descending
    End If
    Dim sorter As New clsListViewItemComparer(e.Column)
    sorter.isDate = e.Column = 2
    sorter.isInteger = e.Column = 1
    sorter.sortOrder = oldsort(e.Column)
    ListView1.ListViewItemSorter = sorter
    ListView1.Sort()
    ListView1.ListViewItemSorter = Nothing
End Sub

this is the sorter class. you just need to include it in your project + use it as shown above:

vb Code:

Public Class clsListViewItemComparer
    Implements IComparer
 
    Private _Column As Integer
    Private _isInteger As Boolean = False
    Private _isDate As Boolean = False
    Private _sortOrder As SortOrder = Windows.Forms.SortOrder.None
 
    Public Property Column() As Integer
        Get
            Return _Column
        End Get
        Set(ByVal Value As Integer)
            _Column = Value
        End Set
    End Property
 
    Public Property isInteger() As Boolean
        Get
            Return _isInteger
        End Get
        Set(ByVal Value As Boolean)
            _isInteger = Value
        End Set
    End Property
 
    Public Property isDate() As Boolean
        Get
            Return _isDate
        End Get
        Set(ByVal Value As Boolean)
            _isDate = Value
        End Set
    End Property
 
    Public Property sortOrder() As SortOrder
        Get
            Return _sortOrder
        End Get
        Set(ByVal Value As SortOrder)
            _sortOrder = Value
        End Set
    End Property
 
    Public Sub New(ByVal columnIndex As Integer)
        Column = columnIndex
    End Sub
 
    Public Function Compare(ByVal x As Object, ByVal y As Object) As Integer Implements System.Collections.IComparer.Compare
        Dim ListX As ListViewItem = CType(x, ListViewItem)
        Dim ListY As ListViewItem = CType(y, ListViewItem)
 
        If isInteger Then
            ' Convert column text to numbers before comparing.
            ' If the conversion fails, just use the value 0.
            Dim ListXVal, ListYVal As Decimal
            Try
                ListXVal = Integer.Parse(ListX.SubItems(Column).Text)
            Catch
                ListXVal = 0
            End Try
 
            Try
                ListYVal = Integer.Parse(ListY.SubItems(Column).Text)
            Catch
                ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return ListYVal.CompareTo(ListXVal)
            Else
                Return ListXVal.CompareTo(ListYVal)
            End If
 
        ElseIf isDate Then
            Dim ListXVal, ListYVal As Date
            Try
                ListXVal = Date.Parse(ListX.SubItems(Column).Text)
            Catch
                'ListXVal = 0
            End Try
 
            Try
                ListYVal = Date.Parse(ListY.SubItems(Column).Text)
            Catch
                'ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return Date.Compare(ListYVal, ListXVal)
            Else
                Return Date.Compare(ListXVal, ListYVal)
            End If
 
        Else
            ' Keep the column text in its native string format
            ' and perform an alphabetic comparison.
            Dim ListXText As String = ListX.SubItems(Column).Text
            Dim ListYText As String = ListY.SubItems(Column).Text
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return String.Compare(ListYText, ListXText)
            Else
                Return String.Compare(ListXText, ListYText)
            End If
 
        End If
 
    End Function
End Class

Hi Paul,

That looks great! it all works awesomely too!

quick question...

my first column is IP addresses... when i sort it it does this...
10.50.200.1
10.50.200.10
10.50.20.2
10.50.200.20

is this cos im sorting it as a string?

also, it doesnt like my 4th column... when i click it gets column value as 3 but crashes on:

vb Code:

If oldsort(e.Column) = SortOrder.Descending Or oldsort(e.Column) = SortOrder.None Then

that line with "index was outside the bounds of the array"... is this cos its specified as 3 columns as i cant see where ... i would imagine im missing something very obvious!

Dan

D'oh, found how to specify 4 columns. twas obvious. sorry!

just got the slight issue with sorting the IPs now..

thanks so much Paul, that's really simple and effective!

Dan

here it is with ipv4 IP Address sorting: (this is a sorter class that sorts integer, decimal, string, IP Address, or date columns. its based on a listview that has a string in column 0, an integer in column 1, a decimal in column 2, a date in column 3, + an ipv4 IP Address in column 4. to use it add the class to your project + use it as shown in the first code box.)

vb Code:

Dim oldsort() As SortOrder = {SortOrder.None, SortOrder.None, SortOrder.None, SortOrder.None, SortOrder.None}
 
Private Sub ListView1_ColumnClick(ByVal sender As Object, ByVal e As System.Windows.Forms.ColumnClickEventArgs) Handles ListView1.ColumnClick
    If oldsort(e.Column) = SortOrder.Descending Or oldsort(e.Column) = SortOrder.None Then
        oldsort(e.Column) = SortOrder.Ascending
    Else
        oldsort(e.Column) = SortOrder.Descending
    End If
    Dim sorter As New clsListViewItemComparer(e.Column)
    sorter.isDate = e.Column = 3
    sorter.isInteger = e.Column = 1
    sorter.isDecimal = e.Column = 2
    sorter.isIPAddress = e.Column = 4
    sorter.sortOrder = oldsort(e.Column)
    ListView1.ListViewItemSorter = sorter
    ListView1.Sort()
    ListView1.ListViewItemSorter = Nothing
End Sub

vb Code:

Public Class clsListViewItemComparer
    Implements IComparer
 
    Private _Column As Integer
    Private _isInteger As Boolean = False
    Private _isDecimal As Boolean = False
    Private _isDate As Boolean = False
    Private _isIPAddress As Boolean = False
    Private _sortOrder As SortOrder = Windows.Forms.SortOrder.None
 
    Public Property Column() As Integer
        Get
            Return _Column
        End Get
        Set(ByVal Value As Integer)
            _Column = Value
        End Set
    End Property
 
    Public Property isInteger() As Boolean
        Get
            Return _isInteger
        End Get
        Set(ByVal Value As Boolean)
            _isInteger = Value
        End Set
    End Property
 
    Public Property isDecimal() As Boolean
        Get
            Return _isDecimal
        End Get
        Set(ByVal Value As Boolean)
            _isDecimal = Value
        End Set
    End Property
 
    Public Property isDate() As Boolean
        Get
            Return _isDate
        End Get
        Set(ByVal Value As Boolean)
            _isDate = Value
        End Set
    End Property
 
    Public Property isIPAddress() As Boolean
        Get
            Return _isIPAddress
        End Get
        Set(ByVal Value As Boolean)
            _isIPAddress = Value
        End Set
    End Property
 
    Public Property sortOrder() As SortOrder
        Get
            Return _sortOrder
        End Get
        Set(ByVal Value As SortOrder)
            _sortOrder = Value
        End Set
    End Property
 
    Public Sub New(ByVal columnIndex As Integer)
        Column = columnIndex
    End Sub
 
    Public Function Compare(ByVal x As Object, ByVal y As Object) As Integer Implements System.Collections.IComparer.Compare
        Dim ListX As ListViewItem = CType(x, ListViewItem)
        Dim ListY As ListViewItem = CType(y, ListViewItem)
 
        If isInteger Then
            ' Convert column text to numbers before comparing.
            ' If the conversion fails, just use the value 0.
            Dim ListXVal, ListYVal As Integer
            Try
                ListXVal = Integer.Parse(ListX.SubItems(Column).Text)
            Catch
                ListXVal = 0
            End Try
 
            Try
                ListYVal = Integer.Parse(ListY.SubItems(Column).Text)
            Catch
                ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return ListYVal.CompareTo(ListXVal)
            Else
                Return ListXVal.CompareTo(ListYVal)
            End If
 
        ElseIf isDecimal Then
            ' Convert column text to numbers before comparing.
            ' If the conversion fails, just use the value 0.
            Dim ListXVal, ListYVal As Decimal
            Try
                ListXVal = Decimal.Parse(ListX.SubItems(Column).Text)
            Catch
                ListXVal = 0
            End Try
 
            Try
                ListYVal = Decimal.Parse(ListY.SubItems(Column).Text)
            Catch
                ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return Decimal.Compare(ListYVal, ListXVal)
            Else
                Return Decimal.Compare(ListXVal, ListYVal)
            End If
            
        ElseIf isDate Then
            Dim ListXVal, ListYVal As Date
            Try
                ListXVal = Date.Parse(ListX.SubItems(Column).Text)
            Catch
                'ListXVal = 0
            End Try
 
            Try
                ListYVal = Date.Parse(ListY.SubItems(Column).Text)
            Catch
                'ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return Date.Compare(ListYVal, ListXVal)
            Else
                Return Date.Compare(ListXVal, ListYVal)
            End If
        ElseIf isIPAddress Then
            Dim ListXVal, ListYVal As Integer
            Dim splitIndex As Integer = 0
 
nextElement:
 
            Try
                ListXVal = Integer.Parse(ListX.SubItems(Column).Text.Split("."c)(splitIndex))
            Catch
                ListXVal = 0
            End Try
 
            Try
                ListYVal = Integer.Parse(ListY.SubItems(Column).Text.Split("."c)(splitIndex))
            Catch
                ListYVal = 0
            End Try
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                If ListYVal.CompareTo(ListXVal) = 0 Then
                    If splitIndex < 3 Then
                        splitIndex += 1
                        GoTo nextElement
                    Else
                        Return 0
                    End If
                Else
                    Return ListYVal.CompareTo(ListXVal)
                End If
            Else
                If ListXVal.CompareTo(ListYVal) = 0 Then
                    If splitIndex < 3 Then
                        splitIndex += 1
                        GoTo nextElement
                    Else
                        Return 0
                    End If
                Else
                    Return ListXVal.CompareTo(ListYVal)
                End If
            End If
        Else
            ' Keep the column text in its native string format
            ' and perform an alphabetic comparison.
            Dim ListXText As String = ListX.SubItems(Column).Text
            Dim ListYText As String = ListY.SubItems(Column).Text
 
            If Not sortOrder = Windows.Forms.SortOrder.Ascending Then
                Return String.Compare(ListYText, ListXText)
            Else
                Return String.Compare(ListXText, ListYText)
            End If
 
        End If
 
    End Function
End Class

thanks dude..

That is perfect!

Dan