ListView

Can anyone tell me how to get my code to work in a listview please.

VB Code:

Option Explicit
Dim mPerson As PersonalInfo
Dim mFileNum As Integer
Dim mRecordLen As Long
Dim mCurrentRecord As Long
Dim mLastRecord As Long
Dim ShiftTest As Integer
 
Private Sub cmdSave_Click()
 
    MsgBox ("Members Saved"), vbInformation, "Douglas Lads Club"
 
    SaveCurrentRecord
 
End Sub
 
 
Public Sub SaveCurrentRecord()
 
    mPerson.MemberID = txtID.Text
    mPerson.MembersName = txtName.Text
    mPerson.MembersAddress = txtAddress.Text
    mPerson.MembersPostalCode = txtPostal.Text
    mPerson.MembersHomePhone = txtHome.Text
    mPerson.MembersMobileNumber = txtMobile.Text
 
    Put #mFileNum, mCurrentRecord, mPerson
 
End Sub
 
Public Sub ShowCurrentRecord()
 
    Get #mFileNum, mCurrentRecord, mPerson
 
    txtID.Text = Trim(mPerson.MemberID)
    txtName.Text = Trim(mPerson.MembersName)
    txtAddress.Text = Trim(mPerson.MembersAddress)
    txtPostal.Text = Trim(mPerson.MembersPostalCode)
    txtHome.Text = Trim(mPerson.MembersHomePhone)
    txtMobile.Text = Trim(mPerson.MembersMobileNumber)
 
 
frmAddressBook.Caption = "Douglas Lads Club" + Str(mCurrentRecord) + "/" + Str(mLastRecord)
End Sub
 
Private Sub cmdBack_Click()
    
    If mCurrentRecord = 1 Then
    
    Beep
    
    MsgBox "This is the first record !", vbExclamation, "Douglas Lads Club"
    
    Else
    
    SaveCurrentRecord
    
    mCurrentRecord = mCurrentRecord - 1
    
    ShowCurrentRecord
    
    End If
    
    txtID.SetFocus
    
End Sub
 
Private Sub cmdDelete_Click()
 
Dim DirResult
Dim TmpFileNum
Dim TmpPerson As PersonalInfo
Dim RecNum As Long
Dim TmpRecNum As Long
 
 
If MsgBox("Delete the current record?", vbYesNo + vbCritical, "Douglas Lads Club") = vbNo Then
 
 
txtID.SetFocus
 
 
 
Exit Sub
End If
 
If Dir("Data/addressbook.tmp") = "addressbook.tmpP" Then
 
Kill "Data/addressbook.tmp"
End If
 
TmpFileNum = FreeFile
 
Open "Data/addressbook.tmp" For Random As TmpFileNum Len = mRecordLen
 
RecNum = 1
TmpRecNum = 1
Do While RecNum < mLastRecord + 1
If RecNum <> mCurrentRecord Then
Get #mFileNum, RecNum, TmpPerson
Put #TmpFileNum, TmpRecNum, TmpPerson
TmpRecNum = TmpRecNum + 1
End If
RecNum = RecNum + 1
Loop
 
 
Close mFileNum
Kill "Data/addressbook.dat"
 
 
 
Close TmpFileNum
 
Name "Data/addressbook.tmp" As "Data/addressbook.dat"
 
 
mFileNum = FreeFile
 
Open "Data/addressbook.dat" For Random As mFileNum Len = mRecordLen
 
mLastRecord = mLastRecord - 1
 
 
If mLastRecord = 0 Then mLastRecord = 1
 
If mCurrentRecord > mLastRecord Then
   mCurrentRecord = mLastRecord
End If
ShowCurrentRecord
txtID.SetFocus
    
End Sub
 
Private Sub cmdSearch_Click()
 
    Dim NameToSearch As String
    
    Dim Found As Integer
    
    Dim RecNum As Long
    
    Dim TmpPerson As PersonalInfo
    
    NameToSearch = InputBox("Search for Member ID :", "Search Members")
    
    If NameToSearch = "" Then
    
    txtID.SetFocus
    
    Exit Sub
    
    End If
    
    NameToSearch = UCase(NameToSearch)
    
    Found = False
    
    For RecNum = 1 To mLastRecord
    
    Get #mFileNum, RecNum, TmpPerson
    
    If NameToSearch = UCase(Trim(TmpPerson.MemberID)) Then
    
    Found = True
    
    Exit For
    
    End If
    
    Next
    
    If Found = True Then
    
    SaveCurrentRecord
    
    mCurrentRecord = RecNum
    
    ShowCurrentRecord
    
    Else
    
    MsgBox "The Member ID you entered  could not be found!" & vbCrLf & vbCrLf & "Tip : Enter the correct Member Id Number to search!", vbInformation, "Douglas Lads Club"
    
    End If
    
    txtID.SetFocus
 
