[RESOLVED] winmm.dll keeps causing Errors and Crashes?

Hello,

I get vb to play a sound upon Mouse_Over via the sndPlaySound function.

All fine, it plays sounds BUT, cos there are a couple of command button
on t he form (3-4) and when you move the mouse over all of them, the sound is played and then the program causes a Crash!! Stating winmm.dll caused the error.

Is there a better way of handling sounds??

I have to same error but only running under Windows XP when I play a sound from a resource file. :sick:

VB Code:

Const SND_MEMORY = &H4 
Const SND_ASYNC = &H1
Const SND_NODEFAULT = &H2
 
Public Declare Function sndPlaySound Lib "winmm.dll" Alias _
"sndPlaySoundA" (ByVal lpszSoundName As String, _
ByVal uFlags As Long) As Long
 
Public Sub PlaySound(Soundname As String) 'ResData
 
Dim SoundBuffer As String
    
SoundBuffer = StrConv(LoadResData(Soundname, "WAVE"), vbUnicode)
Call sndPlaySound(SoundBuffer, SND_MEMORY Or SND_ASYNC Or SND_NODEFAULT)
 
End Sub

Quote:

---

Originally Posted by some1uk03

Is there a better way of handling sounds?

---

Give us a clue and post your code ;). You could use mciSendString or mciExecute - but if your sounds are stored in a res file, you have to create temporary files from them first.

Quote:

---

Originally Posted by Keithuk

I have to same error but only running under Windows XP when I play a sound from a resource file.

---

Try using PlaySound instead of sndPlaySound.

You may both find the problem disappears if you purge the sound file from memory before trying to play it again.

VB Code:

Option Explicit
 
'Form level code.
 
'YOU MUST COMPILE TO AN EXECUTABLE TO MAKE IT WORK !!!
'-----------------------------------------------------
 
Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
   (ByVal lpszName As Long, ByVal hModule As Long, ByVal dwFlags As Long) As Long
 
'Required constants.
Const SND_ASYNC = &H1 'Play asynchronously.
Const SND_RESOURCE = &H40004 'Name is a resource name or atom.
Const SND_PURGE = &H40 'Release memory.
 
Private Sub mnuMusic_Click(Index As Integer)
    Dim RetVal As Long
     
'Reference nothing and purge memory.
   RetVal = PlaySound(0, App.hInstance, SND_PURGE)
 
'Reference the res file and ... Top Of The Pops ...
   RetVal = PlaySound(101, App.hInstance, SND_RESOURCE Or SND_ASYNC)
End Sub

Does anyone know the difference between

VB Code:

Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
(ByVal lpszName As String, ByVal hModule As Long, _
ByVal dwFlags As Long) As Long
 
Private Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" _
(ByVal lpszSoundName As String, ByVal uFlags As Long) As Long

sndPlaySound is the API call thats been used for many years. When did PlaySound come about? It has the extra call App.hInstance for ByVal hModule As Long.

Quote:

---

Originally Posted by schoolbusdriver

but if your sounds are stored in a res file, you have to create temporary files from them first.

---

I don't think you don't have to extract the wave file before you play them. I've never seen any in Windows\Temp or App.Path. Its the same as putting bmp's, cur's and ico's in a resource file. You just extract them directly to your app. You have to extract jpg's and gif's to a temp file and any other Custom addin.

SCHOOLBUSDRIVER, sorry but ur code doesnt work for me.

I get no sound back, even when i compile my app.

VB Code:

mSound = StrConv(LoadResData(102, "SOUND"), vbUnicode)
       PlaySound mSound, App.hInstance, flags&

and also whats the difference between,

sndPlaySound & PlaySound ?

Quote:

---

Originally Posted by Keithuk

When did PlaySound come about? It has the extra call App.hInstance for ByVal hModule As Long.

---

Not sure, but it's been around for a while. MS says sndPlaySound is a cut down version of PlaySound, so which came first ;). It may have been an *undocumented* API initially. MS are good at that.

Quote:

---

Originally Posted by Keithuk

...don't have to extract the wave...

---

My fuzzy - I was referring to mciSendString and mciExecute.

