[RESOLVED]write/check file

Hello,

How can I make an .vbs file that does this:
Check if there is a hello.txt file with "hello" in it, if yes, give messagebox, if no, give messagebox and create/write the file.

A sort of cookie system in vbscript, but it wil not be used on the web, just on my computer.

Thanks in advance,
Thomas

VB Code:

'Code file for "hello.vbs"
 
Dim fso, flspec, fl, flcontents
 
'First create fso (FileSystemObject)
Set fso = CreateObject("Scripting.FileSystemObject")
 
'Now look for file C:\hello.txt
If fso.FileExists("C:\hello.txt") Then
     'Get file to check size
     Set flspec = fso.GetFile("C:\hello.txt")
     If flspec.Size > 0 Then 
          'File size > 0 so file contains something
      Set fl = fso.OpenTextFile("C:\hello.txt", 1, False)
          flcontents = fl.ReadAll() 
          fl.Close
     Else 
      'File size is 0 so nothing in file
          flcontents = ""
     End If
     'Check file contents for "hello"
     If flcontents = "hello" Then
          '"hello" found
          MsgBox("The file contatins hello!")
     Else
      '"hello" not found, but file exists
          CreateHelloFile()
          MsgBox("The file did not have hello in it.")
     End If
Else
     '"C:\hello.txt did not exist
     CreateHelloFile()
     MsgBox("The file did not exist.")
End If
 
'Kill all objects
Set fl = Nothing
Set flspec = Nothing
Set fso = Nothing
 
Function CreateHelloFile()
     'Function that creates txt file C:\hello.txt and writes "hello" in it
     Set fl = fso.OpenTextFile("C:\hello.txt", 2, True)
     fl.Write("hello")
     fl.Close
End Function

Thank you! :thumb:

no problem, don't forget to mark the thread resolved.