[RESOLVED] [2008] Copying state of Treeview

Hi,

I have one main form with a panel called pnl. On the panel are a few controls including a Treeview (tv1).

Now, when the user clicks a certain button, the panel pnl (including the treeview) is hidden, and a new form opens, showing the same treeview.
(Basically, you could see it as 'undocking' the treeview from the main form into a seperate form)

Now, I want the treeview in the new seperate form to have the same state (that is, the same nodes opened) as the treeview I have just hidden.


I tried this code but for some reason it is not working:

In the main form, in the 'undock' button click event:

vb.net Code:

If frmSCP.Created = True Then
      frmSCP.Visible = True
Else
      frmSCP.Show()
End If
pnl.Visible = False

(frmSCP is the seperate treeview form)

I check for the creation of frmSCP first because loading the contents of the treeview takes a little time and I don't want it to load it all over again each time the form is loaded. Therefore I simply hide it (Visible = False) and re-show it (Visible = True) again if it was opened before.


In frmSCP I have the following code:

vb.net Code:

Private Sub btnDock_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnDock.Click
        frmMain.pnl.Visible = True
        frmMain.tv1.CollapseAll()
        frmMain.tv1.SelectedNode = tv1.SelectedNode
        Me.Visible = False
    End Sub
 
    Private Sub frmSCP_Activated(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Activated
        tv1.CollapseAll()
        tv1.SelectedNode = frmMain.tv1.SelectedNode
    End Sub
 
    Private Sub frmSCP_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        LoadTreeViewFromXmlFile(My.Resources.IntelXML, tv1)
        tv1.CollapseAll()
        tv1.SelectedNode = frmMain.tv1.SelectedNode
    End Sub

(LoadTreeViewFromXlmFile() is the treeview loading sub)

As you can see, when the Dock button is pressed, the first thing to happen is to re-show the treeview in the main form. Then, all it's nodes are collapsed. Then, it's SelectedNode property is set to the same SelectedNode property of the treeview in the current form, and finally, the current form is hidden.

When the form is activated or loaded, the treeviews nodes are all collapsed and then the correct node should be selected again.

I know that this will not automatically expand the same nodes as the other treeview, it merely selects the same nodes (but, afaik, if you tell it to select a subnode for example, the parent node will automatically expand, no??)

I am still looking for how to expand the same nodes...


But first, the code above is NOT working! It does not select the same node (not even when I have a parent node selected). I can see no reason why it shouldn't be working... Also note that I have made sure that the new treeview's nodes are first selected, before closing (hiding) the old treeview, so that should give me no problems right??


If anyone has any ideas, please let me know! Thanks.

You need to do the serialization of the treeview to persist the data and state. Here are the results given by Google.

Thanks, that helped alot!

I have now succesfully been able to copy the treeview, including which nodes are expanded.

However, the selected node is not copied over yet. If I selected some child node and then 'undock' the treeview (which copies over the treeview) then in the new treeview, the node is not selected (no nodes are).

Is this because, as soon as I press the button, the node goes unselected (because the treeview loses focus) ? How could I do this?

Quote:

---

Originally Posted by NickThissen

However, the selected node is not copied over yet. If I selected some child node and then 'undock' the treeview (which copies over the treeview) then in the new treeview, the node is not selected (no nodes are).

Is this because, as soon as I press the button, the node goes unselected (because the treeview loses focus) ? How could I do this?

---

No, I don't think so... because even the treeview is loosing the focus, the selected node is still there as selected. Can you post your serialization code so that people here can look into it...

I am using exactly this:
http://www.codeproject.com/KB/vb/Tre...ataAccess.aspx

As far as I can understand the code there seems to be no SelectedNode that gets saved and/or loaded. I have tried to add it myself but I only understand the code partially so I had no succes with that...

I am now trying to use variations on my very first attempt (thought it might work now that the expanded nodes are the same, but don't have much hope...)


EDIT
I've tried to identify what is happening with my first attempt by walking through the code in debug mode. However, when hovering the mouse over "frmMain.tv1.SelectedNode" in frmSCP, there is no pop-up telling me what it contains.
When I pass the line "Me.tv1.SelectedNode = frmMain.tv1.SelectedNode" I can see that before and after this is executed, 'Me.tv1.SelectedNode' is always Nothing, so frmMain.tv1.SelectedNode was also Nothing...??

Well I'm really stumped now...

I made a public variable 'SelectedNode' (of type 'Treenode'). Before hiding the original treeview, I save the currently selected node to SelectedNode (debugging confirms that it is saved properly).

Then after loading the new form (and treeview) I set the new treeview's SelectedNode property to SelectedNode:
Me.tv1.SelectedNode = SelectedNode

While debugging I can see that 'SelectedNode' contains (for example): {Text = 'node text'}.

However, after stepping over the line mentioned above, Me.tv1.SelectedNode is still Nothing..?! It is simply not doing what it is supposed to do... It is not setting the value for some reason...??


EDIT
I made a quick test project with simply two treeviews, with the same number of nodes and childnodes.
I then expand a parent node in both treeviews (the same parent node in both) and select one childnode.
Then when I use the following code, it should 'carry over' the selection from tv1 to tv2, but it does not!

Code:

---

        tv2.SelectedNode = tv1.SelectedNode
        tv2.Focus()

---

Even though tv1.SelectedNode does have a value, tv2.SelectedNode is not set to that value...

Sorry for triple-posting, but I think it's better to post this in a seperate reply.

I have finally made some progress, by editing the serialization process from this site:
http://www.codeproject.com/KB/vb/Tre...ataAccess.aspx

In the '<Serializable()> Public Structure TreeNodeData' I have added a 'Public Selected As Boolean' variable alongside the 'Checked', 'Expanded' etc variables.

Then, in the 'Public Sub New(ByVal node As TreeNode)' sub, I have added the following line:
'Me.Selected = node.IsSelected'
to save the selected state of the nodes.

Opening the xml file manually I can see that the correct node gets a 'Selected' tag with value True, while all others get False. <-- correct.

Then I needed to find a way to read this tag and select the right node. I did this by editing the 'PopulateTree' sub slightly:

vb.net Code:

Public Sub PopulateTree(ByVal treeview As TreeView)
            'Check to see if there are any root nodes in the TreeViewData
            If Me.Nodes Is Nothing OrElse Me.Nodes.Length = 0 Then Exit Sub
 
            'Populate the TreeView with child nodes
            treeview.BeginUpdate()
            Dim n As Integer
            For i As Integer = 0 To Me.Nodes.Length - 1
                treeview.Nodes.Add(Me.Nodes(i).ToTreeNode)
 
                '--------
                If Me.Nodes(i).Selected = True Then n = i
                '--------
            Next
            treeview.EndUpdate()
 
            '--------
            If n > -1 Then treeview.SelectedNode = treeview.Nodes(n)
            '--------
        End Sub

(Additions are between dashed comments --------.)


Although this seems to work, it only works for parent nodes, it does NOT work for child nodes.

When I select a parent node and save/load the treeview state to the other treeview, the right parent node is selected.
When I select a childnode however, the SelectedNode becomes 'Nothing' once again (and for some reason it selects the first parent node)...


EDIT
I have attached the test project. It contains two treeviews. You can select a node in the first (left-most) treeview and press the button to copy over the state to the right treeview. Expanded nodes are all copied over alright, but as you can see only the selected parent nodes are copied, not the child nodes.
(NOTE, this saves a file 'tv.xml' in your C:\ drive, change the path in Form1 if you like.)

EDIT


Nevermind I finally got it to work! I think it's quite a messy solution and might only work in my case (where there's only one level of childnodes).

If anyone wants to know how I did it, I used the project from the links I posted above, and edited it slightly. The code is now this (edited bits are clearly stated):

vb.net Code:

Option Strict On
 
''' <summary>
''' The TreeViewDataAccess class allows the nodes within a TreeView to be 
''' persisted to xml for later retrevial.
''' </summary>
Public Class TreeViewDataAccess
 
    '=============================
    '----- START EDITED ----------
    '=============================
    Public Shared n As Integer
    Public Shared tn As TreeNode
    '=============================
    '----- END EDITED ------------
    '=============================
 
#Region "Structures"
 
    ''' <summary>
    ''' TreeViewData structure represents the root node collection of a TreeView
    ''' and provides the PopulateTreeView function to add these nodes to a specified
    ''' TreeView instance.
    ''' </summary>
    <Serializable()> Public Structure TreeViewData
 
        ''' <summary>Array of TreeNodeData objects representing the root nodes in a TreeView.</summary>
        Public Nodes() As TreeNodeData
 
        ''' <summary>
        ''' Creates new instance of the TreeViewData structure based from the 
        ''' specified TreeView.
        ''' </summary>
        ''' <param name="treeview">TreeView to build the TreeViewData instance from.</param>
        Public Sub New(ByVal treeview As TreeView)
 
            'Check to see if there are any root nodes in the TreeView
            If treeview.Nodes.Count = 0 Then Exit Sub
 
            'Populate the Nodes array with child nodes
            ReDim Nodes(treeview.Nodes.Count - 1)
            For i As Integer = 0 To treeview.Nodes.Count - 1
                Nodes(i) = New TreeNodeData(treeview.Nodes(i))
            Next
        End Sub
 
        ''' <summary>
        ''' Populates the specified TreeView with the current TreeViewData instance.
        ''' </summary>
        ''' <param name="treeview">TreeView instance to populate.</param>
        Public Sub PopulateTree(ByVal treeview As TreeView)
            'Check to see if there are any root nodes in the TreeViewData
            If Me.Nodes Is Nothing OrElse Me.Nodes.Length = 0 Then Exit Sub
 
            'Populate the TreeView with child nodes
            treeview.BeginUpdate()
 
            For i As Integer = 0 To Me.Nodes.Length - 1
                treeview.Nodes.Add(Me.Nodes(i).ToTreeNode())
 
                '=============================
                '----- START EDITED ----------
                '=============================
                If Me.Nodes(i).Selected Then
                    tn = Me.Nodes(i).ToTreeNode
                    n = i
                End If
                '=============================
                '----- END EDITED ------------
                '=============================
 
            Next
            treeview.EndUpdate()
 
            '=============================
            '----- START EDITED ----------
            '=============================
            If tn.Level > 0 Then
                treeview.SelectedNode = tn
            ElseIf n > -1 Then
                treeview.SelectedNode = treeview.Nodes(n)
            End If
            '=============================
            '----- END EDITED ------------
            '=============================
        End Sub
 
    End Structure
 
    ''' <summary>
    ''' TreeNodeData structure represents a TreeNode and provides the
    ''' ToTreeNode function to convert the instance to a TreeNode object.
    ''' </summary>
    <Serializable()> Public Structure TreeNodeData
 
        ''' <summary>String representing the Text property of the TreeNode.</summary>
        Public Text As String
        ''' <summary>Integer representing the ImageIndex property of the TreeNode.</summary>
        Public ImageIndex As Integer
        ''' <summary>Integer representing the SelectedImageIndex property of the TreeNode.</summary>
        Public SelectedImageIndex As Integer
        ''' <summary>Boolean representing the Checked state of the TreeNode.</summary>
        Public Checked As Boolean
        ''' <summary>Boolean representing the Expanded state of the TreeNode.</summary>
        Public Expanded As Boolean
        ''' <summary>Object representing the Tag property of the TreeNode.</summary>
        Public Tag As Object
 
        '=============================
        '----- START EDITED ----------
        '=============================
        ''' <summary>Boolean representing the Selected property of the TreeNode.</summary>
        Public Selected As Boolean
        '=============================
        '----- END EDITED ------------
        '=============================
 
        ''' <summary>Array of TreeNodeData objects representing the root nodes in a TreeView.</summary>
        Public Nodes() As TreeNodeData
 
        ''' <summary>
        ''' Creates new instance of the TreeNodeData structure based on the specified TreeNode.
        ''' </summary>
        ''' <param name="node">TreeNode to build the TreeNodeData instance from.</param>
        Public Sub New(ByVal node As TreeNode)
            'Set the basic TreeNode properties
            Me.Text = node.Text
            Me.ImageIndex = node.ImageIndex
            Me.SelectedImageIndex = node.SelectedImageIndex
            Me.Checked = node.Checked
            Me.Expanded = node.IsExpanded
 
            '=============================
            '----- START EDITED ----------
            '=============================
            Me.Selected = node.IsSelected
            '=============================
            '----- END EDITED ------------
            '=============================
 
            'See if there is an object in the tag property and if it is serializable
            If (Not node.Tag Is Nothing) AndAlso node.Tag.GetType.IsSerializable Then Me.Tag = node.Tag
 
            'Check to see if there are any child nodes
            If node.Nodes.Count = 0 Then Exit Sub
 
            'Recurse through child nodes and add to Nodes array
            ReDim Nodes(node.Nodes.Count - 1)
            For i As Integer = 0 To node.Nodes.Count - 1
                Nodes(i) = New TreeNodeData(node.Nodes(i))
            Next
        End Sub
 
        ''' <summary>
        ''' Returns as TreeNode built from the instance of the TreeNodeData object.
        ''' </summary>
        Public Function ToTreeNode() As TreeNode
            'Create TreeNode based on instance of TreeNodeData and set basic properties
            ToTreeNode = New TreeNode(Me.Text, Me.ImageIndex, Me.SelectedImageIndex)
            ToTreeNode.Checked = Me.Checked
            ToTreeNode.Tag = Me.Tag
            If Me.Expanded Then ToTreeNode.Expand()
 
            '=============================
            '----- START EDITED ----------
            '=============================
            If Me.Selected Then tn = ToTreeNode
            '=============================
            '----- END EDITED ------------
            '=============================
 
            'Recurse through child nodes adding to Nodes collection
            If Me.Nodes Is Nothing OrElse Me.Nodes.Length = 0 Then Exit Function
 
            For i As Integer = 0 To Me.Nodes.Length - 1
                ToTreeNode.Nodes.Add(Me.Nodes(i).ToTreeNode())
            Next
 
        End Function
 
    End Structure
 
#End Region
 
#Region "Public"
 
    ''' <summary>
    ''' Populates the specified TreeView from the serialized TreeViewData structure file specified.
    ''' </summary>
    ''' <param name="treeView">TreeView instance to populate.</param>
    ''' <param name="path">Serialized Xml representation of TreeViewData</param>
    Public Shared Sub LoadTreeViewData(ByVal treeView As TreeView, ByVal path As String)
        'Create as serializer and get the file to deserialize
        Dim ser As New System.Xml.Serialization.XmlSerializer(GetType(TreeViewData))
        Dim file As New System.IO.FileStream(path, IO.FileMode.Open)
        Dim reader As New System.Xml.XmlTextReader(file)
 
        'Deserialize the file and populate the treeview
        Dim treeData As TreeViewData = CType(ser.Deserialize(reader), TreeViewData)
        treeData.PopulateTree(treeView)
 
        'Tidy up
        reader.Close()
        file.Close()
        file = Nothing
    End Sub
 
    ''' <summary>
    ''' Saves the specified TreeView in serialized TreeViewData structure file specified.
    ''' </summary>
    ''' <param name="treeView">TreeView instance to save.</param>
    ''' <param name="path">Path to store serialized file.</param>
    Public Shared Sub SaveTreeViewData(ByVal treeView As TreeView, ByVal path As String)
        'Create as serializer and file to save TreeViewData
        Dim ser As New System.Xml.Serialization.XmlSerializer(GetType(TreeViewData))
        Dim file As New System.IO.FileStream(path, IO.FileMode.Create)
        Dim writer As New System.Xml.XmlTextWriter(file, Nothing)
 
        'Generate TreeViewData from TreeView and serialize the file.
        ser.Serialize(writer, New TreeViewData(treeView))
 
        'Tidy up
        writer.Close()
        file.Close()
        file = Nothing
    End Sub
 
#End Region
 
End Class