[RESOLVED] Detect what container a control is in

How can you step thru each control on a form and determine if it is in a container or not and what container it is in?

Something like this perhaps. It makes the assumption that if the Control doesn't have a Container Property then it is contained by the Form. (Not sure if that's a valid assumption or not)

Code:

---

Dim ctl As Control
For Each ctl In Controls
    Debug.Print ctl.Name; " ";
    On Error Resume Next
    Debug.Print ctl.Container
    If Err.Number <> 0 Then
        Debug.Print Me.Name
    End If
Next

---

No that does not work... I tried that. The problem is that if a container is inside a container that test fails...

This is what I have tried:

VB Code:

Option Explicit
 
Private Sub Form_Load()
Dim ctl As Control
Dim sStr As String
 
    On Error Resume Next
    
    For Each ctl In Controls
    
        Err.Clear
        sStr = ctl.Container
        If Err.Number = 0 And sStr <> "" Then
            sStr = "In a Container - " & sStr & " - " & ctl.Parent.Name
        Else
            sStr = "A Container"
        End If
        Debug.Print ctl.Name & " - " & sStr
        
    Next
    
End Sub

This works for me when I have Frames within Frames, Frames within PictureBoxes
(Edit: and PictureBoxes in Frames and PictureBoxes in PictureBoxes))

Code:

---

Dim ctl As Control
For Each ctl In Controls
    Debug.Print ctl.Name; " ";
    On Error Resume Next
    Debug.Print ctl.Container.Name
    If Err.Number <> 0 Then
        Debug.Print Me.Name
    End If
Next

---

Example output:
Frame4 Form1
Picture2 Frame4
Picture3 Picture2
Picture1 Form1
Frame3 Picture1
Frame1 Form1
Frame2 Frame1
Label1 Frame1
txtKey Form1
MSComm1 Form1
Command1 Form1

The 'clue' is to use the Name property of the Container

Another variation...

Code:

---

Option Explicit

Private Sub Command1_Click()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        Debug.Print "Control: " & ctrl.Name & " has a container of - " & TypeName(ctrl.Parent)
    Next
End Sub

'Control: Frame1 has a container of - Form1
'Control: Check1 has a container of - Form1
'Control: Text1 has a container of - Form1
'Control: Command1 has a container of - Form1
'Control: Label1 has a container of - Form1

---

RobDog888: I get strange results with your variation

Code:

---

Control: Command1 has a container of - Form1
Control: Picture1 has a container of - Form1
Control: Picture2 has a container of - Form1
Control: Picture3 has a container of - Form1
Control: Frame1 has a container of - Form1
Control: Text1 has a container of - Form1
Control: Timer1 has a container of - Form1
Control: cmdDown has a container of - Form1
Control: cmdUp has a container of - Form1
Control: List1 has a container of - Form1

---

But with my version

Code:

---

Private Sub Form_Load()
Dim ctl As Control
For Each ctl In Controls
    Debug.Print ctl.Name; " is contained in ";
    On Error Resume Next
    Debug.Print ctl.Container.Name
    If Err.Number <> 0 Then
        Debug.Print Me.Name
    End If
Next
End Sub

---

I get:

Code:

---

Command1 is contained in Form1
Picture1 is contained in Form1
Picture2 is contained in Picture1
Picture3 is contained in Picture2
Frame1 is contained in Picture3
Text1 is contained in Form1
Timer1 is contained in Form1
cmdDown is contained in Form1
cmdUp is contained in Form1
List1 is contained in Form1

---

There's a subtle difference between Container and Parent.
(BTW the results from my code refect the real situation)

A parent and a container are similar. It depends on what randem is needing. Also what controls and how they are set on a form.

If a control is on a form then its parent is the form but it is also contained in the form too. If he only wants controls that can host other controls then dont use my code. I have no idea and am not psychic as to what and how your controls are on your form. As I said its a variation to give him options, not an improvement f the code you posted.

The problem is that is a container is inside a container VB no longer considers it a container by these methods. This is my testing for this:

vb Code:

Option Explicit
 
Private Sub Form_Load()
Dim ctl As Object
Dim sStr As String
 
    On Error Resume Next
    
    For Each ctl In Controls
    
        Err.Clear
        sStr = ctl.Container
        
        If Err.Number = 0 And sStr <> "" Then
            sStr = "In a Container - " & sStr & " - " & ctl.Parent.Name
            Debug.Print ctl.Name & " - " & sStr
        Else
            CheckContainer ctl
            
        End If
        
    Next
    
End Sub
 
Private Sub CheckContainer(Container As Object)
Dim ctl As Object
Dim sStr As String
Dim i As Integer
 
 
    On Error Resume Next
    
    Debug.Print vbCrLf & "Container - " & Container.Name
    
    For i = 0 To Container.Controls.Count - 1
    
        Err.Clear
        sStr = Container.Controls(i).Name
        
        If Err.Number = 0 And sStr <> "" Then
            CheckContainer ctl
        Else
            Debug.Print sStr
        End If
    Next
    
End Sub

but if you use .Parent and check if its not the form itself and check if its a .Container from the parent level it may tell you what you want to know.

ctl.Parent.Container fails on everything.

I must be missing the point.
I don't understand this statement: "The problem is that is (sic) a container is inside a container VB no longer considers it a container by these methods"

Code:

---

Private Sub Form_Load()
Dim ctrl As Control
For Each ctrl In Controls
    Call FindContainer(ctrl)
    Debug.Print
Next ctrl
End Sub

