[2005] Saving important data

I am familiar with saving data such as strings and ints to XML files and such but what if the data is important? Such as an int representing what level the character is on in your game? You cannot simply put that in an XML file. Encryption comes to mind but really, whatever you come up with someone will hack and exploit. Also, you must deal with decryption and is really a waste IMO. Surely there must be a better way?

I was thinking about storing the values IN the exe. Would such a thing be fine for this sort of thing? Also, decompiling DLL's seems to be almost impossible. Should I just write and read to and from a DLL?

(I'm not going to have a server so please don't suggest it)

I'd really like to hear some nice, clean suggestions on performing such a task as I don't really want 10 seperate classes just for writing and reading what level a character is on.

I'm sure other people have encountered this problem before? What did you do?

Thanks

Millions of software applications and computer users the world over use encryption all the time. Maybe you just don't understand it properly.

I have good and simple codes, comes with encryption, and decryption...

all you do is

Public Wrapper As New Simple3Des("PasswordForUniqueness")

Code:

---

Dim EncryptText As String = Wrapper.Encrypt("mytext")
Dim DecryptText As String = Wrapper.Decrypt(EncryptText)

---

(and if you want to make it even simpler, you can create a function to read and write to a stream/file, so that you don't have to keep calling Wrapper.Encrypt etc..
It's just

Code:

---

WriteToStream(FileStream, Text)

---

The code is this:

(Note I have made a modification to the Encrypt/Decrypt function to make sure the length of the value provided is greater than 0)

vb.net Code:

#Region " [Cryptography] "
    Public NotInheritable Class Simple3Des
        Private TripleDes As New TripleDESCryptoServiceProvider
 
        Sub New(ByVal key As String)
            ' Initialize the crypto provider.
            TripleDes.Key = TruncateHash(key, TripleDes.KeySize \ 8)
            TripleDes.IV = TruncateHash("", TripleDes.BlockSize \ 8)
        End Sub
 
        Private Function TruncateHash( _
ByVal key As String, _
ByVal length As Integer) _
As Byte()
 
            Dim sha1 As New SHA1CryptoServiceProvider
 
            ' Hash the key.
            Dim keyBytes() As Byte = _
                System.Text.Encoding.Unicode.GetBytes(key)
            Dim hash() As Byte = sha1.ComputeHash(keyBytes)
 
            ' Truncate or pad the hash.
            ReDim Preserve hash(length - 1)
            Return hash
        End Function
 
        Public Function EncryptData( _
        ByVal plaintext As String) _
        As String
            If plaintext.Length > 0 Then
 
                ' Convert the plaintext string to a byte array.
                Dim plaintextBytes() As Byte = _
                    System.Text.Encoding.Unicode.GetBytes(plaintext)
 
                ' Create the stream.
                Dim ms As New System.IO.MemoryStream
                ' Create the encoder to write to the stream.
                Dim encStream As New CryptoStream(ms, _
                    TripleDes.CreateEncryptor(), _
                    System.Security.Cryptography.CryptoStreamMode.Write)
 
                ' Use the crypto stream to write the byte array to the stream.
                encStream.Write(plaintextBytes, 0, plaintextBytes.Length)
                encStream.FlushFinalBlock()
 
                ' Convert the encrypted stream to a printable string.
                Return Convert.ToBase64String(ms.ToArray)
            Else
                Return ""
            End If
        End Function
 
        Public Function DecryptData( _
        ByVal encryptedtext As String) _
        As String
            If encryptedtext.Length > 0 Then
 
                ' Convert the encrypted text string to a byte array.
                Dim encryptedBytes() As Byte = Convert.FromBase64String(encryptedtext)
 
                ' Create the stream.
                Dim ms As New System.IO.MemoryStream
                ' Create the decoder to write to the stream.
                Dim decStream As New CryptoStream(ms, _
                    TripleDes.CreateDecryptor(), _
                    System.Security.Cryptography.CryptoStreamMode.Write)
 
                ' Use the crypto stream to write the byte array to the stream.
                decStream.Write(encryptedBytes, 0, encryptedBytes.Length)
                decStream.FlushFinalBlock()
 
                ' Convert the plaintext stream to a string.
                Return System.Text.Encoding.Unicode.GetString(ms.ToArray)
            Else
                Return ""
            End If
        End Function
    End Class
#End Region

Just import these:

Code:

---

Imports System
Imports System.Drawing
Imports System.Drawing.Imaging
Imports System.Char
Imports System.IO
Imports System.Security
Imports System.Security.Cryptography
Imports System.Text

---

(Some are not necessary, but the Cryptography one is the important one I think)

Cheers

If it's important encrypt it. There are encryption methods out there now that take years for programs to decrypt without the correct method.

If you want the easiest but non secure way, just use XML files, but rename it to something unfamiliar (ex: data.wll, xyz.abc). Therefore, they wouldn't know what file is about unless they curious and open it in a text editor.

If you want a secure way, you should use encryption. .NET provide encryption technology in security namespace.

Alright, I suppose I will use encryption. Thanks everyone.