How Do I Minimize A Form To Its NotifyIcon In The System Tray?

I need to make a form minimize to it's system tray icon instead of minimizing to its task bar button, how?

Thanks,
Louix.

Strictly speaking you don't actually minimise a form to the system tray. That's a conceptual thing rather than what actually happens. You simply add a NotifyIcon to the form and set it's Visible property to True.

You can handle the SizeChanged event of the form and test the WindowState property. If it's Minimized you Hide the form and Show the NotifyIcon, otherwise you do the opposite.

Hmmm... I tested what I was sure had worked before and it didn't. This does:

vb.net Code:

Private Sub Form1_SizeChanged(ByVal sender As Object, _
                              ByVal e As EventArgs) Handles Me.SizeChanged
    Me.UpdateTrayState(Me.WindowState = FormWindowState.Minimized)
End Sub
 
Private Sub NotifyIcon1_MouseDoubleClick(ByVal sender As Object, _
                                         ByVal e As MouseEventArgs) Handles NotifyIcon1.MouseDoubleClick
    Me.UpdateTrayState(False)
    Me.WindowState = FormWindowState.Normal
End Sub
 
Private Sub UpdateTrayState(ByVal minimiseToTray As Boolean)
    Me.Visible = Not minimiseToTray
    Me.NotifyIcon1.Visible = minimiseToTray
End Sub

No, what I mean is I need the minimize animation to fly over to the far right of the screen instead of minimizing to its task bar button. Hence "I need to make a form minimize to it's system tray icon instead of minimizing to its task bar button".

It's also worth noting that setting the form's ShowInTaskbar property instead of its Visible property will allow you to restore the form using Alt+Tab, although it will not be activated automatically when you restore it that way.

Quote:

---

Originally Posted by Louix

No, what I mean is I need the minimize animation to fly over to the far right of the screen instead of minimizing to its task bar button. Hence "I need to make a form minimize to it's system tray icon instead of minimizing to its task bar button".

---

Well that's not possible because, as I said, there really is no such thing as minimising to the system tray. Form's are simply minimised or not. You can hide the form's Taskbar icon and display an icon in the Notification Area if you want but that doesn't mean that the form was minimised to there.

An icon on the Taskbar directly represents a form. An icon in the Notification Area does not. A single form might create multiple icons in the system tray if you want or, as is usually the case, the entire application is represented by a single icon. There is no direct relationship between a form and a system tray icon so there is no animation to display such a relationship.

Okay, thank you very much for your help anyway, it might help with another part of this app.

Here is some code that I got from Google search.

vb.net Code:

Public Class Form1
    Inherits System.Windows.Forms.Form
 
    Structure RECT
        Public left As Integer
        Public top As Integer
        Public right As Integer
        Public bottom As Integer
    End Structure
 
    Structure APPBARDATA
        Public cbSize As Integer
        Public hWnd As IntPtr
        Public uCallbackMessage As Integer
        Public uEdge As ABEdge
        Public rc As RECT
        Public lParam As IntPtr
    End Structure
 
    Enum ABMsg
        ABM_NEW = 0
        ABM_REMOVE = 1
        ABM_QUERYPOS = 2
        ABM_SETPOS = 3
        ABM_GETSTATE = 4
        ABM_GETTASKBARPOS = 5
        ABM_ACTIVATE = 6
        ABM_GETAUTOHIDEBAR = 7
        ABM_SETAUTOHIDEBAR = 8
        ABM_WINDOWPOSCHANGED = 9
        ABM_SETSTATE = 10
    End Enum
 
    Enum ABNotify
        ABN_STATECHANGE = 0
        ABN_POSCHANGED
        ABN_FULLSCREENAPP
        ABN_WINDOWARRANGE
    End Enum
 
    Enum ABEdge
        ABE_LEFT = 0
        ABE_TOP
        ABE_RIGHT
        ABE_BOTTOM
    End Enum
 
    Public Declare Function SHAppBarMessage Lib "shell32.dll" Alias "SHAppBarMessage" (ByVal dwMessage As Integer, ByRef pData As APPBARDATA) As Integer
 
    Private Const ABM_GETTASKBARPOS As Integer = &H5&
    Private Const WM_SYSCOMMAND As Integer = &H112
    Private Const SC_MINIMIZE As Integer = &HF020
 
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        If m.Msg = WM_SYSCOMMAND AndAlso m.WParam.ToInt32() = SC_MINIMIZE Then
            AnimateWindow(True)
            Exit Sub
        End If
 
        MyBase.WndProc(m)
    End Sub
 
    Private Sub NotifyIcon1_DoubleClick(ByVal sender As Object, ByVal e As System.EventArgs) Handles NotifyIcon1.DoubleClick
        AnimateWindow(False)
    End Sub
 
    Private Sub AnimateWindow(ByVal ToTray As Boolean)
        ' get the screen dimensions
        Dim screenRect As Rectangle = Screen.PrimaryScreen.GetBounds(Me.Location)
 
        ' figure out where the taskbar is (and consequently the tray)
        Dim destPoint As Point
        Dim BarData As APPBARDATA
        BarData.cbSize = System.Runtime.InteropServices.Marshal.SizeOf(BarData)
        SHAppBarMessage(ABMsg.ABM_GETTASKBARPOS, BarData)
        Select Case BarData.uEdge
            Case ABEdge.ABE_BOTTOM, ABEdge.ABE_RIGHT
                ' Tray is to the Bottom Right
                destPoint = New Point(screenRect.Width, screenRect.Height)
 
            Case ABEdge.ABE_LEFT
                ' Tray is to the Bottom Left
                destPoint = New Point(0, screenRect.Height)
 
            Case ABEdge.ABE_TOP
                ' Tray is to the Top Right
                destPoint = New Point(screenRect.Width, 0)
 
        End Select
 
        ' setup our loop based on the direction
        Dim a, b, s As Single
        If ToTray Then
            a = 0
            b = 1
            s = 0.05
        Else
            a = 1
            b = 0
            s = -0.05
        End If
 
        ' "animate" the window
        Dim curPoint As Point, curSize As Size
        Dim startPoint As Point = Me.Location
        Dim dWidth As Integer = destPoint.X - startPoint.X
        Dim dHeight As Integer = destPoint.Y - startPoint.Y
        Dim startWidth As Integer = Me.Width
        Dim startHeight As Integer = Me.Height
        Dim i As Single
        For i = a To b Step s
            curPoint = New Point(startPoint.X + i * dWidth, startPoint.Y + i * dHeight)
            curSize = New Size((1 - i) * startWidth, (1 - i) * startHeight)
            ControlPaint.DrawReversibleFrame(New Rectangle(curPoint, curSize), Me.BackColor, FrameStyle.Thick)
            System.Threading.Thread.Sleep(15)
            ControlPaint.DrawReversibleFrame(New Rectangle(curPoint, curSize), Me.BackColor, FrameStyle.Thick)
        Next
 
        If ToTray Then
            ' hide the form and show the notifyicon
            Me.Hide()
            NotifyIcon1.Visible = True
        Else
            ' hide the notifyicon and show the form
            NotifyIcon1.Visible = False
            Me.Show()
        End If
    End Sub
 
End Class

Cool! Never say never. :blush: