[RESOLVED] Finding Partial Text Within A ListBox

lets say i have a textbox and a listbox, Text1 and List1. List 1 is filled with many words. and what i want to do is, whenever the user starts typing in Text1, it starts taking him to the place in List1. for instance

user types: "r", it would take him to the first R in the list. then the user entered another letter, so now the user has the following

user has: "ru", so now the listbox is in the "ru" place, then he types "n" and it takes him to the place where all the run's are.

i guess kind of like how you press F1 in VB6, and you use its index search. or something like that. how would i do this?

if u need clarifications, just ask.

Hmm Let me check for "r" and then "ru"...

the following code will take to directly to list1 if there is a match

VB Code:

Private Sub Text1_Change()
    List1.Text = Text1.Text
End Sub

for example if list1 has "asdfgh" and if you type "asdfgh" in text1 then "asdfgh" in list1 will get highlighted...

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
Const LB_FINDSTRING = &H18F
Private Sub Text1_Change()
    'Retrieve the item's listindex
    List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))
End Sub

Quote:

---

Originally Posted by Andrew G

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
Const LB_FINDSTRING = &H18F
Private Sub Text1_Change()
    'Retrieve the item's listindex
    List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))
End Sub

---

exactly what i wanted :). thanks a ton. but now, this is a totally diff question, when the user is searching for those things, how would i eliminate (basicly remove from listbox) the items in the listbox that dont have anything in commen with what the user is searching? and then if the user presses backspace, it shows him his possibilitys. heres an example (btw, this does have 2 do with my question, its not different)

exp:
List1 items:
A
Allie
Cool
Sweet

now, lets say the user typed "A", it would remove cool and sweet, now if the user typed "al", it would remove everything that doesn't have "al" in it. then, if the user presses backspace and goes back to have "A", i want the "A" and "Allie" to both be showing, and if he has nothing in his textbox, then all items show again. if u need clarification, again, ask.

The only way i can think of to do something like this, is to have all the items in an array, then loop all the available items, and only add the ones that match each time. But with a lot of items, and the possibility of having the listbox keep refreshing as items are added, it could slow down the program. Maybe there is an easier way to what you want to achieve.

ya, an array is the way i would do it too. there are 1355 items in it. and the fact that it would slow down the program, makes sense. if anyone knows how 2 do this an easier way that doesn't slow down the program as much, post :).

Quote:

---

Originally Posted by koolsid

Hmm Let me check for "r" and then "ru"...

the following code will take to directly to list1 if there is a match

VB Code:

Private Sub Text1_Change()
    List1.Text = Text1.Text
End Sub

for example if list1 has "asdfgh" and if you type "asdfgh" in text1 then "asdfgh" in list1 will get highlighted...

---

That's not what he's asking for.

Quote:

---

Originally Posted by GRPsuper9

exactly what i wanted :). thanks a ton. but now, this is a totally diff question, when the user is searching for those things, how would i eliminate (basicly remove from listbox) the items in the listbox that dont have anything in commen with what the user is searching? and then if the user presses backspace, it shows him his possibilitys. heres an example (btw, this does have 2 do with my question, its not different)

exp:
List1 items:
A
Allie
Cool
Sweet

now, lets say the user typed "A", it would remove cool and sweet, now if the user typed "al", it would remove everything that doesn't have "al" in it. then, if the user presses backspace and goes back to have "A", i want the "A" and "Allie" to both be showing, and if he has nothing in his textbox, then all items show again. if u need clarification, again, ask.

---

you would need to, when you add the items to a list, create a string of all the items separated by a common dilimiter. Then, every time something is typed in the textbox, split the saved string by the delimiter and scan through it to see if any of them start with what is contained in the text box and add them to the list. Upon changing the textbox(be it adding or deleting a character), you'd have to remember to clear the list before scanning the string and adding the matches ;D

Quote:

---

Originally Posted by Andrew G

The only way i can think of to do something like this, is to have all the items in an array, then loop all the available items, and only add the ones that match each time. But with a lot of items, and the possibility of having the listbox keep refreshing as items are added, it could slow down the program. Maybe there is an easier way to what you want to achieve.

---

****. Wish I would have ready this prior to my last post :\

Quote:

---

Originally Posted by GRPsuper9

ya, an array is the way i would do it too. there are 1355 items in it. and the fact that it would slow down the program, makes sense. if anyone knows how 2 do this an easier way that doesn't slow down the program as much, post :).

---

That's the only way I think you could do it, really.

cuz ive seen many other programs, i forgot the names, but ive seen them do it, where they eliminate the things from the list, without lagging.

