resizing a form

Hi,

I know you can set your form to be resizable or non resizable.

But how can I have it so that it is proportionately resizable no matter where the user drags the outline - it will always end up in the proportion: 2:3, where 2 is height and 3 is width?

Thanks!

this comes close but not perfect in some situtations.
it doesn't do the 2/3 ratio but keeps things in perspective

Code:

---

'this goes in a class module  NOT bas ( A CLASS MODULE)
'
Option Explicit

' Title:    Elastic Forms
' Author:  Leigh Bowers
' Email:    [email protected]
' WWW:      http://www.esheep.freeserve.co.uk/compulsion
' Version:  1.01
' Date:    19th June 1999
' Requires: N/A
' License:  Freely Distributable (non-commercial use)

Private fForm As Form

Private lOriginalWidth As Long
Private lOriginalHeight As Long

Private lMinWidth As Long
Private lMinHeight As Long

Private Type udtControl
    lLeft As Long
    lTop As Long
    lWidth As Long
    lHeight As Long
End Type
Private aControls() As udtControl

Public Property Let Form(ByVal fPassForm As Form)
   
Dim iCount As Integer
Dim cControl As Control

    Set fForm = fPassForm
   
    ' Store form's original Width & Height
   
    lOriginalWidth = fForm.Width
    lOriginalHeight = fForm.Height

    ' Use error trapping to ignore components that don't
    ' support certain properties being read at run-time

    On Error Resume Next

    ' Store the form's component's properties

    iCount = 0
    ReDim aControls(fForm.Controls.Count)

    For Each cControl In fForm.Controls
        iCount = iCount + 1
        With aControls(iCount)
            If TypeOf cControl Is Line Then
                .lLeft = cControl.X1
                .lTop = cControl.Y1
                .lWidth = cControl.X2
                .lHeight = cControl.Y2
            Else
                .lLeft = cControl.Left
                .lTop = cControl.Top
                .lWidth = cControl.Width
                .lHeight = cControl.Height
            End If
        End With
    Next ' Each

End Property

Public Sub FormResize()

    ' v1.01 (19/06/1999)
    '
    ' bDisableResize:
    ' Used to avoid unnecessary *recursive* resizing
    '
    ' lPreviousWidth/Height:
    ' Used to avoid unnecessary resizing

    ' Resize the form's controls

Dim iCount As Integer
Dim cControl As Control
Dim iTaskBarHeight As Integer
Dim sOriginalWidthUnit As Single
Dim sOriginalHeightUnit As Single
Static bDisableResize As Boolean
Static lPreviousWidth As Long
Static lPreviousHeight As Long

    If fForm Is Nothing Or bDisableResize Then Exit Sub

    ' Don't process minimized forms
   
    If fForm.WindowState = vbMinimized Then Exit Sub

    ' Check form size against minimums
   
    bDisableResize = True
    If fForm.Width < lMinWidth Then fForm.Width = lMinWidth
    If fForm.Height < lMinHeight Then fForm.Height = lMinHeight
    bDisableResize = False
   
    ' Ensure form size has changed
   
    If lPreviousWidth = fForm.Width And lPreviousHeight = fForm.Height Then Exit Sub
    lPreviousWidth = fForm.Width
    lPreviousHeight = fForm.Height

    ' Perform calculations in advance (speed increase)

    iTaskBarHeight = 28 * Screen.TwipsPerPixelY ' Standard height
    sOriginalWidthUnit = lOriginalWidth / fForm.Width
    sOriginalHeightUnit = (lOriginalHeight - iTaskBarHeight) / (fForm.Height - iTaskBarHeight)

    ' Use error trapping to ignore components that don't
    ' support certain properties being set at run-time

    On Error Resume Next

    ' Do the resize...
   
    iCount = 0

    For Each cControl In fForm.Controls
        iCount = iCount + 1
        With cControl
            If TypeOf cControl Is Line Then
                .X1 = Int(aControls(iCount).lLeft / sOriginalWidthUnit)
                .Y1 = Int(aControls(iCount).lTop / sOriginalHeightUnit)
                .X2 = Int(aControls(iCount).lWidth / sOriginalWidthUnit)
                .Y2 = Int(aControls(iCount).lHeight / sOriginalHeightUnit)
            Else
                .Left = Int(aControls(iCount).lLeft / sOriginalWidthUnit)
                .Top = Int(aControls(iCount).lTop / sOriginalHeightUnit)
                .Width = Int(aControls(iCount).lWidth / sOriginalWidthUnit)
                .Height = Int(aControls(iCount).lHeight / sOriginalHeightUnit)
            End If
        End With
    Next ' Each

End Sub


Private Sub Class_Terminate()

    Set fForm = Nothing

End Sub




Public Property Let MinWidth(ByVal lPassMinWidth As Long)

    lMinWidth = lPassMinWidth

End Property
Public Property Let MinHeight(ByVal lPassMinHeight As Long)

    lMinHeight = lPassMinHeight

End Property

'<<<<<<<<<<<<<<<<<<<<<<<<<<<<>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

'this if your form code for every form in project

Option Explicit

Private clsElastic As clsElasticForms

Private Sub Form_Load()

    Set clsElastic = New clsElasticForms
    clsElastic.Form = Me
    clsElastic.MinHeight = 4000
    clsElastic.MinWidth = 4000

End Sub


Private Sub Form_Resize()

    clsElastic.FormResize

End Sub


Private Sub Form_Unload(Cancel As Integer)

    Set clsElastic = Nothing

End Sub

---

Thanks HeSaidJoe,

But do I need to do something more than simply put it into a Class Module? I did that and nothing happened.

Besides, does your code resize line controls? I haven't come along a resizer that resizes the line control - which I need to happen.

So all I need to be able to do is resize my form proportionately.

If it did nothing you have not implemented the code properly. My guess is you left the name Class1 and forgot ot change it to clsElasticForms or it went in a bas module and not a class module. It does work and yes, it does handle lines as well. I use this code and I've just retested it to see if perhaps I had left out something, but it passed the test and works.


PS. This is not my code. As the intro suggests, it belongs to:

Code:

---

' Title:    Elastic Forms
' Author:  Leigh Bowers
' Email:    [email protected]
' WWW:      http://www.esheep.freeserve.co.uk/compulsion
' Version:  1.01
' Date:    19th June 1999
' Requires: N/A
' License:  Freely Distributable (non-commercial use)

---