Right Click Mouse

Hi Currently i'm have Activex Control made by some one else (textbox with some advanced properties and event added). From it documentation, i found it was made based on VB standard Textbox. The problem is, it's mousedown and mouseup event doesn't work (not fire at all, the event does exist). Since i like it and using it a lot in my program, so i want to add event my own mousedown and my own mouseup event by made User Control based on this activex.
My question is how to add event on user control and how to detect mousedown and mouseup using API or whatever it take :). Sample attached will be very helpfull.

Thanks.

BA

Sorry to "bump" this question up.
Perhaps anyone on different timezone is now already up and online can give me a hands.

Thanks

Create the events yourself. Use the following:

VB Code:

Public Event MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
 
Public Event MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

You can then intercept the messages WM_LBUTTONDOWN and WM_LBUTTONUP and use the RaiseEvent() statement to tell you application to fire the event.

Thanks Jenova

After dig the net for while i got almost same with your suggestion, but i still don't know when exact time and how to intercept WM_LBUTTONDOWN and WM_LBUTTONUP on my current user control?

FYI, i'm still novice in VB programming.

Do you have the source code for the ActiveX control? If so, just make sure it exposes the textbox's MouseDown event (as Jenova showed you). If they aren't exposed your program won't see them, so you'll have to subclass the ActiveX control and intercept the messages for any MouseDown or MouseUp on the control.

You can SubClass the control by using the CallWindowProc() and SetWindowLong() API Statements. Then write your own windowprocedure that intercepts the messages and processes them the way you want to.

Check out the AllApi link in my sig for a definition of these API's and examples on how to use them.

Al42:
I don't have source code.

Jenova:
I don't know how to subclass it. Sorry if i'm just to whine but sample from you guys (if you got time) will be very helpful.

Thanks

Here you go, this is how subclassing a text box control would happen, you may need to modify the code slightly, if you don't have the code then we cant ammend it for you. Hope this is of some help:

VB Code:

'
' You will need a project with 
' 1 x Form
' 1 x Text Box
' 1 x Module
 
' *** IN A MODULE ***
 
Option Explicit
 
Private Declare Function CallWindowProc _
    Lib "user32" _
    Alias "CallWindowProcA" ( _
        ByVal lpPrevWndFunc As Long, _
        ByVal hwnd As Long, _
        ByVal Msg As Long, _
        ByVal wParam As Long, _
        ByVal lParam As Long) _
        As Long
        
Private Declare Sub CopyMemory _
    Lib "kernel32" _
    Alias "RtlMoveMemory" ( _
        Destination As Any, _
        Source As Any, _
        ByVal Length As Long)
        
Private Declare Function SetWindowLong _
    Lib "user32" _
    Alias "SetWindowLongA" ( _
        ByVal hwnd As Long, _
        ByVal nIndex As Long, _
        ByVal dwNewLong As Long) _
        As Long
 
Private Const GWL_WNDPROC = (-4)
 
Private Const WM_RBUTTONDOWN    As Long = &H204
Private Const WM_RBUTTONUP      As Long = &H205
 
Private OldWindowProc           As Long
 
Public Sub HookWindow(txtTextBox As TextBox)
    ' Set the new window procedure to monitor the text boxes message queue. When our
    ' message is found it is picked out of the queue and proccess by our window
    ' procedure, any other messages are left alone and are processed by the original
    ' window procedure.
    OldWindowProc = SetWindowLong(txtTextBox.hwnd, GWL_WNDPROC, AddressOf NewWindowProc)
End Sub
 
Public Sub UnhookWindow(txtTextBox As TextBox)
    ' Restore the old window procedure and cease monitoring the
    ' the message queue.
    SetWindowLong txtTextBox.hwnd, GWL_WNDPROC, OldWindowProc
    If OldWindowProc Then
        OldWindowProc = 0
    End If
End Sub
 
Private Function NewWindowProc(ByVal hwnd As Long, ByVal Msg As Long, _
                                                ByVal wParam As Long, ByVal lParam As Long) As Long
 
    Select Case Msg
        
        ' Intercept the right mouse button being released
        Case WM_RBUTTONUP
            
            ' Process the message the way we want. If you comment the code in the form and run
            ' the application, right click on the text box, you will see the default text box
            ' menu. However now that we have intercepted the message we are altering it to do
            ' WE want it to do, in this instance, we are generating a message box.
            MsgBox "Put the code that you want here when the user right clicks", vbInformation
            
            ' MSDN tells us to return 0 when ever we procces a message
            NewWindowProc = 0
            
        Case Else
            
            ' Restore the default handling for other messages. Remember that the text box
            ' will be recieving other messages to process. We are not interested in these
            ' so we let the default window procedure process them, not ours.
            NewWindowProc = CallWindowProc(OldWindowProc, hwnd, Msg, wParam, lParam)
    
    End Select
 
End Function
 
' *** IN A FORM ***
Option Explicit
 
Private Sub Form_Load()
    ' Hook the textbox
    HookWindow Text1
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    ' Unhook the textbox
    UnhookWindow Text1
End Sub

I will try it.

Will let you know later jenova.

