[RESOLVED] XML file tutorial?

Does anyone know where to find a good XML file tutorial? I have always used INI files in the past, and since I am now learning .NET I figure I need to go with the times and begin using XML files. What I am trying to do is save user settings in the file. The settings I need to save would be best descrived as task lists. I am working on some backup software that the user can have different backup tasks, and I need to be able to save/load these settings on close/load of the program. Anyone have a good starting example for me?

Check the sticky thread at the top of this forum... it has links to .NET examples, one of them being working with XML

Thanks kleinma, checking it out. Here is more info if anyone can help me out. This is what my xml file will be structured like:

Code:

---

<?xml version="1.0"?>
<backitup>
        <settings>
                <store>c:\</store>
                <mode>File copying</mode>
                <incremental>True</incremental>
                <log>True</log>
        </settings>
        <tasks>
                <name task="My Backup">
                        <dirs>c:\files;c:\files2;c:\files3</dirs>
                </name>
                <name task="Test Backup">
                        <dirs>c:\test</dirs>
                </name>
        </tasks>
</backitup>

---

What I want to do is get the values for <store>, <mode>, etc and those values will be stored on the form (such as in textboxes, checkboxes, etc.) Then, I need to store each task name is an ArrayList.

Have you ever made any classes?

One of the cool things in .NET, is you can serialize a class to and from XML which takes out much of the annoying work of coding it yourself. Some situations require manual coding of the XML file, but if you are simply taking some simple text information, and bringing it to and from XML, then I would personally use a class and serialize it to and from the XML file.

The only code you would do is between the UI and the Class to either take the usered entered info, stick it in the class, and then serialize the class to XML, or serialize the data from XML to the class, and then load the form data from the class.

I have never dealt witch classes. I just moved up to .NET, i have been using VB6 until now. I am trying to learn the new methods of .NET.

Well serializing a class is new in .NET, however classes have been around since long before VB6 (I think VB4, maybe 5 introduced classes into the language)

there are many many tutorials and code samples around the web or here on the forum.

Yes, classes have been around since I do believe VB5. May of been introduced in 4, not sure. However, I ahve never really created my own. I am looking at the sticky and trying to learn from the example...

Ok, I'm sure there is a better way, but tell me what you think so far. Here is what I have done so far:

VB Code:

Dim BackupTasks As New ArrayList
 
        Dim XMLFile As New XmlDocument
        Dim XMLTaskList As XmlNodeList
        Dim XMLData As XmlNode
 
        'Load XML file
        XMLFile.Load("c:\myfile.xml")
 
        txtStore.Text = XMLFile.SelectSingleNode("/backitup/settings/store").InnerText
        cboMethod.Text = XMLFile.SelectSingleNode("/backitup/settings/mode").InnerText
        chkIncremental.Checked = CType(XMLFile.SelectSingleNode("/backitup/settings/incremental").InnerText, Boolean)
        chkSaveLog.Checked = CType(XMLFile.SelectSingleNode("/backitup/settings/log").InnerText, Boolean)
 
        XMLTaskList = XMLFile.SelectNodes("/backitup/tasks/name")
        For Each XMLData In XMLTaskList
            BackupTasks.Add(XMLData.Attributes.GetNamedItem("task").Value)
        Next

Am I doing this correctly, or is there a much better way?

looks ok... but when you do your loop, it looks like the only thing you are puttin in it, is the text value of the "task" attribute, (ie "My Backup" or "Test Backup"). It won't include the <dirs> element

Yeah, that was just a quick way to see if I was doing it correctly. Another question I have. Say the value in txtStore on my form changes and I want to change that value in the XML file, how would I do that?

basically the reverse of the load should do it

VB Code:

XMLFile.SelectSingleNode("/backitup/settings/store").InnerText = txtStore.Text
XMLFile.Save("c:\myfile.xml")

Just remember XMLFile needs to still be in scope, otherwise you would need to load the XMLFile again via

VB Code:

XMLFile.Load("c:\myfile.xml")
XMLFile.SelectSingleNode("/backitup/settings/store").InnerText = txtStore.Text
XMLFile.Save("c:\myfile.xml")

Also, is there a way to "test" if the element is in the XML file. Say if I run the function above and the <mode> element is missing, I get an error the way it is coded now. How can i error-proof it?

One more thing while I'm thinking of them, how can I add another <name> to the <task> element? Thanks for all the help thus far, you are really helping me get a grasp on this...

Quote:

---

Originally Posted by dustintinsley

