[RESOLVED] MSChart- Simple example or explaination needed.

Does anyone have a simple example of creating a chart in VB that I can try to follow? I don't know where to start. I've searched for this and found a few but they have been far more comprehensive than what I need. I just need something simple to replicate the attached image.

Would the MSChart be the best control to do this?

Yes use MSChart for that. Place one on your charts on a form and inside the properties go to custom and click the ... you will be able to format it to match what you have above.

set data like:

VB Code:

Form1.MSChart1.Data = 40

Thanks ggettings, rightclicking on the chart for properties opens up a number of options. Starting to play with them now

If I have two arrays of X and Y values for the two different lines, how do I use them for input? Two lines, different colours, and possibly a legend as I have above.

Think of it like a msflexgrid with rows and cols.
Adding colums will automatically give your new line a different color.

rowcount is the number of intervals
colcount is the numner of lines

try something like this:

VB Code:

dim i as integer
i = 0
 
Do Until i > your max array size
 
    mschart1.column = 1
    mschart1.row = i
    mschart1.data = val(i)
 
    i = i + 1
Loop

Thanks for the help but I'm still not quite following this. Why are the three variables? Is column the X coordinate and row the Y coordinate and then what is data?

I tried this in an XY scatter chart but oddly when I run it it just shows as the demo control.

VB Code:

Private Sub Form_Load()
    MSChart1.Column = 1
    MSChart1.Row = 1
    MSChart1.Data = 1
    MSChart1.Column = 2
    MSChart1.Row = 2
    MSChart1.Data = 2
End Sub

Sgrya1:

The MSChart control has many visible parts, all of which can be programmed.

Each of these parts has a corresponding object in the MSChart control which can be used to change the format of practically any element of your chart.

For example, the code below dramatically changes the look of a chart by changing the colors of the Plot object.

VB Code:

Private Sub cmdFormat_Click()
   ' First, change the chart type to a 3D chart to
   ' see all the parts of the plot.
   MSChart1.chartType = VtChChartType3dArea
 
   ' Color the backdrop light blue using 
   ' the Plot object.
   With MSChart1.Plot.Backdrop 
      ' No color will appear unless you set the style 
      ' property to VtFillStyleBrush.
      .Fill.Style = VtFillStyleBrush
      .Fill.Brush.FillColor.Set 100, 255, 200
      ' Add a border.
      .Frame.Style = VtFrameStyleThickInner
      ' Set style to show a shadow. 
      .Shadow.Style = VtShadowStyleDrop    
   End With
 
   ' Color the wall of the plot yellow.
   With MSChart1.Plot 
      ' Set the style to solid.
      .Wall.Brush.Style = VtBrushStyleSolid 
      ' Set the color to yellow.
      .Wall.Brush.FillColor.Set 255, 255, 0
   End With
   
   With MSChart1.Plot ' Color the plot base blue.
      .PlotBase.BaseHeight = 200
      .PlotBase.Brush.Style = VtBrushStyleSolid
      .PlotBase.Brush.FillColor.Set 0, 0, 255
   End With
End Sub

A very basic task with fonts might be to set the text of the chart's title. In order to do this, use the Title object's Text property:

VB Code:

MSChart1.Title.Text = "Year End Summary"

This is simple enough. The next question is how to change the font's attributes.

In order to format any text attribute on the chart, you must use the VtFont object. For example, to format the title, the following code will work:

VB Code:

With MSChart1.Title.VtFont
   .Name = "Algerian"
   .Style = VtFontStyleBold
   .Effect = VtFontEffectUnderline
   .Size = 14
   .VtColor.Set 255, 0, 255
End With

You can use the same technique with other parts of chart. The only difference lies in the object model. For example, to format the text attributes of the Legend area use the following code:

VB Code:

MSChart1.Legend.VtFont.Size = 18

To change the scale of the plot, you must specify that the y axis of the chart is going to be changed (changing the x axis has no visible effect). A convenient way to change the scale is to use a ComboBox control, as shown in the following code:

VB Code:

Private Sub Form_Load()
   ' Configure a ComboBox control named cmbScale.
   With cmbScale
      .AddItem "Log"
      .AddItem "Percent"
      .AddItem "Linear"
      .ListIndex = 0
   End With
End Sub
 
Private Sub cmbScale_Click()
   ' The ComboBox has three items: Log, Percent,
   ' and Linear (the default scale).
 
   Select Case cmbScale.Text
   Case "Log"
      MSChart1.Plot.Axis(VtChAxisIdY) _
      .AxisScale.Type = VtChScaleTypeLogarithmic
 
      ' You must specify a LogBase to be used when
      ' switching the scale to Log. The base can be 
      ' set to any value between 2 and 200.
      MSChart1.Plot.Axis(VtChAxisIdY).AxisScale _
      .LogBase = 10    
 
   Case "Percent"
      MSChart1.Plot.Axis(VtChAxisIdY).AxisScale _
      .Type = VtChScaleTypePercent
      ' Set the PercentBasis to one of six types. For
      ' the sake of expediency, only one is shown.
      MSChart1.Plot.Axis(VtChAxisIdY).AxisScale _
      .PercentBasis = VtChPercentAxisBasisMaxChart
 
   Case "Linear"
      MSChart1.Plot.Axis(VtChAxisIdY).AxisScale _
      .Type = VtChScaleTypeLinear
   End Select