End Sub
 
Private Sub Form_Paint()
 
    Shadow Me, txtID, 2, vbBlack
    Shadow Me, txtName, 2, vbBlack
    Shadow Me, txtAddress, 2, vbBlack
    Shadow Me, txtPostal, 2, vbBlack
    Shadow Me, txtHome, 2, vbBlack
    Shadow Me, txtMobile, 2, vbBlack
    
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
 
    SaveCurrentRecord
 
End Sub
 
Private Sub cmdExit_Click()
    SaveCurrentRecord
    Unload Me
End Sub
 
Private Sub cmdNew_Click()
    
    SaveCurrentRecord
    
    mLastRecord = mLastRecord + 1
    
    mPerson.MemberID = ""
    
    mPerson.MembersName = ""
    
    mPerson.MembersAddress = ""
    
    mPerson.MembersPostalCode = ""
    
    mPerson.MembersHomePhone = ""
    
    mPerson.MembersMobileNumber = ""
    
    Put #mFileNum, mLastRecord, mPerson
    
    mCurrentRecord = mLastRecord
    
    ShowCurrentRecord
    
    txtID.SetFocus
    
End Sub
 
Private Sub cmdNext_Click()
    
    If mCurrentRecord = mLastRecord Then
    
    Beep
    
    MsgBox "Its the last record !", vbExclamation, "Douglas Lads Club"
    
    Else
    
    SaveCurrentRecord
    
    mCurrentRecord = mCurrentRecord + 1
    
    ShowCurrentRecord
    
    End If
    
    txtID.SetFocus
    
End Sub
 
Private Sub Form_Load()
 
    mRecordLen = Len(mPerson)
    
    mFileNum = FreeFile
    
    Open "Data/addressbook.dat" For Random As mFileNum Len = mRecordLen
    
    mCurrentRecord = 1
    
    mLastRecord = FileLen("Data/addressbook.dat") / mRecordLen
    
    If mLastRecord = 0 Then
    
    mLastRecord = 1
    
    End If
    
    ShowCurrentRecord
    
End Sub

On the assumption that you already know how to add the listview to your components tab...

To retaining existing code... place all textboxes relevant to mPerson in a picture box... make another picture box and place the listview control in this 2nd pic box... then add this in your Form_Load() event after call to ShowCurrentRecord.

VB Code:

Dim lstNew As ListItem
 
'following hides textboxes and shows listview
Picture1.Visible = False
Picture2.Visible = True
 
ListView1.View = lvwReport 
ListView1.LabelEdit = lvwManual
With ListView1.ColumnHeaders
   .Clear
   .Add , , "ID"
   .Add , , "Name"
   .Add , , "Address"
   .Add , , "Postal Code"
   .Add , , "Home Phone"
   .Add , , "Mobile Num"
End With
 
For mCurrentRecord = 1 To mLastRecord
   Get #mFileNum, mCurrentRecord, mPerson
   Set lstNew = ListView1.ListItems.Add
 
   lstNew.Text = Trim(mPerson.MemberID)
   lstNew.Tag = mCurrentRecord
   lstNew.SubItems(1) = Trim(mPerson.MembersName)
   lstNew.SubItems(2) = Trim(mPerson.MembersAddress)
   lstNew.SubItems(3) = Trim(mPerson.MembersPostalCode)
   lstNew.SubItems(4) = Trim(mPerson.MembersHomePhone)
   lstNew.SubItems(5) = Trim(mPerson.MembersMobileNumber)
Next
 
mCurrentRecord = 1  'reset current to start

Try to get a feel for the listview first. All other codes will have to be updated also... we will remove textbox ties to the data source bit by bit and redirect them to the listview.

Say i clicked save record is there anyway that i can get the listview to refresh itself when i have clicked the command button.

You have two choices...

1) update listview items then update the entire file by downloading all listview info

2) update immediately the record in the file per listitem update

So which implementation would you prefer? Also in what order do you want the update? File first before listview or theother way around?

Either way you will need an interface to accept new values, this can be done with Picture1.Visible = True under a new command button cmdEdit. We will use the textboxes as data entry controls.

But before that, next and back will become obsolete so add these in your form load event

cmdNext.Visible = False
cmdBack.Visible = False

how do i gewt it to update immediately.

Quote:

---

Originally Posted by Jamie_Garland

how do i gewt it to update immediately.

---

I updated my post, pls answer

"Also in what order do you want the update? File first before listview or the other way around?"

Listview then File

K. Before anything else we need to update mCurrentRecord