Also, is there a way to "test" if the element is in the XML file. Say if I run the function above and the <mode> element is missing, I get an error the way it is coded now. How can i error-proof it?

---

well it is up to your application to read/write the XML properly. since these XML files won't be written by hand by the end user (I am assuming), then you should always go with the notion that the XML file will be properly formed.

That doesn't mean you don't want to use error handling, it just means you don't need the strict validation that you would want to impose if the XML could be coming from anywhere.

Simply try/catch blocks work well, in the catch block, you would perhaps set the value to a default value you want, if it isn't present.

Quote:

---

Originally Posted by dustintinsley

One more thing while I'm thinking of them, how can I add another <name> to the <task> element? Thanks for all the help thus far, you are really helping me get a grasp on this...

---

This should work.. I wrote it freehand though

VB Code:

Dim NewTask As Xml.XmlElement = XMLFile.CreateElement("name")
        NewTask.SetAttribute("task", "New Backup")
        NewTask.AppendChild(XMLFile.CreateElement("Dirs"))
        NewTask.ChildNodes(0).InnerText = "c:\files;c:\files2;c:\files3"
        XMLFile.DocumentElement.Item("tasks").AppendChild(NewTask)

Also remember that XML is case sensitive in the parser, so if you ask for a node called Task, when it's called task, it won't find it.

Again, thanks. I am looking at the Try/Ctach calls. That is a new one on me. Again, thanks...

When writing an XML file in .NET, how can you write it so the XML is formatted with indentation and each line is on a new line?

Would XPath be a better choice for me? I was browsing around and saw some info on XPtah, and just wondwering which would be better for my uses?

Quote:

---

Originally Posted by dustintinsley

When writing an XML file in .NET, how can you write it so the XML is formatted with indentation and each line is on a new line?

---

What are you viewing the output XML file in? notepad?

If so, just view it in IE instead (or visual studio itself for that matter) it will be color coded and formatted well.

Quote:

---

Originally Posted by dustintinsley

Would XPath be a better choice for me? I was browsing around and saw some info on XPtah, and just wondwering which would be better for my uses?

---

I don't think so. It looks like xpath is simply an XML parser. Microsoft wrote their own XML parser, which is the one included in the .NET framework library

Yeah, I was viewing in Notepad. Thanks, tried in Visual Studio, and all was well. I wasn't sure about the XPath. Seems like I have it working pretty nicely right now. Thanks.

I am not saying XPath is bad or anything, but since you are writing code in VB.NET, you might as well use the built in XML classes in the framework.

Yeah, I understand that. The way I am doing it seems to be working as I want it to, I appreciate the help.

no problem, if you have it all sorted out, mark the thread resolved using the thread tools menu above, or if you have more questions, then feel free to post them here. (or a new thread if they differ greatly from what this one is about)

kleinma, another question i have. here is the way my xml file is designed now:

Code:

---

<?xml version="1.0"?>
<backitup>
        <settings>
                <store>c:\</store>
                <mode>File copying</mode>
                <incremental>True</incremental>
                <log>True</log>
        </settings>
        <tasks>
                <name task="My Backup">
                        <img>0</img>
                        <source>c:\files;c:\files2;c:\files3</source>
                </name>
                <name task="Test Backup">
                        <img>0</img>
                        <source>c:\test</source>
                        <source>f:\</source>
                </name>
        </tasks>
</backitup>

---

and here is my code:

VB Code:

Private Sub LoadXML(ByVal TheFile As String)
        'Check to make sure XML file exists
        If Not File.Exists(TheFile) Then
            'If not, create the file and exit sub
            'TODO: Add code to create new XML file
            Exit Sub
        End If
 
        'Load XM file into memeroy
        XMLFile.Load(TheFile)
 
        Dim XMLTasks As XmlNodeList = XMLFile.SelectNodes("backitup/tasks/name")
        Dim XMLData As XmlNode
        Dim ChildCount As Integer
 
        'Scan trhough all the task entries in the XML file
        For Each XMLData In XMLTasks
            For ChildCount = 0 To XMLData.ChildNodes.Count - 1
                Select Case XMLData.ChildNodes(ChildCount).Name
                    Case "img"
                        'Setup the new button to add to the task bar
                        Dim NewButton As ListBar.Controls.ListBar.ButtonListBarItem = New ListBar.Controls.ListBar.ButtonListBarItem(XMLData.ChildNodes(ChildCount).ParentNode.Attributes.GetNamedItem("task").Value, CType(XMLData.ChildNodes(ChildCount).InnerText, Integer))
                        'Add the new button to the task bar
                        barTasks.Items.Add(NewButton)
                    Case "source"
                        'TODO: Add code for the sources here
                End Select
            Next
        Next
 
        'Get/set the value of the store directory
        txtStore.Text = XMLFile.SelectSingleNode("backitup/settings/store/text()").Value
        'Get/set the value of the copy mode method
        cboMethod.Text = XMLFile.SelectSingleNode("backitup/settings/mode/text()").Value
        'Get/set incremental value option; Use CType() to convert value to either True/False
        chkIncremental.Checked = CType(XMLFile.SelectSingleNode("backitup/settings/incremental/text()").Value, Boolean)
        'Get/set save log value option; Use CType() to convert value to either True/False
        chkSaveLog.Checked = CType(XMLFile.SelectSingleNode("backitup/settings/log/text()").Value, Boolean)
    End Sub