End Sub

AIS4U, Thanks for that. There's a lot there that I can access by right clicking the chart and selecting properties but there does seem to be some formatting properties that aren't directly accessible.
I don't need to change too much of the chart format at runtime other than adding chart lines and changing the chart scales. Do you have any suggestions on how to do this?

I found this. Anyone know how to add a second line to a chart though? The second overrides the first when I try.

VB Code:

Private Sub Form_Load()
         Dim Graph(1 To 10, 1 To 2) As Single
         Dim x As Integer
         For x = 1 To 10
            Graph(x, 1) = x   ' value for X-axis
            Graph(x, 2) = x * 10 ' value for Y-axis
         Next x
         MSChart1.chartType = VtChChartType2dXY  ' set to X Y Scatter chart
         MSChart1 = Graph ' populate chart's data grid using Graph array
         ' Leave the following line commented until step 6:
         MSChart1.Plot.UniformAxis = False
      End Sub

Found this very comprehensive code too. Problem solved.

VB Code:

Option Explicit
'**************************************
'Windows API/Global Declarations for :Creating 2D XY scatter charts on an unbound MSChart Control
'**************************************
 
'This example shows how to plot multiple X-Y scatter graphs, also known as 2D XY, on an unbound MS Chart
'control. X-Y scatter graphs differ from other types because the associated DataGrid object needs
'2 columns per series, rather than just one. The first column for each series stores the X values, and
'the second one stores the Y values. Another difference is that if the # of plot points differs
'between multiple series, you have to remove the null points of the shorter series.
'Instructions: Add the MSChart control to your toolbox, then add it to a form. For clarity, try to make
'it at least 8 inches wide, by 5 inches tall, on the form. then, paste this code into
'the code window, and run.
'written by W. Baldwin, 8/2001
 
'OldRowCount keeps track of how many points have been plotted for the previous series, so we can remove
'null points from all the series that are shorter:
Dim OldRowCount As Long
'PenColor determines whether we are drawing in color or Black & White
'Black & White is for black and white printers, and uses different line patterns to distinguish series.
'ShowMarker is a flag that determines whether each plot point has a marker or not.
Dim PenColor As Boolean, ShowMarker As Boolean
'ChartPoints is the array that will hold the plot data
Dim ChartPoints() As Double
Dim lRow As Long, lRow2 As Long
Dim i As Integer, MsgPrompt As String
Dim XValue As Single, YValue As Single
 
Private Sub Form_Load()
    With MSChart1
        .chartType = VtChChartType2dXY
        .ShowLegend = True
 
        With .Plot.Axis(VtChAxisIdY).AxisTitle
            .VtFont.Size = 12
            .Visible = True
            .Text = "Y Axis text"
        End With
 
        With .Plot.Axis(VtChAxisIdX).AxisTitle
            .VtFont.Size = 12
            .Visible = True
            .Text = "X Axis text"
        End With
        .Title.VtFont.Size = 12
        .Title = "Example 2D XY Scatter Graph"
        .Legend.Location.LocationType = VtChLocationTypeBottom
        .Plot.Axis(VtChAxisIdY).AxisScale.Type = VtChScaleTypeLinear
        .Plot.Axis(VtChAxisIdX).AxisScale.Type = VtChScaleTypeLinear
        'Tip from KB article Q194221:
        .Plot.UniformAxis = False
        .Footnote.Text = "Footnote goes here"
    End With
    PenColor = True 'Draw In color
    ShowMarker = True 'Show plot points
    ChartIt 1
    PenColor = False 'Black and White
    ShowMarker = False 'Don't show plot points
    ChartIt 2
