screen res

Hi everybody
I recently created a vb app. using a desktop resolution of 1024x768. I made the form to fit the page in a windowed state but when I installed on a 800x600 res the form was bigger than the screen. Is there a way of getting the form to adjust to whatever the users current res is ?
Thanks!

The following works in 98% of situtations but it has a few minor bugs. You can try it and see if your situtation works.
Only problem is it retains the original size so you must design your form for the smallest size and then the code will stretch it to the largest. It doesn't go backward.
Will not help the current situtation but it may help you in a future endevor.'resize as per secreen resolution
'general declaration of form

Code:

---

'create a class module and put this code into it
'set the name property of the object as clsElasticForms
'save as clsElastic

Option Explicit

' Title:    Elastic Forms
' Author:  Leigh Bowers
' Email:    [email protected]
' WWW:      http://www.esheep.freeserve.co.uk/compulsion
' Version:  1.01
' Date:    19th June 1999
' Requires: N/A
' License:  Freely Distributable (non-commercial use)

Private fForm As Form

Private lOriginalWidth As Long
Private lOriginalHeight As Long

Private lMinWidth As Long
Private lMinHeight As Long

Private Type udtControl
    lLeft As Long
    lTop As Long
    lWidth As Long
    lHeight As Long
End Type
Private aControls() As udtControl

Public Property Let Form(ByVal fPassForm As Form)
   
Dim iCount As Integer
Dim cControl As Control

    Set fForm = fPassForm
   
    ' Store form's original Width & Height
   
    lOriginalWidth = fForm.Width
    lOriginalHeight = fForm.Height

    ' Use error trapping to ignore components that don't
    ' support certain properties being read at run-time

    On Error Resume Next

    ' Store the form's component's properties

    iCount = 0
    ReDim aControls(fForm.Controls.Count)

    For Each cControl In fForm.Controls
        iCount = iCount + 1
        With aControls(iCount)
            If TypeOf cControl Is Line Then
                .lLeft = cControl.X1
                .lTop = cControl.Y1
                .lWidth = cControl.X2
                .lHeight = cControl.Y2
            Else
                .lLeft = cControl.Left
                .lTop = cControl.Top
                .lWidth = cControl.Width
                .lHeight = cControl.Height
            End If
        End With
    Next ' Each

End Property

Public Sub FormResize()

    ' v1.01 (19/06/1999)
    '
    ' bDisableResize:
    ' Used to avoid unnecessary *recursive* resizing
    '
    ' lPreviousWidth/Height:
    ' Used to avoid unnecessary resizing

    ' Resize the form's controls

Dim iCount As Integer
Dim cControl As Control
Dim iTaskBarHeight As Integer
Dim sOriginalWidthUnit As Single
Dim sOriginalHeightUnit As Single
Static bDisableResize As Boolean
Static lPreviousWidth As Long
Static lPreviousHeight As Long

    If fForm Is Nothing Or bDisableResize Then Exit Sub

    ' Don't process minimized forms
   
    If fForm.WindowState = vbMinimized Then Exit Sub

    ' Check form size against minimums
   
    bDisableResize = True
    If fForm.Width < lMinWidth Then fForm.Width = lMinWidth
    If fForm.Height < lMinHeight Then fForm.Height = lMinHeight
    bDisableResize = False
   
    ' Ensure form size has changed
   
    If lPreviousWidth = fForm.Width And lPreviousHeight = fForm.Height Then Exit Sub
    lPreviousWidth = fForm.Width
    lPreviousHeight = fForm.Height

    ' Perform calculations in advance (speed increase)

    iTaskBarHeight = 28 * Screen.TwipsPerPixelY ' Standard height
    sOriginalWidthUnit = lOriginalWidth / fForm.Width
    sOriginalHeightUnit = (lOriginalHeight - iTaskBarHeight) / (fForm.Height - iTaskBarHeight)

    ' Use error trapping to ignore components that don't
    ' support certain properties being set at run-time

    On Error Resume Next

    ' Do the resize...
   
    iCount = 0

    For Each cControl In fForm.Controls
        iCount = iCount + 1
        With cControl
            If TypeOf cControl Is Line Then
                .X1 = Int(aControls(iCount).lLeft / sOriginalWidthUnit)
                .Y1 = Int(aControls(iCount).lTop / sOriginalHeightUnit)
                .X2 = Int(aControls(iCount).lWidth / sOriginalWidthUnit)
                .Y2 = Int(aControls(iCount).lHeight / sOriginalHeightUnit)
            Else
                .Left = Int(aControls(iCount).lLeft / sOriginalWidthUnit)
                .Top = Int(aControls(iCount).lTop / sOriginalHeightUnit)
                .Width = Int(aControls(iCount).lWidth / sOriginalWidthUnit)
                .Height = Int(aControls(iCount).lHeight / sOriginalHeightUnit)
            End If
        End With
    Next ' Each

End Sub


Private Sub Class_Terminate()

    Set fForm = Nothing

End Sub




Public Property Let MinWidth(ByVal lPassMinWidth As Long)

    lMinWidth = lPassMinWidth

End Property
Public Property Let MinHeight(ByVal lPassMinHeight As Long)

    lMinHeight = lPassMinHeight

End Property

'====================================================================
 
' in the general declarations of each form in your application

Option Explicit

Private clsElastic As clsElasticForms

'====================================================================

'this goes in the form load event of each form in app

    Set clsElastic = New clsElasticForms
    clsElastic.Form = Me
    clsElastic.MinHeight = 1950
    clsElastic.MinWidth = 6960

'====================================================================

'this goes in the form resize event of each form in app
'resize as per secreen resolution
 
clsElastic.FormResize

'====================================================================

'this goes in the Form_Unload(Cancel As Integer) of each form
'in the app
'resize as per secreen resolution
 
Set clsElastic = Nothing

---