[RESOLVED] "as any" problem

I'm new to .net and just upgraded a vb6 project. I'm fixing upgrade problems but ran into an issue I can't figure out. I know that "as any" isn't allowed any more. But I have a function declaration that passes a structure and I can't figure out how to declare it for .net. Here's the function. LicInfo is a structure. Any ideas?

Public Declare Function GMW_GetLicenseInfo Lib "gm7s32.dll" (ByRef LicInfo As Any) As Integer

I normally change it to int32, try that. Works for me alot :wave:

The best way to do external function declarations in .NET is to import the System.Runtime.Interop namespace and use <DllImport> on the function signature. Leave the function body blank (you need an End Function too). And use <MarshalAs...> on troublesome parameters, you will find a lot of options that allow you to control exactly how the function is called.

If it is a structure, then pass an instance ByRef. You may need to initialise members that are arrays, strings or further structures. It is very likely it won't work without some custom marshalling attributes applied, and you might need to set a size member of the structure to the correct value (the size, in bytes of the structure - which is not always easy to determine).

Integer might work as the c funciton is expecting a pointer to a structure, and pointers and integers are both 4 byte values. The returned int then is really an IntPtr to a structure, but it probably wouldn't work without sending off a blob of memory holding an initialised structure...

If you have the declaration of the structure (the c one is best), then I could give a code sample with a best guess...

This is the c code for the structure and the function:

VB Code:

licensing structure passed to GMW_GetLicenseInfo
typedef struct
{
char szLicensee[60]; // licensee name
char szLicNo[20]; // master serial number
char szSiteName[20]; // undocked site name
long iLicUsers; // licensed users
long iSQLUsers; // licensed SQL users
long iGSSites; // license GoldSync sites
long isDemo; // is demo install
long isServerLic; // is primary license ('D' or 'E')
long isRemoteLic; // is remote license ('U' or 'S')
long isUSALicense; // is USA license (1=US,128/32
// bit, 0=nonUS, 32-bit only)
long iDLLVersion; // the DLL version (400822)
long iReserved1;
long iReserved2;
long szReserved[100];
} GMW_LicInfo;
 
int _stdcall GMW_GetLicenseInfo( GMW_LicInfo *pLic );

Hmm, here's an attempt. It's very difficult without being able to test it.

VB Code:

<DllImport("gm7s32.dll")> _
    Private Shared Function GMW_GetLicenseInfo(ByRef licenseInfo As GMW_LicInfo) As Integer
    End Function
 
    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Ansi)> _
    Private Structure GMW_LicInfo
        ' msdn says a c CHAR is an 8 bit ansi character.
        ' we can marshal it as a string if we initialise it first.
        ' see topic "default marshaling for strings" in the library.
        ''' <summary>licensee name</summary>
        <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=60)> _
        Public szLicensee As String
        ''' <summary>master serial number</summary>
        <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=20)> _
        Public szLicNo As String
        ''' <summary>undocked site name</summary>
        <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=20)> _
        Public szSiteName As String
        ' msdn says a c LONG is a 32-bit signed integer, so use int32
        ''' <summary>licensed users</summary>
        Public iLicUsers As Integer
        ''' <summary>licensed SQL users</summary>
        Public iSQLUsers As Integer
        ''' <summary>license GoldSync sites</summary>
        Public iGSSites As Integer
        '''<summary>is demo install</summary>
        Public isDemo As Integer
        '''<summary>is primary license ('D' or 'E')</summary>
        Public isServerLic As Integer
        ''' <summary>is remote license ('U' or 'S')</summary>
        Public isRemoteLic As Integer
        ''' <summary>is USA license (1=US,128/32bit, 0=nonUS, 32-bit only.</summary>
        Public isUSALicense As Integer
        ''' <summary>the DLL version (400822)</summary>
        Public iDLLVersion As Integer
        Public iReserved1 As Integer
        Public iReserved2 As Integer
        ' See topic 'Default marshaling for arrays' in the library
        <MarshalAs(UnmanagedType.ByValArray, ArraySubType:=UnmanagedType.I4, SizeConst:=100)> _
        Public szReserved() As Integer
 
        Public Sub Initialize()
            ' fill the strings with dummy data
            Me.szLicensee = New String("*"c, 60)
            Me.szLicNo = New String("*"c, 20)
            Me.szSiteName = New String("*"c, 20)
            Me.szReserved = New Int32(99) {}
            szReserved.Initialize()
        End Sub
    End Structure
 
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
 
        Dim licInfo As New GMW_LicInfo
        licInfo.Initialize()
        ' call
        Dim result As Integer = GMW_GetLicenseInfo(licInfo)
        ' hopefully licinfo is now filled in...
 
    End Sub

Simple solution. I changed the "any" to the name of the structure.

Public Declare Function GMW_GetLicenseInfo Lib "gm7s32.dll" (ByRef LicInfo As GMW_LicInfo) As Integer