Printable View
I used commondialog. Why It open the files not the folder? I just want to show the folder not the files inside the folder
Code:Private Sub Command1_Click()
Dim shape As String
shape = "ESRI Shapefiles (*.shp) |*.shp"
CommonDialog1.CancelError = True
On Error GoTo FileOpenCancel
CommonDialog1.Filter = shape
CommonDialog1.DialogTitle = "Lokasi Pangkalan data"
CommonDialog1.ShowOpen
outputfile = CommonDialog1.fileName
FileOpenCancel:
Exit Sub
End Sub
It does that because that is what the common dialog is designed to do.
If you don't want the files to be shown why are you adding a "shape" filter?
Oh, I no idea about how to point out the working directory location. I have create manually the directory let say in this location C:\Project\Database.. How I can select this location using browse or something that able me to search this location
You just want to browse for folders or do you just need to know if it exists?
I have create the folder "database" first manually before run the VB.. let say I create the folder inside this directory C:\Project.
How I can find this folder I have created using browse method? I have idea about using drivelistbox but I don't know how to used it
To browse for folders you can use something likeCode:Private Const BIF_RETURNONLYFSDIRS = &H1
Private Const BIF_DONTGOBELOWDOMAIN = &H2
Private Const BIF_STATUSTEXT = &H4
Private Const BIF_RETURNFSANCESTORS = &H8
Private Const BIF_EDITBOX = &H10
Private Const BIF_VALIDATE = &H20
Private Const BIF_BROWSEFORCOMPUTER = &H1000
Private Const BIF_BROWSEFORPRINTER = &H2000
Private Const BIF_BROWSEINCLUDEFILES = &H4000
Private Const MAX_PATH = 260
Private Type T_BROWSEINFO
HwndOwner As Long
pIDLRoot As Long
pszDisplayName As Long
lpszTitle As Long
ulFlags As Long
lpfnCallback As Long
lParam As Long
iImage As Long
End Type
Private Declare Function SHBrowseForFolder Lib "shell32" _
(lpbi As T_BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" _
(ByVal pidList As Long, _
ByVal lpBuffer As String) As Long
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" _
(ByVal lpString1 As String, ByVal _
lpString2 As String) As Long
Public Function BrowseFolder(ByVal HwndOwner As Long, ByRef Titre As String) As String
Dim lpIDList As Long
Dim sBuffer As String
Dim BrowseInfo As T_BROWSEINFO
BrowseFolder = ""
With BrowseInfo
.HwndOwner = HwndOwner
.lpszTitle = lstrcat(Titre, "")
.ulFlags = BIF_RETURNONLYFSDIRS
End With
lpIDList = SHBrowseForFolder(BrowseInfo)
If (lpIDList) Then
sBuffer = Space(MAX_PATH)
SHGetPathFromIDList lpIDList, sBuffer
sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
BrowseFolder = sBuffer
End If
End Function
How I can use this function?:eek: What the object required?
Just do something likeCode:BrowseFolder Me.hWnd, "My Folder List"
Thank you so much!!!!.
How it can show the selected folder location in the textbox?
Private Sub Command1_Click()
BrowseFolder Me.hWnd, "My Folder List"
End Sub
After select the folder, I click ok..
How I can get the "corrupt shp" path location? and show it in the textbox
Since BrowseFolder is a function you need to use variable and assign return value to it:
Code:myPath = BrowseFolder(Me.hWnd, "My Folder List")
If Not myPath = "" Then
'...
Emd If
Hi, Hack.. How I can modify this title "Browse for folder" to another name?
I don't understand what you mean.Quote:
Originally Posted by matrik02
How to change this title name "Browse for folder" to another name
I think he means change the Title bar text of the dialog, tho not sure why anyone would want to change it, it is a "browse for folder" dialog, why confuse things by changing it?:confused:
Because I want to change to my local language :D
How do I add a "new folder" to the left of the OK and Cancel buttons?
You need to pass another flag to BrowseInfo type:
Code:Private Const BIF_NEWDIALOGSTYLE = &H40
Many thanks :-)
Hmmm, I added it in the same section as similar lines (those that started "Private Const BIF_") and it doesn't seem to make a difference, I still don't get a "new folder" icon :-)
Your list of flags may look like this:
Code:Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2
Private Const BIF_EDITBOX = &H10
Private Const BIF_VALIDATE = &H20
Private Const BIF_NEWDIALOGSTYLE = &H40
Private Const BIF_BROWSEFORCOMPUTER = &H1000
'-------------------
With tBrowseInfo
.hWndOwner = Me.hWnd
.ulFlags = BIF_RETURNONLYFSDIRS & BIF_DONTGOBELOWDOMAIN & _
BIF_EDITBOX & BIF_VALIDATE & BIF_NEWDIALOGSTYLE & _
BIF_BROWSEFORCOMPUTER
End With
I am using the exact same code as listed near the top by Hack.
It has ".ulFlags = BIF_RETURNONLYFSDIRS" which I replaced with ".ulFlags = BIF_RETURNONLYFSDIRS & BIF_NEWDIALOGSTYLE" and it hasn't made any difference...BIF_NEWDIALOGSTYLE is in the list of CONSTs.
This is all stuff I've not done before, as you can guess :-)
Sorry, my mistake :blush: - you need to use th OR operator. Also, for simplicity you may declare another const that is a combination of several other:
That should do it.Code:Private Const BIF_SHOWMAKENEW As Long = (BIF_NEWDIALOGSTYLE Or BIF_EDITBOX)
With tBrowseInfo
.hWndOwner = Me.hWnd
.ulFlags = BIF_RETURNONLYFSDIRS
.ulFlags = .ulFlags Or BIF_SHOWMAKENEW
End With
Under the browseinfo (tBrowseInfo in your example) I changed the AND to OR so it read ".ulFlags = BIF_RETURNONLYFSDIRS Or BIF_NEWDIALOGSTYLE" and that worked fine first time...many thanks :-)
No problem. :afrog: