CRX Viewer error code 0xbe4

Hello.
I'm trying to open a Crystal Report that was originally made in CR5 in a CRX viewer. I plan to port all reports into CRX, so I wanted to use the CRX viewer instead of the CR5 one.

I'm getting this message when I try to open my report:
Attachment 69861

I'm using the following code to render the report:

vb Code:

Private Sub RenderReport()
'The Crystal Reports "application" to hold the CRReport and control the viewer
Dim vl_CRApp_cra As CRAXDRT.Application
'The Crystal Reports "CRReport" containing the CRReport itself and any changes
Dim vl_CRRep_cra As CRAXDRT.Report
 
 
'Initialize objects
   'On Error GoTo RenderReport_Error
   Stack.Push "RenderReport"
 
Set vl_CRApp_cra = New CRAXDRT.Application
Set vl_CRRep_cra = New CRAXDRT.Report
 
 
'Ensure that parameters are entered and file exists
If (SourceFile <> vbNullString) And (Dir(SourceFile) <> vbNullString) Then
    
    'Open the CRReport
    Set vl_CRRep_cra = vl_CRApp_cra.OpenReport(SourceFile)
    
    vl_CRRep_cra.RecordSelectionFormula = SelectionFormula
    vl_CRRep_cra.DiscardSavedData
    vl_CRRep_cra.Database.SetDataSource DataSource
    
    
    
    'Set the selection formula on the CRReport
    CRReport.ReportSource = vl_CRRep_cra
    
    
    RefreshReport
Else
    MsgBox "Invalid parameters"
End If
 
Set vl_CRApp_cra = Nothing
Set vl_CRRep_cra = Nothing
 
 
CleanUp:
   On Error GoTo 0
   Stack.Pop
   Exit Sub
 
RenderReport_Error:
 
ErrHandler "frmCRX", "Form", "Sub", "RenderReport", Erl
 
End Sub

My thought is that perhaps I'm not setting the report's database location properly. I assume I'm supposed to be using SetDataSource - since it makes sense that the report would want to pull info straight from a recordset.
Is there another property in which I would specify a database file name? I'm a n3wb to the CRX SDK.

Here's an example about how to render a .rpt file with subreports using Crystal Reports X
The report was designed to read a MS Access database file using DAO

Code:

---

'General Declarations
Public CRApplication As New CRAXDRT.Application
Public CRReport      As New CRAXDRT.Report
Public CRConProp    As CRAXDRT.ConnectionProperty
Public CRTabla      As CRAXDRT.DatabaseTable
Public CRFormula    As CRAXDRT.FormulaFieldDefinition
Public CRSections    As CRAXDRT.Sections
Public CRSection    As CRAXDRT.Section
Public CRSubRpt      As CRAXDRT.Report
Public CRSubRptObj  As CRAXDRT.SubreportObject
Public CRRptObjs    As CRAXDRT.ReportObjects
Public CRField      As CRAXDRT.DatabaseFieldDefinition
Public ReportObject  As Object

Public GTituloA      As String  'Main title
Public GTituloB      As String  'Subtitle
Public GSelFor      As String  'Selection formula string
Public MEnt2            As Integer 'a counter

'Preview the report
        GTituloA = "Main Title"
        GSelFor = "{Ingresos.FechaIng} = Date(" & MHasta & ")"
       
        Set CRReport = CRApplication.OpenReport(MyPath & "\rdi.rpt", 1)
        For MEnt2 = 1 To CRReport.Database.Tables.Count
            Set CRTabla = CRReport.Database.Tables(MEnt2)
            Set CRConProp = CRTabla.ConnectionProperties("Database Type")
                CRConProp.value = "Access/Excel (DAO)"
            Set CRConProp = CRTabla.ConnectionProperties("Database Name")
                CRConProp.value = MyPath & "\Ingresos.mdb"
            Set CRConProp = CRTabla.ConnectionProperties("Database Type")
                CRConProp.value = "Access"
            Set CRConProp = CRTabla.ConnectionProperties("Session UserID")
                CRConProp.value = ""
        Next MEnt2
        '
        For MEnt2 = 1 To CRReport.FormulaFields.Count
            Select Case CRReport.FormulaFields(MEnt2).name
                Case "{@a}"
                    CRReport.FormulaFields(MEnt2).Text = "Trim(" & Chr(39) & "Company's Name" & Chr(39) & ")"
                Case "{@b}"
                    CRReport.FormulaFields(MEnt2).Text = "Trim(" & Chr(39) & GTituloA & Chr(39) & ")"
                Case "{@c}"
                    CRReport.FormulaFields(MEnt2).Text = "Trim(" & Chr(39) & GTituloB & Chr(39) & ")"
            End Select
        Next MEnt2

        If Trim(GSelFor) <> "" Then
            CRReport.RecordSelectionFormula = GSelFor
        End If
       
        Set CRSections = CRReport.Sections
        For Each CRSection In CRSections
            Set CRRptObjs = CRSection.ReportObjects
            For Each ReportObject In CRRptObjs
                If ReportObject.Kind = CRAXDRT.CRObjectKind.crSubreportObject Then
                    Set CRSubRptObj = ReportObject
                    Set CRSubRpt = CRSubRptObj.OpenSubreport
                    For MEnt2 = 1 To CRSubRpt.Database.Tables.Count
                        Set CRTabla = CRSubRpt.Database.Tables(MEnt2)
                        Set CRConProp = CRTabla.ConnectionProperties("Database Type")
                            CRConProp.value = "Access/Excel (DAO)"
                        Set CRConProp = CRTabla.ConnectionProperties("Database Name")
                            CRConProp.value = App.Path & "\IngresosU.Mdb"
                        Set CRConProp = CRTabla.ConnectionProperties("Database Type")
                            CRConProp.value = "Access"
                        Set CRConProp = CRTabla.ConnectionProperties("Session UserID")
                            CRConProp.value = ""
                    Next MEnt2
                End If
            Next ReportObject
        Next CRSection
       
        'Here show the form with the viewer
        frmReporte.Show vbModal
       
        Set CRSections = Nothing
        Set CRSection = Nothing
        Set CRSubRpt = Nothing
        Set CRSubRptObj = Nothing
        Set CRRptObjs = Nothing
        Set ReportObject = Nothing

---

Now in the form with the viewer

Code:

---

Private Sub Form_Load()

    Me.Caption = GTituloA
    CRViewer1.ReportSource = CRReport
    CRViewer1.Zoom 1
    CRViewer1.ViewReport   

End Sub



Private Sub Form_Unload(Cancel As Integer)

    Set CRTabla = Nothing
    Set CRConProp = Nothing
    Set CRReport = Nothing
    Set CRApplication = Nothing
    GTituloA = ""
    GTituloB = ""
    GSelFor = ""
   
End Sub

---

Yeah..so....updating a CR5 report to CRX helps with the programmatic interaction.....