RollOverPanel and RollOverLabel

I wrote a simple tutorial on a RollOverLabel I while back. One of the reasons I created the label was for an application I am building that has a menu like so:

http://img29.picoodle.com/img/img29/...em_7eb6ca0.gif

I wanted the heading and description to change colour when I entered the "outer" region. I also wanted to be able to click anywhere in this region and preform one click event. What I came up with was the reworked RollOverLabel and the new RollOverPanel.

Wheter they know it or not the following people had a part to play and have my thanks for helping complete this project.

Athiest, Max Mayhofer, Jmcilhinney and Deepak Sakpal.

Panel Code

VB Code:

'Component Name: RollOverPanel
'Author: Dean McDonnell
'Date: 29 Sept 2008
Imports System.ComponentModel
 
<ToolboxBitmap(GetType(Panel))> _
Public Class RollOverPanel
    Inherits System.Windows.Forms.Panel
 
 
#Region "Overriden Methods."
    ''' <summary>
    ''' OnMouseEnter - Calls ActivateHotControls.
    ''' </summary>
    Protected Overrides Sub OnMouseEnter(ByVal e As System.EventArgs)
        MyBase.OnMouseEnter(e)
        ActivateHotControls()
    End Sub
 
    ''' <summary>
    ''' OnMouseLeave - Deactivates Hot Controls. This method does not know if the mouse entered
    ''' a child control. This is handled by the MouseInChild() Method.
    ''' </summary>
    Protected Overrides Sub OnMouseLeave(ByVal e As System.EventArgs)
        MyBase.OnMouseLeave(e)
        DeactivateHotControls()
    End Sub
 
    ''' <summary>
    ''' OnControlAdded - Adds handlers to each control as they are created via the AddHandleToChildren(e)
    ''' method. They are destroyed in the finalize method"
    ''' </summary>
    Protected Overrides Sub OnControlAdded(ByVal e As System.Windows.Forms.ControlEventArgs)
        MyBase.OnControlAdded(e)
        AddHandleToChildren(e)
    End Sub
 
    ''' <summary>
    ''' Finalize - Overrided to remove handle from children.
    ''' </summary>
    Protected Overrides Sub Finalize()
        MyBase.Finalize()
        RemoveHandleFromChildren()
    End Sub
#End Region
 
