[2008] open file dialog

me again with something a little different this time.
I have made an "mp3 player" in which i use the open file dialog to open multipal mp3 files. and a list box to list the files that are open... but it keeps opening the files and displaying the full file path and not just the name... so my question is, how would I get it to just disply the file name???

Dan

Something like this

Code:

---


 ' declare a global variable to hold the name of the data base being used
  Dim selectedDatabase As String
 ' varaible to hold the path to the data base
  Dim dataBasePath As String = Me.selectedDatabase
 ' the actual name of the data base
  Dim dataBaseName As String = IO.Path.GetFileName(dataBasePath)

---

from a project I created

hmmm... i am not sure i understood that. I am a complete programming noob. Dont know to much about it:(

So what is your open file dialog code, post it.

try this:

vb Code:

Dim ofd As New OpenFileDialog
ofd.Multiselect = True
If ofd.ShowDialog = Windows.Forms.DialogResult.OK Then
  For Each filename As String In ofd.FileNames
      ListBox1.Items.Add(IO.Path.GetFileName(filename))
  Next
End If

but you need the full filename to open them, don't you?

should look something like this

Code:

---

        Dim openFD As New OpenFileDialog(), openFDr As DialogResult

        openFD.InitialDirectory = "c:\"
        openFD.Filter = "txt files (*.txt)|*.txt|All files (*.*)|*.*"
        openFD.FilterIndex = 2
        openFD.RestoreDirectory = True
        openFD.Multiselect = True

        openFDr = openFD.ShowDialog

        If openFDr = Windows.Forms.DialogResult.OK Then
            For Each fn As String In openFD.FileNames
                ListBox3.Items.Add(IO.Path.GetFileNameWithoutExtension(fn))
            Next
        End If

---

you could use a custom listitem, like this:

vb Code:

Public Class fileListItem
    Public display As String
    Public fileName As String
 
    Public Overrides Function ToString() As String
        Return Me.display
    End Function
 
    Public Sub New(ByVal display As String, ByVal fileName As String)
        Me.display = display
        Me.fileName = fileName
    End Sub
End Class

then to use it:

vb Code:

Public Class Form1
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim ofd As New OpenFileDialog
        ofd.Multiselect = True
        If ofd.ShowDialog = Windows.Forms.DialogResult.OK Then
            For Each filename As String In ofd.FileNames
                ListBox1.Items.Add(New fileListItem(IO.Path.GetFileNameWithoutExtension(filename), filename))
            Next
        End If
    End Sub
 
    Private Sub ListBox1_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ListBox1.SelectedIndexChanged
        MsgBox(DirectCast(ListBox1.SelectedItem, fileListItem).fileName)
    End Sub
 
End Class

this is the coding that I have already, which works... but it displays the file path:(

Code:

---

Private Sub Importdiag_FileOk(ByVal sender As System.Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles Importdiag.FileOk
        For Each track As String In Importdiag.FileNames
            Playlist.Items.Add(track)
        Next
    End Sub

---

I will try what you said Paul
edit: sorry I forgot the coding

Instead of

Code:

---

Playlist.Items.Add(track)

---

Use

Code:

---

Playlist.Items.Add(IO.Path.GetFileNameWithoutExtension(track))

---

Now however, you can no longer use the items in the Listbox to get the full path (for example for actually playing them). If this is OK then the code above will do.
If you still need the full path but only display the filename you can use any of the above suggestions.

Also, you could use a ListView instead of a ListBox, and set the "View" property to "List".
Then, assuming the Listview is called "Playlist" you can use:

Code:

---

Dim lvi As New ListViewItem(IO.Path.GetFileNameWithoutExtension(track))
lvi.Tag = track
Playlist.Items.Add(lvi)

---

What that does is create a new ListViewItem (lvi) which displays the Filename of 'track' only, but stores the actual full path (track) in it's Tag property.
To access the full path now you can use:

Code:

---

lvi.Tag.ToString

'or
CType(lvi.Tag, String)

'example:
Dim lvi As ListViewItem = PlayList.SelectedItem
Dim fullPath As String = lvi.Tag.ToString

---