Private Sub FindContainer(ctrl As Object)
Dim objCtrl As Object
On Error Resume Next
If ctrl.Container.Name <> "" Then
    If Err.Number = 0 Then
        On Error GoTo 0
        Set objCtrl = ctrl.Container
        Call FindContainer(objCtrl)
        Debug.Print "->"; ctrl.Name;
    Else
        On Error GoTo 0
        Debug.Print ctrl.Name;
    End If
End If
End Sub

---

Will show each control's position within the 'hierarchy' of containers
eg
I have a Form with a TextBox, and a Frame. Within the Frame I have a PictureBox, within that PictureBox I have a Textbox and another PictureBox

The results I get are :

Form1->Frame1
Form1->Frame1->Picture1
Form1->Frame1->Picture1->Picture2
Form1->Frame1->Picture1->Text2
Form1->Text1

What am I missing?

Hes saying that he can not detect a nested container. Your code is not doing a test for container but just looping through the controls on a form.

I think this is more of what he is asking for. Simple code. Since no containers at the form level can have a container (as the form itself is a type of container) the second level of nested containers will come up correct all the way down.

Code:

---

Option Explicit

Private Sub Command1_Click()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        If TypeName(ctrl.Container) <> Me.Name Then
            Debug.Print "Control: " & ctrl.Name & " has a container of - " & ctrl.Container
        Else
            Debug.Print "Control: " & ctrl.Name & " has a container of - " & TypeName(ctrl.Container)
        End If
    Next
End Sub
'Control: Text1 has a container of - Form1
'Control: Frame1 has a container of - Form1
'Control: Frame2 has a container of - Frame1
'Control: Command1 has a container of - Frame2

---

Doogle,

You are missing nothing, it was me who was missing something. It was all in the technique use to find the answer.

Thanks

Quote:

---

Your code is not doing a test for container

---

I think it is

Code:

---

On Error Resume Next
If ctrl.Container.Name <> "" Then
    If Err.Number = 0 Then

---

If the control doesn't have a container then Err.Number <> 0

Anyway, glad it's sorted.

On Error Resume Next is never a good way to handle errors.

When you get into larger projects using that technique it can lead to many unforseen issues which increases your debugging time and throw your budgeted timeline way out of wack.

That's why I used On Error GoTo 0 as soon as I had examined the Err Object.

In this case the only error that could be generated is "438 Object does not support this property or method" which means that there is no container. I think that, when used correctly, On Error Resume Next is handy to perform in-line error checking. (But I emphasise "when used correctly")

No it doesnt mean that as I explained the control could reside on the Form which is not a Container but rather a host which is similar to a container. the Form contains controls but its from a different logic/design.

RobDog888,

You method has some flaws for this type of window:

Code:

---

Control: Frame2 has a container of - Form1
Control: Frame3 has a container of - Frame2
Control: Picture2 has a container of - Frame3
Control: Drive1 has a container of - 0
Control: Frame1 has a container of - Form1
Control: Text1 has a container of - Frame1
Control: Picture1 has a container of - Frame1
Control: Command1 has a container of - 0

---

Ah close it was says I :D

Seems the picturebox control is throwing it off. Hmm.

While Doogle's code for the same window shows:

Code:

---

Form1->Frame1
Form1->Frame1->Picture1
Form1->Frame1->Picture1->Command1
Form1->Frame1->Text1
Form1->Frame2
Form1->Frame2->Frame3
Form1->Frame2->Frame3->Picture2
Form1->Frame2->Frame3->Picture2->Drive1

---

Hmm, it worked for me.

Picturebox at form level and a picturebox nested inside frame 2.

Code:

---

Control: Picture1 has a container of - Form1
Control: Text1 has a container of - Form1
Control: Frame1 has a container of - Form1
Control: Frame2 has a container of - Frame1
Control: Picture2 has a container of - Frame2
Control: Command1 has a container of - Frame2

---

I duplicated your object heirarchy and fixed it simply with a typename call.

Code:

---

Option Explicit

Private Sub Command1_Click()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        Debug.Print "Control: " & ctrl.Name & " has a container of - " & TypeName(ctrl.Container)
    Next
End Sub

Control: Frame2 has a container of - Form1
Control: Frame3 has a container of - Frame2
Control: Picture1 has a container of - Frame3
Control: Drive1 has a container of - PictureBox
Control: Frame1 has a container of - Form1
Control: Text1 has a container of - Frame
Control: Picture2 has a container of - Frame
Control: Command1 has a container of - PictureBox

---

Ok, now that worked somewhat, it just doesn't tell me the actual name of the container.

But if I do this it does...

vb Code:

Private Sub Command1_Click()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        If TypeName(ctrl.Container) <> Me.Name Then
            Debug.Print "Control: " & ctrl.Name & " has a container of - " & ctrl.Container.Name
        Else
            Debug.Print "Control: " & ctrl.Name & " has a container of - " & ctrl.Container.Name
        End If
    Next
End Sub

Code:

---

Control: Frame2 has a container of - Form1
Control: Frame3 has a container of - Frame2
Control: Picture2 has a container of - Frame3
Control: Drive1 has a container of - Picture2
Control: Frame1 has a container of - Form1
Control: Text1 has a container of - Frame1
Control: Picture1 has a container of - Frame1
Control: Command1 has a container of - Picture1

---

Well its closer then before and alot shorter :D The typename is getting the type of the object to prevent the "0" Container display. Multiple ways to skin a cat. You can choose or mix/match as you need. :)

I had edited my code previously. So here is the addition of your part with my edit. Massivly complex code!!! :D

:thumb:

Code:

---

Option Explicit

Private Sub Command1_Click()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        Debug.Print "Control: " & ctrl.Name & " has a container of - " & ctrl.Container.Name
    Next
End Sub

---