If the item array is sorted in alphabetical order, it might improve the speed as you don't need to sort through every item. Once you can't find any more matches then you wouldn't need to continue searching the array. Also if the items are all known, you could further improve the speed by making it search for matches from known positions, for example if you know that all entries starting with a 'T' start at item 400 then you could search from 400 to 500 (if thats for 'U'), hence you don't need to go through the first 400 and the ones after 500.

I can't say for sure how it would work for a huge list but maybe something like this will work for you.

VB Code:

Private Sub Form_Load()
    List1.AddItem "Peaches"
    List1.AddItem "Nectarines"
    List1.AddItem "Pears"
    List1.AddItem "Quinces"
    List1.AddItem "Cherries"
    List1.AddItem "Apricots"
    List1.AddItem "Apples"
    List1.AddItem "Plums"
    List1.AddItem "Figs"
    List1.AddItem "Kiwis"
    List1.AddItem "Olives"
    List1.AddItem "Clementine"
    List1.AddItem "Kumquat"
    List1.AddItem "Minneola"
    List1.AddItem "Mandarin"
    List1.AddItem "Orange"
    List1.AddItem "Satsuma"
    List1.AddItem "Tangarine"
    List1.AddItem "Tangelo"
    List1.AddItem "Lemon"
    List1.AddItem "Rough Lemon"
    List1.AddItem "Lime"
    List1.AddItem "Leech Lime"
    List1.AddItem "Grapefruit"
    List1.AddItem "Pummelo"
    List1.AddItem "Sweety"
    List1.AddItem "Ugli"
End Sub
 
Private Sub Text1_Change()
Dim i As Integer
 
    For i = List1.ListCount - 1 To 0 Step -1
        If UCase(Left(List1.List(i), Len(Text1.Text))) <> UCase(Text1.Text) Then
            List1.RemoveItem i
        End If
    Next i
End Sub

This may still have heaps of bugs etc, but it should be close to what you need.
Edit: Tested it with a large listbox but was too slow. It didn't refresh often, but it was still too slow

Code:

---

       

VB Code:

       

'NOTE: Make sure Listbox is sorted

 
Option Explicit

 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long

Private Declare Function LockWindowUpdate Lib "user32" (ByVal hwndLock As Long) As Long

 
Const LB_FINDSTRING = &H18F

 
Dim ListBoxItems() As String

Const Letters As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"

Dim LetterPos(1 To 26) As Long

 
Dim PrevTextLen As Long

 
 
Private Sub Form_Load()

Dim Itm As Long

Dim CurrentLetter As String

Dim PrevLetter As String

 
 
    'Add Items

    List1.AddItem "Peaches"

    List1.AddItem "Nectarines"

    List1.AddItem "Pears"

    List1.AddItem "Quinces"

    List1.AddItem "Cherries"

    List1.AddItem "Apricots"

    List1.AddItem "Apples"

    List1.AddItem "Plums"

    List1.AddItem "Figs"

    List1.AddItem "Kiwis"

    List1.AddItem "Olives"

    List1.AddItem "Clementine"

    List1.AddItem "Kumquat"

    List1.AddItem "Minneola"

    List1.AddItem "Mandarin"

    List1.AddItem "Orange"

    List1.AddItem "Satsuma"

    List1.AddItem "Tangarine"

    List1.AddItem "Tangelo"

    List1.AddItem "Lemon"

    List1.AddItem "Rough Lemon"

    List1.AddItem "Lime"

    List1.AddItem "Leech Lime"

    List1.AddItem "Grapefruit"

    List1.AddItem "Pummelo"

    List1.AddItem "Sweety"

    List1.AddItem "Ugli"

 
   

    'We now add them all to an array. Since we sorted first, it makes it easier

    ReDim ListBoxItems(1 To List1.ListCount) As String

    

    For Itm = 1 To List1.ListCount

        CurrentLetter = Left(List1.List(Itm), 1)

        If CurrentLetter <> PrevLetter And Len(CurrentLetter) > 0 Then

            LetterPos(InStr(1, Letters, CurrentLetter, vbTextCompare)) = Itm

            PrevLetter = CurrentLetter

        End If

        ListBoxItems(Itm) = List1.List(Itm - 1)

    Next

End Sub

 
Private Sub Text1_Change()

Dim FirstLetter As String

Dim UpperRange As Integer

Dim LowerRange As Integer

Dim Itm As Integer

Dim x As Long

Dim RemItem As Long

Dim r As Long

 
LockWindowUpdate List1.hwnd

If Len(Text1) = 0 Then      'There is nothing in the textbox so we have to write all items again

 
    List1.Clear

    For Itm = 1 To UBound(ListBoxItems)

        List1.AddItem ListBoxItems(Itm)

    Next

 