End Sub
 
 
Private Sub ChartIt(CurSeries As Integer)
    MousePointer = 11
    'Create a new array of plot points for this Series
    'We will redim the first subscript differently, to show that each series can have a different # of plot points:
 
    If CurSeries = 1 Then
        ReDim ChartPoints(1 To 15, 1 To 2)
    Else
        ReDim ChartPoints(1 To 10, 1 To 2)
    End If
    'Create the array data:
 
    For lRow = 1 To UBound(ChartPoints, 1)
        'create the X and Y values:
        XValue = lRow + Rnd * 2
        YValue = lRow + Rnd * 2
        'create negative values for the 2nd series:
 
        If CurSeries = 2 Then
            XValue = XValue * -1
            YValue = YValue * -1
        End If
        ChartPoints(lRow, 1) = XValue
        ChartPoints(lRow, 2) = YValue
    Next lRow
    'We need to increase the ColumnCount. For X-Y Scatter graphs, we need 2 columns for each series.
    MSChart1.ColumnCount = CurSeries * 2
 
    With MSChart1
        With .Plot
            .Wall.Brush.Style = VtBrushStyleSolid
            'Normally, you might want the Wall background of the Chart
            'to be in color, if you're using Color pens, and to be white
            'if using B&W pens, but, since we're drawing both a color
            'series *and* a B&W series on *one* chart, we'll just make
            'the wall color, for now. If you want White, uncomment the
            'line found about 10 lines down:
            .Wall.Brush.FillColor.Set 255, 255, 225
 
            If PenColor Then
                .Wall.Brush.FillColor.Set 255, 255, 225
                'You can set the individual Pen colors here, or just use
                'the defaults.
            Else 'Based on an article In the VB KB:
                'Uncomment the next line if you want the wall color to
                'be white:
                '.Wall.Brush.FillColor.Set 255, 255, 255
                '
                'Set the different patterns for Black and White plotting.
                'You need to set the Pen for only the 'X column:
 
                Select Case CurSeries * 2 - 1
                    Case 1
                    .SeriesCollection(1).Pen.Style = VtPenStyleSolid
                    .SeriesCollection(1).Pen.VtColor.Set 0, 0, 0
                    Case 3
                    .SeriesCollection(3).Pen.Style = VtPenStyleDashed
                    .SeriesCollection(3).Pen.VtColor.Set 0, 0, 0
                    Case 5
                    .SeriesCollection(5).Pen.Style = VtPenStyleDotted
                    .SeriesCollection(5).Pen.VtColor.Set 0, 0, 0
                    Case 7
                    
                    .SeriesCollection(7).Pen.Style = VtPenStyleDitted
                    .SeriesCollection(7).Pen.VtColor.Set 0, 0, 0
                End Select
        End If
    End With
    .ColumnLabelCount = CurSeries * 2
    'If the current series has more plot points that the previous
    'one, we need to change .RowCount accordingly:
 
    If UBound(ChartPoints, 1) > OldRowCount& Then
        .RowCount = UBound(ChartPoints, 1)
    End If
    'Both of the next 2 lines seem to do thesame thing:
    .Plot.SeriesCollection(CurSeries * 2 - 1).SeriesMarker.Show = ShowMarker
    .Plot.SeriesCollection.Item(CurSeries * 2 - 1).SeriesMarker.Show = ShowMarker
    'Create the plot points for this series from the ChartPoints array:
 
    For lRow = 1 To UBound(ChartPoints, 1)
        .DataGrid.SetData lRow, CurSeries * 2 - 1, ChartPoints(lRow, 1), False
        .DataGrid.SetData lRow, CurSeries * 2, ChartPoints(lRow, 2), False
    Next
    'Remove null points from *this* series,if it has *fewer*
    'points than the prior ones. If you don't remove null points,
    'then the graph will add 0,0 points, erroneously. See MS
    'Knowledge Base article Q177685 for more info:
 
    For lRow2 = lRow To OldRowCount&
        .DataGrid.SetData lRow2, CurSeries * 2 - 1, 0, True
        .DataGrid.SetData lRow2, CurSeries * 2, 0, True
    Next
    'Remove null points from *prior* series,if this series
    'has *more* points than the prior ones:
 
    If CurSeries > 1 Then
        For lRow = OldRowCount& + 1 To .RowCount
            For lRow2 = 1 To CurSeries - 1
                .DataGrid.SetData lRow, lRow2 * 2 - 1, 0, True
                .DataGrid.SetData lRow, lRow2 * 2, 0, True
            Next
        Next
    End If
    'Store the current RowCount
    OldRowCount& = .RowCount
    .Column = CurSeries * 2 - 1
    .ColumnLabel = "Series " & Str(CurSeries)
    .Refresh
End With
 
SubExit:
    MousePointer = 0
End Sub
 
 
Private Sub Command1_Click()
    'If you want to be able to print the chart, just
    'add a Command1 button that calls this event.
    MsgPrompt = "Make sure that device " & Printer.DeviceName & " is ready"
    i = MsgBox(MsgPrompt, vbOKCancel, "Confirmation")
 
    If i = vbCancel Then
        Exit Sub
    End If
    On Error GoTo ErrHandler
    MSChart1.EditCopy
    Printer.Print " "
    Printer.PaintPicture Clipboard.GetData(), 0, 0
    Printer.EndDoc
    Exit Sub
ErrHandler:
    i = MsgBox("An Error has occurred. Make sure your selected printer can print graphics.", vbOKOnly, "Error")
    Resume Next
End Sub