Quote:

---

Originally Posted by some1uk03

I get no sound back, even when i compile my app.

VB Code:

mSound = StrConv(LoadResData(102, "SOUND"), vbUnicode)
       PlaySound mSound, App.hInstance, flags&

and also whats the difference between,

sndPlaySound & PlaySound ?

---

1) Did you try my code, and not your own ?? You don't need "mSound = StrConv(LoadResData(102, "SOUND"), vbUnicode)"

2) See above.

Quote:

---

Originally Posted by schoolbusdriver

You don't need "mSound = StrConv(LoadResData(102, "SOUND"), vbUnicode)"

---

Thats alright providing he is using a resource file as well as me. He hasn't said how he is playing a wave file.

@schoolbusdriver - your code doesn't work for me either, type mismatch. :sick:

VB Code:

Call PlaySound(App.Path & "\Chimes.wav", _
App.hInstance, SND_RESOURCE Or SND_ASYNC)

Quote:

---

Originally Posted by Keithuk

Thats alright providing he is using a resource file as well as me. He hasn't said how he is playing a wave file.

@schoolbusdriver - your code doesn't work for me either, type mismatch. :sick:

VB Code:

Call PlaySound(App.Path & "\Chimes.wav", _
App.hInstance, SND_RESOURCE Or SND_ASYNC)

---

As some1uk03's using "LoadResData" (post 6), one can only assume... :p

The code I posted is specifically for playing wav files from a res file - specified by SND_RESOURCE - not from HDD... (post 2) ;)

Actually, I've gone through this before. If you look at Re: VB6 Embed audio - posts 14 - 20 inclusive, it shows the pitfalls...

This is somewhat strange. I've just tried rapid repeated playback (with several PlaySound code combinations) using a variety of wav files. Some will play back repeatedly without problems, and some won't.

E.g, - "wmpaud1.wav", (which comes with media player) at 347KB repeats OK, as do all files lager than this. "nudge.wav", at 169KB doesn't.

Even using a wav file editor to increase "nudge.wav"'s file size to 502KB didn't work, so the playback and repeated playback failures appears to be related to the file's format :rolleyes: .

Not a solution, but at least a partial reason...

Quote:

---

Does anyone know the difference between

visual basic code:
Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
(ByVal lpszName As Long, ByVal hModule As Long, ByVal dwFlags As Long) As Long

Private Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" _
(ByVal lpszSoundName As String, ByVal uFlags As Long) As Long

---

Ok i figured it out.

the PlaySound Function requires a LONG as you can see (ByVal lpszName As Long)
Which is what Schoolbusdriver was saying and from hes point of view is correct. I got it working.

Where As:

sndPlaySound Function requires a STRING as you can see (ByVal lpszSoundName As String)
Which means you could use the StrConv(LoadResData(101, "SOUND"), vbUnicode) function to convert the .RES data to a string and play it back.

I know it's marked as resolved, but as a final bit of info:

VB Code:

'Note the different ways you can call PlaySound & sndPlaySound, depending
'on whether you want to pass a number or string.
 
'PlaySound.
'Pass a String reference to lpszName.
Private Declare Function PlaySoundString Lib "winmm.dll" Alias "PlaySoundA" _
   (ByVal lpszName As String, ByVal hModule As Long, ByVal dwFlags As Long) As Long
 
'Pass a Long Resource reference to lpszName.
Private Declare Function PlaySoundResource Lib "winmm.dll" Alias "PlaySoundA" _
   (ByVal lpszName As Long, ByVal hModule As Long, ByVal dwFlags As Long) As Long
 
 
'sndPlaySound.
'Pass a String reference to lpszSoundName.
Private Declare Function sndPlaySoundString Lib "winmm.dll" Alias "sndPlaySoundA" _
   (ByVal lpszSoundName As String, ByVal uFlags As Long) As Long
 
'Pass a Long Resource reference to lpszSoundName.
Private Declare Function sndPlaySoundLong Lib "winmm.dll" Alias "sndPlaySoundA" _
   (ByVal lpszSoundName As Long, ByVal uFlags As Long) As Long