Manual 'MDI Window List' Menu

Hi,

After receiving a few questions about it, I decided to make a codebank submission about how to manually create the well-known "MDI Window List" menu. The menu I'm talking about is simply a list of all currently opened MDI child windows. The checked window is the active window, and by clicking any menu item the corresponding window is activated.
http://i39.tinypic.com/21jazaa.jpg

Now, please not that if you are simply working with MDI forms and you require no special functionality, Visual Studio can do this automatically. If you make your main form an MDI Parent (by setting the IsMdiContainer property to True) and add a MenuStrip control to the form, the Form's MainMenuStrip property is automatically set to that MenuStrip. If you finally create a 'Window' ToolStripMenuItem on that MenuStrip you can assign that menu item to the MenuStrip's MdiWindowListItem property and Visual Studio will automatically add the windows to that list.

However, what if you are not working with actual MDI forms but for example with 'fake' MDI forms (like in my Tabbed MDI Editor codebank submission)? Or what do you do if you want an extra MenuItem after the Window List (like the "Windows..." menu item in Visual Studio itself)? If you use the automatic method the windows are added to the bottom automatically, as far as I know there is nothing you can do about that.

So, the only way to overcome that is to create your own MDI window list, and it's not even that hard!

I'm going to try to explain what is happening exactly, and there is a [VS 2008] example project attached so you can have a look.

First of all, we need a method that refreshes the window list with changes in the forms (text, number of forms etc). This method will be called right before the Window DropDown is opened so it is always up to date.
I have called it RefreshWindowList.
vb.net Code:
Private Sub WindowToolStripMenuItem_DropDownOpening(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles WindowToolStripMenuItem.DropDownOpening
        RefreshWindowList()
    End Sub
The first step is to remove all the window items that may already be in the list (we don't want duplicate windows do we!). This step is already the most difficult step, because you will have to adjust it to your own needs.
The problem is that we cannot simply remove all the items in the Window dropdown, because there may be items that we want to keep. For example, in my example project there is a "Close" menu item, a separator and an Extra menu item at the bottom. We don't want to remove them.

So, to do that, we simply Loop through all the DropdownItems backwards. We then check if the current index is any of the items we don't want to remove, and if it is not, we remove it.
We loop backwards because we are removing items inside the loop. If we did that while looping forward normally, we would get an Index out of range error.
vb.net Code:
Dim item As ToolStripItem
        For i As Integer = menuItemWindowCount - 1 To 0 Step -1
            item = Me.WindowToolStripMenuItem.DropDownItems(i)
 
            If Not (item Is CloseToolStripMenuItem _
                    Or item Is WindowSeparator _
                    Or item Is ExtraItemToolStripMenuItem) Then
                Me.WindowToolStripMenuItem.DropDownItems.RemoveAt(i)
            End If
        Next
As you can see, I simply use an If statement to check the current menu item is any of the ones we don't want to remove.

The next step is to add new menu items for each open MDI child window. We simply loop through all the MDI child windows and create a new ToolStripMenuItem for each window. We set its Text to a number (counter) + the window text.
Then, we assign the current window to the Tag property of the menu item so we can retrieve it when it is clicked.
Then, we see if the current window is also the Active window. If it is, we check it.
Then, we need to add a Click EventHandler to allow the user to Click the items.

Finally, we Insert it into the Window dropdown items. We need to Insert it instead of Add it, because we still want the Extra menu item to be on the bottom! So we need to insert it into the next-to-last index. If you want to have more menu items behind the window list, you need to insert it into a different position.
vb.net Code:
If mdiWindowCount > 0 Then
            Dim menuItem As ToolStripMenuItem
            Dim counter As Integer = 1
            ' Add the new window items
            For Each window As mdiForm In Me.MdiChildren
                'Create new menuitem
                menuItem = New ToolStripMenuItem
 
                'Set the text to for example "2. Windowtext"
                menuItem.Text = counter.ToString & ". " & window.Text
 
                'Set the tag to the current window so we can retrieve it later
                menuItem.Tag = window
 
                'Check the menuitem if this is the currently active window
                If window Is Me.ActiveMdiChild Then
                    menuItem.Checked = True
                End If
 
                'Add a Click EventHandler to be able to click it
                AddHandler menuItem.Click, AddressOf WindowMenuItemClicked
 
                'Finally add it to the actual menuitem list
                Me.WindowToolStripMenuItem.DropDownItems.Insert(Me.WindowToolStripMenuItem.DropDownItems.Count - 1, menuItem)
 
                'Raise the counter by 1
                counter += 1
            Next
        End If
The last step is the create the click eventhandler method which is called when the menu item is Clicked. The 'sender' object can be casted to a ToolStripMenuItem, and its Tag property will be the window we need to activate.
vb.net Code:
Private Sub WindowMenuItemClicked(ByVal sender As Object, ByVal e As EventArgs)
        'Retrieve the clicked MenuItem from the sender object
        Dim menuItem As ToolStripMenuItem = TryCast(sender, ToolStripMenuItem)
 
        'Retrieve the corresponding form from the Tag property
        Dim frm As mdiForm = TryCast(menuItem.Tag, mdiForm)
 
        'Activate it
        If frm IsNot Nothing Then
            frm.Activate()
        End If
    End Sub
Note that we don't need to check the menu item here for example, because as soon as you click it, the dropdown closes. The next time you open it, the RefreshWindowList method will be called again and the correct item will be checked.

Result:
http://i40.tinypic.com/2i1m3wo.jpg

So, that's that! If there are any questions or suggestions, don't hesitate to ask, but not after looking at the code and its comments, you might learn a lot from that!

Note that, if the reason that you are creating the list manually is because you are not using Mdi Forms but for example TabPages, you will have to replace some things in the code. For example, the active window using Mdi forms is just "Me.ActiveMdiChild" but if you're using TabPages it is different... If you can't figure it out, just ask!

Enjoy...