ElseIf Len(Text1) < PrevTextLen Then

    'We deleted something

        

    List1.Clear

    

    FirstLetter = Left(Text1, 1)

    

    'Get Range

    LowerRange = LetterPos(InStr(1, Letters, FirstLetter, vbTextCompare))

    

    For x = InStr(1, Letters, FirstLetter, vbTextCompare) + 1 To 26 Step 1

        If Not LetterPos(x) = 0 Then

            UpperRange = LetterPos(x)

            Exit For

        End If

    Next

    

    If LowerRange < 1 Or UpperRange < 1 Then

        PrevTextLen = Len(Text1)

        LockWindowUpdate 0

        Exit Sub

    End If

    

    For r = LowerRange To UpperRange

        If InStr(1, ListBoxItems(r), Text1, vbTextCompare) = 1 Then

            List1.AddItem ListBoxItems(r)

        End If

    Next

 
 
ElseIf Len(Text1) = 1 Then

'First Letter, so we remove all unwanted items before and after it

'Should be a bit faster than having to check each item has the text or not

 
    FirstLetter = Left(Text1, 1)

    

    If LetterPos(InStr(1, Letters, FirstLetter, vbTextCompare)) < 1 Then

        List1.Clear

        PrevTextLen = Len(Text1)

        LockWindowUpdate 0

        Exit Sub

    End If

    

    'Get Range

    LowerRange = LetterPos(InStr(1, Letters, FirstLetter, vbTextCompare))

        If LowerRange = 1 Then LowerRange = 0

    

    For x = InStr(1, Letters, FirstLetter, vbTextCompare) + 1 To 26 Step 1

        If Not LetterPos(x) = 0 Then

            UpperRange = LetterPos(x)

            Exit For

        End If

    Next

        If UpperRange = 0 Then UpperRange = List1.ListCount

    

    'Remove all those after it

    For RemItem = UpperRange To List1.ListCount - 1 Step 1

        List1.RemoveItem UpperRange

    Next

    

    'Remove all those before it

    For RemItem = 1 To LowerRange Step 1

        List1.RemoveItem 0

    Next

    

    

ElseIf Len(Text1) > 1 Then

    'Remove items using a loop now. Anything that doesn't match

    For r = List1.ListCount - 1 To 0 Step -1

        'When we look at the item string,

        'we must make sure that the text we wrote starts at pos 1

        If InStr(1, List1.List(r), Text1, vbTextCompare) <> 1 Then

            List1.RemoveItem r

        End If

    Next

End If

 
PrevTextLen = Len(Text1)

LockWindowUpdate 0

 
'Retrieve the item's listindex

List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))

End Sub

---

I also borrowed MarkT's list items :p

here's my go.

it uses three ListBoxes

lstFull - Sorted = True, contains full list
lstPart - used to show the matches - in exactly the same position as lstFull
lstRev - Visible = False, the full list reversed.

and this is the search code:

VB Code:

Private Sub Text1_Change()
    Dim lAsc As Long, lStart As Long, lEnd As Long
    Dim sText As String
    
    If Trim$(Text1.Text) = vbNullString Then lstFull.ZOrder: Exit Sub
    
    sText = UCase$(Trim$(Text1.Text))
    
    lAsc = Asc(sText)
    lStart = lIndex(lAsc - 65)
    
    lstPart.Clear
    If (lStart = 0) And Not (lAsc = 65) Then
        lstPart.AddItem "No Matches"
    Else
        For lAsc = lAsc + 1 To 90
            If lIndex(lAsc - 65) > 0 Then lEnd = lIndex(lAsc - 65) - 1: Exit For
        Next
        If lAsc > 90 Then lEnd = lstFull.ListCount - 1
        
        lStart = SendMessage(lstFull.hwnd, LB_FINDSTRING, lStart - 1, ByVal sText)
        If lStart > -1 Then
            For lAsc = lStart To lstRev.ListCount - SendMessage(lstRev.hwnd, LB_FINDSTRING, _
                                                      lstRev.ListCount - lEnd - 2, ByVal sText) - 1
                lstPart.AddItem lstFull.List(lAsc)
            Next lAsc
        Else
            lstPart.AddItem "No Matches"
        End If
    End If
    lstPart.ZOrder
End Sub

it's instantaneous with 30000 items, and, more importantly, it never has to repopulate the full list.

i've attached it so you can see what i mean about the three ListBoxes.

An awesome bit of code Bush :thumb:, heaps faster than my try :p

Nice Bush it's fast! Good Job.

what is this program for?

Very nice but is there a way to limit to 1 listbox instead of 3? as it seems unprofessional that way :D