For each "task", a new button is added to a task bar on the form. Now instead of storing every source in an array list for each task, i want to load it into an array list or listbox once the button is clicked. how can i do that?

Also, how could I remove an entire <name> element form the <task> element by the name in the task atrribute. say i have this:

Code:

---

<?xml version="1.0"?>
<backitup>
        <settings>
                <store>c:\</store>
                <mode>File copying</mode>
                <incremental>True</incremental>
                <log>True</log>
        </settings>
        <tasks>
                <name task="My Backup">
                        <img>0</img>
                        <source>c:\files;c:\files2;c:\files3</source>
                </name>
                <name task="Test Backup">
                        <img>0</img>
                        <source>c:\test</source>
                        <source>f:\</source>
                </name>
        </tasks>
</backitup>

---

but want to end up with this:

Code:

---

<?xml version="1.0"?>
<backitup>
        <settings>
                <store>c:\</store>
                <mode>File copying</mode>
                <incremental>True</incremental>
                <log>True</log>
        </settings>
        <tasks>
                <name task="My Backup">
                        <img>0</img>
                        <source>c:\files;c:\files2;c:\files3</source>
                </name>
        </tasks>
</backitup>

---

Sorry, I am rather busy today with a project, I will post information to you as I can...

Here is how you would remove a specific node from the tasks section

VB Code:

Dim XMLTasks As Xml.XmlElement = XMLFile.Item("tasks")
        For Each TaskName As Xml.XmlElement In XMLTasks.ChildNodes
            If TaskName.GetAttribute("task") = "Test Backup" Then
                XMLTasks.RemoveChild(TaskName)
                Exit For
            End If
        Next

I didn't test it.. but it should work.

Also I want to say that you are a prefect example of the easier people to help on the forum.

you post a clear question, you try to work things out yourself, you post code, and example data for those who may be able to help you.

We get a lot of "I want to do this, please give me the code" posts on this forum. It is good to see people using this forum for HELP, versus using it to do their work for them.

kleinma: that seems like it will be a lot easie then the approach i was working on. i tried it and get this error:

NullReferenceException was Unhandled
Object reference not set to an instance of an object.

on the line:
For Each TaskName As Xml.XmlElement In XMLTasks.ChildNodes

I tried working around it, but no matter what I did, I got an error. I checked to make sure the XML file has those references, and there are 2 of them in there.

my bad. I left out the DocumentElement, the DocumentElement is the ROOT node, which an XML document can only have 1 of. In your file the root element is backitup

VB Code:

Dim XMLTasks As Xml.XmlElement = XMLFile.[b]DocumentElement[/b].Item("tasks")
        For Each TaskName As Xml.XmlElement In XMLTasks.ChildNodes
            If TaskName.GetAttribute("task") = "Test Backup" Then
                XMLTasks.RemoveChild(TaskName)
                Exit For
            End If
        Next

kleinma: this *seems* to work, is it correct? i was working on this at the same time you were helping me with your code:

VB Code:

Dim XMLData As XmlNode = XMLFile.SelectSingleNode("backitup/tasks/name[@task='Test Backup']")
        XMLData.ParentNode.RemoveChild(XMLData)

yeah... as long as it works, its ok.

There are many ways to drill down and work with nodes using the XML classes, so you will find that one specific problem, can be solved with multiple approaches.

You could combine your code into one line.

VB Code:

XMLData.ParentNode.RemoveChild(XMLFile.SelectSingleNode("backitup/tasks/name[@task='Test Backup']"))

Thanks for your help. You have been a big help. I may need a little more assistance with this, so for the time being, I will not mark this as resolved. Again, you have been a huge help, I would of never figured this all out without you...