[RESOLVED] [2008] XML or INI

Hey I have an application that has a user interface like this

http://www.typol.co.uk/google/355e.png

The user will be able to save, edit, make a new account. The problem I am having is if I should use ini files or xml, some people told me that ini files are out of date and shouldn't be used so i started googling xml but i can't find anything useful.

If it was a ini file i would have it set out like this

Code:

---

[Name]
user=myusername
password=mypassword

---

etc...

If xml is better how would i go about doing this?

Thanks :)

If it was me I would probably go for XML, and since I just learnt today how to read XML files, I suppose this would be a good chance for me to learn how to write them. I'll post back with my code (assuming I get it working) in a moment :)

Ok thanks

you could easily write an xml file
heres the output:

Code:

---

<?xml version="1.0" encoding="utf-8"?>
<Records>
  <Record Host="local" User="myUsername" Password="myPassword" Directory="myDirectory" Timeout="myTimeout" URL="myUrl" />
</Records>

---

heres the code to use:

vb Code:

Dim writer As New Xml.XmlTextWriter("example.xml", System.Text.Encoding.UTF8)
writer.Formatting = Xml.Formatting.Indented
writer.WriteStartDocument()
writer.WriteStartElement("Records")
writer.WriteStartElement("Record")
writer.WriteAttributeString("Host", String.Empty, "local")
writer.WriteAttributeString("User", String.Empty, "myUsername")
writer.WriteAttributeString("Password", String.Empty, "myPassword")
writer.WriteAttributeString("Directory", String.Empty, "myDirectory")
writer.WriteAttributeString("Timeout", String.Empty, "myTimeout")
writer.WriteAttributeString("URL", String.Empty, "myUrl")
writer.WriteEndElement()
writer.WriteEndElement()
writer.Close()

Aw dammit paul I just finished my example! :D

vb Code:

Using writer As New XmlTextWriter("C:\Testing\test.xml", System.Text.Encoding.UTF8)
  With writer
        .WriteStartDocument()
        .WriteStartElement("UserProfile")
        .WriteElementString("UserName", usernamebox.Text)
        .WriteEndElement()
        .WriteEndDocument()
        .Close()
   End With
End Using

EDIT: One thing I do not understand about XML is what is the point in attributes? I mean for example, the way you have done in your example you have just created attributes for each item that is going to be stored, whereas I have created an element/node for each item. Is one method better than the other?

Thanks guys the help is much appreciated, and how would I retrieve the data into the textbox like txtHost.text =

Edit: I tried reversing the code didn't really work :( ill have another google or yahoo.

Here's a code example I gave someone else earlier for reading an XML file:

vb.net Code:

Dim xmldoc As New xmldocument
xmldoc.Load("C:\test.xml")
 
Dim Nodes As XmlNodeList
Nodes = xmldoc.SelectNodes("/Server/Specs")
 
For Each node As XmlNode In Nodes
     MessageBox.Show(node("HardDrives").InnerText)
Next

Obviously you need to change various bits and bobs in that but it might help you out a bit :)

heres how you'd retrieve the xml from my example:

vb Code:

Dim xmlDoc As New Xml.XmlDocument
xmlDoc.Load("example.xml")
 
Dim Host As String
Dim User As String
Dim Password As String
Dim Directory As String
Dim Timeout As String
Dim URL As String
 
For Each node As Xml.XmlNode In xmlDoc.SelectNodes("Record/Records")
    Host = node.Attributes("Host").Value
    User = node.Attributes("User").Value
    Password = node.Attributes("Password").Value
    Directory = node.Attributes("Directory").Value
    Timeout = node.Attributes("Timeout").Value
    URL = node.Attributes("URL").Value
Next

Thanks, when I use your code .paul. and do

Code:

---

txtHost.text = node.Attributes("Host").Value

---

its just blank even though the data is in the file saved, why is this?

Thanks :)

who's method of saving the data did you use? If you saved the data in the way I mentioned (using Nodes instead of Attributes) and are then trying to read it back using paul's method then you will find that it doesnt find anything.

Also, just to re-ask the question I added to one of my previous posts - does anyone know if using attributes for something like this is better/worse than using nodes or is there no real difference?

I used Pauls to save and load, still trying to get yours working to load.

did you get it working now?

if not, can you post your code?

well mine wont load anything if you used paul's method of saving ;)
As for why paul's isnt working... not sure, can you post your entire code block?

vb Code:

Imports System.Xml
Public Class frmFTP
 
    Private Sub cmdSave_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdSave.Click
        Dim writer As New Xml.XmlTextWriter("example.xml", System.Text.Encoding.UTF8)
        writer.Formatting = Xml.Formatting.Indented
        writer.WriteStartDocument()
        writer.WriteStartElement("Records")
        writer.WriteStartElement("Record")
        writer.WriteAttributeString("Host", String.Empty, txtHost.Text)
        writer.WriteAttributeString("User", String.Empty, txtUser.Text)
        writer.WriteAttributeString("Password", String.Empty, txtPass.Text)
        writer.WriteAttributeString("Directory", String.Empty, txtDir.Text)
        writer.WriteAttributeString("Timeout", String.Empty, txtTim.Text)
        writer.WriteAttributeString("URL", String.Empty, txtUrl.Text)
        writer.WriteEndElement()
        writer.WriteEndElement()
        writer.Close()
    End Sub
 
    Private Sub cmdLoad_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdLoad.Click
        Dim xmlDoc As New Xml.XmlDocument
        xmlDoc.Load("example.xml")
 
        For Each node As Xml.XmlNode In xmlDoc.SelectNodes("Record")
            txtHost.Text = node.Attributes("Host").Value
            txtUser.Text = node.Attributes("User").Value
            txtPass.Text = node.Attributes("Password").Value
            txtDir.Text = node.Attributes("Directory").Value
            txtTim.Text = node.Attributes("Timeout").Value
            txtUrl.Text = node.Attributes("URL").Value
        Next
 
    End Sub
End Class

Here you go :) Thanks, im going to try get chris's working.

all that i can see wrong with it is:

vb Code:

xmlDoc.SelectNodes("Record")

should be:

vb Code:

xmlDoc.SelectNodes("Records/Record")

chris's example uses the same method

Ahh thanks i changed that to see if it would work, I remember now i changed

Code:

---

writer.WriteStartElement("Record")

---

in the write code just testing something and forgot to change back. Thankyou chris and paul for the help :)