PS: How to put your code above if i made user control based on this control (which doesn't have mousedown and mouseup event). User control doesn't have form, where should i put HookWindow procedure?

I'm not sure, i have never made a User Control before. I would imagine that you would still need to add it to the form that your control is on, either that, i think user controls have 'Initialize' or 'Activate' events. just hook the window from that point in the control.

Jenova, it doesnt work. No error produce but it never met this condition

VB Code:

select Case Msg
         ' Intercept the right mouse button being released
        Case WM_RBUTTONUP, WM_RBUTTONDOWN

Quote:

---

Originally Posted by barianto

Jenova, it doesnt work. No error produce but it never met this condition

VB Code:

select Case Msg
         ' Intercept the right mouse button being released
        Case WM_RBUTTONUP, WM_RBUTTONDOWN

---

If your using it with the control you have then i am ot sure how to get around it. But it should be

VB Code:

Select Case Msg
         ' Intercept the right mouse button being released
        Case WM_RBUTTONUP
  
            ' Process message here
 
End Select

Have you tried searching Google for Subclassing ActiveX Controls in Visual Basic 6

I will try searching on goole then :)

I add "WM_RBUTTONDOWN" just in case it will hit, but still doesn't wor.

Use Spy++/Classy/WinID to get the handle of the textbox and then subclass it (Classy can actually write code for you).

As it is created with VB, the textbox's class will be ThunderTextBox or ThunderRT6TextBox.

Once you get the handle you can easily subclass it by following previous examples.

He doesn't need to use Spy++ or any other application for that matter, the text box has a .hWnd property.

If I understood correctly, the Custom-TextBox-Control has a VB6 textbox inside it.

In that case the hWnd exposed by the ActiveX control is NOT the handle of the VB6TextBox inside it.
So, directly hooking the VB6Textbox MAY work.

I think, the parent hierarchy is something like this,

Code:

---

Form (ThunderFormDC)
|__ UserControl (ThunderUserControlDC)
        |__TextBox (ThunderTextBox)

---

(That is what looks like when you create your own usercontrol with a textbox and place it on a form. For an 'external' ActiveX control it should be similar.)

I'm not sure if it will work. But as directly hooking the control isn't working, there is no harm trying this. :D

thanks, jenova, iPrank
will try it (iPrank suggestion)

For the record. This was actually easier than i thought :D. I'm not sure if you have done this but here you go this is how you subclass the textbox on the ActiveX control. FindWindow was not necesary for the control.

VB Code:

' 
' For this application to work you will need
' 1 x Form
' 1 x Module
' 1 x User Control w/ Text Box Control on it
'
 
' Module Code
Option Explicit
 
Private Declare Function CallWindowProc _
    Lib "user32" _
    Alias "CallWindowProcA" ( _
        ByVal lpPrevWndFunc As Long, _
        ByVal hwnd As Long, _
        ByVal Msg As Long, _
        ByVal wParam As Long, _
        ByVal lParam As Long) _
        As Long
        
Private Declare Sub CopyMemory _
    Lib "kernel32" _
    Alias "RtlMoveMemory" ( _
        Destination As Any, _
        Source As Any, _
        ByVal Length As Long)
        
Private Declare Function SetWindowLong _
    Lib "user32" _
    Alias "SetWindowLongA" ( _
        ByVal hwnd As Long, _
        ByVal nIndex As Long, _
        ByVal dwNewLong As Long) _
        As Long
 
Private Const GWL_WNDPROC = (-4)
 
Private Const WM_RBUTTONUP      As Long = &H205
 
Private OldWindowProc           As Long
 
Public Sub HookWindow(txtTextBox As TextBox)
    ' Set the new window procedure to monitor the text boxes message queue. When our
    ' message is found it is picked out of the queue and proccess by our window
    ' procedure, any other messages are left alone and are processed by the original
    ' window procedure.
    OldWindowProc = SetWindowLong(txtTextBox.hwnd, GWL_WNDPROC, AddressOf NewWindowProc)
End Sub
 
Public Sub UnhookWindow(txtTextBox As TextBox)
    ' Restore the old window procedure and cease monitoring the
    ' the message queue.
    SetWindowLong txtTextBox.hwnd, GWL_WNDPROC, OldWindowProc
    If OldWindowProc Then
        OldWindowProc = 0
    End If
End Sub
 
Private Function NewWindowProc(ByVal hwnd As Long, ByVal Msg As Long, _
                                                ByVal wParam As Long, ByVal lParam As Long) As Long
 
    Select Case Msg
        
        ' Intercept the right mouse button being released
        Case WM_RBUTTONUP
            
            ' Process the message the way we want. If you comment the code in the form and run
            ' the application, right click on the text box, you will see the default text box
            ' menu. However now that we have intercepted the message we are altering it to do
            ' WE want it to do, in this instance, we are generating a message box.
            MsgBox "Put the code that you want here when the user right clicks", vbInformation
            
            ' MSDN tells us to return 0 when ever we procces a message
            NewWindowProc = 0
            
        Case Else
            
            ' Restore the default handling for other messages. Remember that the text box
            ' will be recieving other messages to process. We are not interested in these
            ' so we let the default window procedure process them, not ours.
            NewWindowProc = CallWindowProc(OldWindowProc, hwnd, Msg, wParam, lParam)
    
    End Select
 
End Function
 
' Form  Code
 
Option Explicit
 
Private Sub UserControl_Initialize()
    HookWindow Text1
End Sub
 
Private Sub UserControl_Resize()
    With Text1
        .Height = UserControl.Height
        .Width = UserControl.Width
    End With
End Sub
 
Private Sub UserControl_Terminate()
    UnhookWindow Text1
End Sub