VB Code:

Private Sub ListView1_ItemClick(ByVal Item As MSComctlLib.ListItem)
   mCurrentRecord = Val(Item.Tag)
End Sub

You will also need a button cmdEdit

VB Code:

Private Sub cmdEdit_Click()
   If ListView1.SelectedItem Is Nothing Then Exit Sub
   ListView1.Enabled = False  'so he can't change selected item
   'you can slo use Picture2.Visible = False, 
   'but we'll show both picture boxes for now so you can compare
 
   With ListView1.SelectedItem  'initial values
      txtID.Text = .Text
      txtName.Text = .SubItems(1)
      txtAddress.Text = .SubItems(2)
      txtPostal.Text = .SubItems(3)
      txtHome.Text = .SubItems(4)
      txtMobile.Text = .SubItems(5)
   End With
 
   Picture1.Visible = True
   txtID.SetFocus
End Sub

You will need 2 more buttons in Picture1 (so they are shown when pic 1 is shown); cmdAccept and cmdCancel

VB Code:

Private Sub cmdCancel_Click()
   Picture1.Visible = False
   ListView1.Enabled = True
End Sub
 
Private Sub cmdAccept_Click()
   SaveCurrentRecord
   ListView1.Enabled = True
End Sub

To implement Private Sub ListView1_ItemClick(ByVal Item As MSComctlLib.ListItem) properly, in form load change this line

mCurrentRecord = 1 'reset current to start

To this

ListView1.ListItems(1).Selected = True

My bad... this is shorter and uses existing procedure

VB Code:

Private Sub cmdEdit_Click()
   If ListView1.SelectedItem Is Nothing Then Exit Sub
   ListView1.Enabled = False  
   ShowCurrentRecord
   Picture1.Visible = True
   txtID.SetFocus
End Sub

And I didn;t notice the update to frmAddressBook.Caption... transfer it to ListView's ItemClick event

VB Code:

Private Sub ListView1_ItemClick(ByVal Item As MSComctlLib.ListItem)
   mCurrentRecord = Val(Item.Tag)
   frmAddressBook.Caption = "Douglas Lads Club" + Str(mCurrentRecord) + "/" + Str(mLastRecord)
End Sub

When your done we will update implementation for delete

This code seems to mess everything up

Cant i just use

VB Code:

ListView1.Refresh

Have you got msn so i can send you my code and you can see what ive done couse im geting confused?

Phooey I'm getting sleepy, forgot to update listview. Change button name to AcceptEdit since we need to differentiate with AcceptNew

VB Code:

Private Sub cmdAcceptEdit_Click()
   SaveCurrentRecord
[b]   With ListView1.ListItems.SelectedItem
      .Text = Trim(mPerson.MemberID)
      .SubItems(1) = Trim(mPerson.MembersName)
      .SubItems(2) = Trim(mPerson.MembersAddress)
      .SubItems(3) = Trim(mPerson.MembersPostalCode)
      .SubItems(4) = Trim(mPerson.MembersHomePhone)
      .SubItems(5) = Trim(mPerson.MembersMobileNumber)
   End With
   cmdAcceptEdit.Visible = False[/b]
   ListView1.Enabled = True
End Sub
 
Private Sub cmdEdit_Click()
   If ListView1.SelectedItem Is Nothing Then Exit Sub
   ListView1.Enabled = False  
   ShowCurrentRecord
   Picture1.Visible = True
   [b]cmdAcceptEdit.Visible = True[/b]
   txtID.SetFocus
End Sub

Quote:

---

Originally Posted by Jamie_Garland

This code seems to mess everything up

Cant i just use

VB Code:

ListView1.Refresh

---

That will just repaint the listview... you have to assign new values that will be reflected in the refresh.

Sure attach your project in a zip

ill pm you the download link in a sec

Nope don;t have msn, you can attach the zip in your post.

EDIT: k I'll wait for the link

Link has been sent

K made some changes to frmAddressBook... though the app doesn't have handling routines for zero records yet. I also included code for resorting the list based on clicked columns.

isnt there anyway i can keep both them on the forms instead of one needing to be visible.

You will have problems with convergence (listview data matches textbox data) if the user edits data in textboxes when both are shown. To prevent that... In the last project, you could initially set the textboxes locked property to true, and unlock them only on cmdEdit.... When creating new records, set ListView1.Selected = nothing and refresh then go to textboxes (unlock same as in edit).... in the listview's itemclick event, call ShowCurrentRecord after updating mCurrentRecord to update textboxes, you navigate with listview so keep next and back buttons hidden.

Have to go to bed now... so sleepy i'm programming slow. Changes took more time than I expected.

Ciao!