#Region "Custom Methods."
    ''' <summary>
    ''' AddHandleToChildren - Places handles on each child to allow the panel to control when its hot and if it
    ''' is clicked. If these where not in place when the user moused over other controls in the panel the
    ''' RollOverLabels would revert to their base color. The second handler allows the user to click anywhere
    ''' on the panel including its children. Clicks are handled by Instance.OnClick(). 
    ''' </summary>
    Private Sub AddHandleToChildren(ByVal e As System.Windows.Forms.ControlEventArgs)
        AddHandler e.Control.MouseEnter, AddressOf MouseInChild
        AddHandler e.Control.Click, AddressOf ChildClicked
    End Sub
 
    ''' <summary>
    ''' RemoveHandleFromChildren - See above for explaination on why handles where added. This method
    ''' simply removes them.
    ''' </summary>
    Private Sub RemoveHandleFromChildren()
        For Each Child As Control In Me.Controls
            RemoveHandler Child.MouseEnter, AddressOf MouseInChild
            RemoveHandler Child.Click, AddressOf ChildClicked
        Next
    End Sub
 
    ''' <summary>
    ''' ChildClicked - Allows the user of the RollOverPanel to call just one Click() Method to handle the
    ''' panel and its children. Each child control that is clicked will fire this event.
    ''' </summary>
    Private Sub ChildClicked(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.OnClick(e)
    End Sub
 
    ''' <summary>
    ''' MouseInChild - This method enables the hot controls to stay hot even if mouseleave is fired by the
    ''' panel because the mouse entered a child control.
    ''' </summary>
    Private Sub MouseInChild(ByVal sender As Object, ByVal e As System.EventArgs)
        ActivateHotControls()
    End Sub
 
    ''' <summary>
    ''' DeactivateHotControls - Loops through each RollOver Control and calls the triggeroff() method 
    ''' of said controls. TriggerOff() reverts from the controls "hot" color to its base color. 
    ''' </summary>
    Private Sub DeactivateHotControls()
        For Each Control In Me.Controls
            If TypeOf Control Is RollOverLabel Then
                Dim CurrentLabel As RollOverLabel = CType(Control, RollOverLabel)
                CurrentLabel.TriggerOff()
            End If
        Next
    End Sub
 
    ''' <summary>
    ''' ActivateHotControls - Loops through each RollOver control and calls the triggeroff() method of said 
    ''' controls. TriggerOn() changes the controls base color to its "hot" color.
    ''' </summary>
    Private Sub ActivateHotControls()
        For Each Control In Me.Controls
            If TypeOf Control Is RollOverLabel Then
                Dim CurrentLabel As RollOverLabel
                CurrentLabel = CType(Control, RollOverLabel)
                CurrentLabel.TriggerOn()
            End If
        Next
    End Sub
#End Region
 
End Class

Label Code

VB Code:

'Component Name: RollOverLabel
'Author: Dean McDonnell
'Date: 29 Sept 2008
Imports System.ComponentModel
 
<ToolboxBitmap(GetType(Label))> _
Public Class RollOverLabel
    Inherits System.Windows.Forms.Label
 
#Region "Properties and Their Variables."
 
    ''' <summary>
    ''' BaseColor = ForeColor     HotColor = RollOverColor
    ''' </summary>
    Private BaseColor As Color = Color.Black
    Private HotColor As Color = Color.Black
 
    ''' <summary>
    ''' RollOverColor - A simple property to GET/SET the RollOver color.
    ''' </summary>
    <Description("Sets the color the label will change to when moused over")> _
    <Category("Appearance")> _
    Public Property RollOverColor() As Color
        Get
            Return HotColor
        End Get
 
        Set(ByVal value As Color)
            HotColor = value
        End Set
    End Property
#End Region
 
#Region "Overriden Methods."
    ''' <summary>
    ''' OnMouseEnter - Calls TriggerOn() if a RollOverPanel is not its parent.
    ''' </summary>
    Protected Overrides Sub OnMouseEnter(ByVal e As System.EventArgs)
        MyBase.OnMouseEnter(e)
 
        If TypeOf Me.Parent Is RollOverPanel Then
            Exit Sub
        Else
            TriggerOn()
        End If
    End Sub
 
    ''' <summary>
    ''' OnMouseLeave - Calls TriggerOf() if a RollOverPanel is not its parent.
    ''' </summary>
    Protected Overrides Sub OnMouseLeave(ByVal e As System.EventArgs)
        MyBase.OnMouseLeave(e)
 
        If TypeOf Me.Parent Is RollOverPanel Then
            Exit Sub
        Else
            TriggerOff()
        End If
    End Sub
#End Region
 
#Region "Custom Methods."
    ''' <summary>
    ''' This method changes the foreColor from the base color to the hot color.
    ''' </summary>
    ''' <remarks>This method is visible to the RollOverPanel because of the Friend Modifier</remarks>
    Friend Sub TriggerOn()
        If Me.ForeColor = Me.HotColor Then
            Exit Sub
        Else
            BaseColor = Me.ForeColor
            Me.ForeColor = HotColor
        End If
 
    End Sub
 
    ''' <summary>
    ''' This method changes the foreColor from the hot color to the base color.
    ''' </summary>
    ''' <remarks>This method is visible to the RollOverPanel because of the Friend Modifer</remarks>
    Friend Sub TriggerOff()
        Me.ForeColor = BaseColor
    End Sub
#End Region
 
End Class

Any problems or if you think you can refactor any particular part better let me know let me know.

Guys,

I teach myself VB and as such I have nobody to look over my code and help me to refactor it. If you find anything wrong please DO post. While I wrote the original code I have no qualms with refactoring it to make to make the code cleaner and run better. I have received one submission already and will change the code shortly.

Instead of removing all eventhandlers and adding them again when OnControlAdded is called, you should make use of the ControlEventArgs object and add that single control only:

VB.NET Code:

Protected Overrides Sub OnControlAdded(ByVal e As System.Windows.Forms.ControlEventArgs)
        MyBase.OnControlAdded(e)
        AddHandler e.Control.MouseEnter, AddressOf MouseInChild
            AddHandler e.Control.Click, AddressOf ChildClicked
    End Sub

Thanks Athiest, this is the change I was talking about. Im currently updating the source and will post it again soon.

Right that looks much better and will save a lot of looping. Ive kept the AddHandler() method though for cleanlyness sake.

I just thought this was worth mentioning. a panels child controls CANNOT sit on the border of the panel control. If they do the mouseleave event wont fire and the control will not work:

http://img29.picoodle.com/img/img29/...em_071c344.jpg

As you can see my picture boxes are 1px away from the border so it works now. And just a screen of them in action:

http://img03.picoodle.com/img/img03/...2m_0db769b.jpg