[RESOLVED] keydown trouble

i am making a game where you use the left and right arrow keys to move a little guy left and right on the screen and i have used this code:

VB Code:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
 
If KeyCode = vbKeyLeft Then
 x = x - 100
 
Elseif keycode = vbkeyright then
 x = x + 100
end if
 
End Sub

that moves him left and right but the only thing is that when i hold down the key, he moves forwards for a fraction of a second, stops then starts moving normally until i let go. does anyone know how to just make it start moving normally as soon as i press the key?
also if i have any text boxes or buttons on my form then this code doesn't work, how do i get it to work while it has buttons and text boxes on it?

Set a flag that will not let the keydown code run until the keyup event clear the flag.

sorry i don't know what you mean by a flag

VB Code:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
 
   [B]if KeyFlag = True then exit sub[/B]
 
   If KeyCode = vbKeyLeft Then
       x = x - 100
 
   Elseif keycode = vbkeyright then
       x = x + 100
   End if
 
   [B]KeyFlag = True[/B]
 
End Sub
 
Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
   KeyFlag = False
End Sub

no it still does the motion that i described in my first post

The the problem is with the rest of your code that moves him. Which you doid not show.

here it is

VB Code:

Dim x As Integer
 
 
Private Sub Form_Load()
x = 2000
End Sub
 
Private Sub Timer1_Timer()
 Line3.X1 = x
 Line3.X2 = x
 Line4.X1 = x - 450
 Line4.X2 = x
 Line5.X1 = x + 450
 Line5.X2 = x
Line2.X1 = x
Line2.X2 = x + 240
Line1.X1 = x
Line1.X2 = x - 240
Shape2.Left = x - 240
Shape3.Left = x - 135
Shape4.Left = x + 45
Shape5.Left = x - 120
 
End Sub

the timer1.interval is set to 1

I don't know whether this is just my stupidity or not but i'm finding it really hard to decipher exactly what everything does and is for. If you give me your whole code and the amount of lines, shapes etc then I may be able to re-create your code and see if I can fix it.

You possibly need to erase that which is on the screen (the guy) before moving in the new direction. Also try disabling the timer when you press the down key and reenabling it upon exit.

here is my project m

I think what killo wants is an automatic repeat of his KeyDown code for as long as the key is held down.

Don't update X every time the keydown event fires, update x using an increment value when the Timer event fires (ie when it is time to move). Set the increment value only when the key first goes down and reset it when the key goes up.

This has the added benefit of being able to use multiple keys. If both the Left and Right keys are down, the character should basically stop. As it is now the character will move based on the last key to be pressed. When you add the ability to Move Up or Down, pressing (for example) Left and Up will cause the character to move diagonally.

Here check out this code.

VB Code:

Dim x As Integer
Dim increment As Integer
Dim blnLeftDown As Boolean
Dim blnRightDown As Boolean
 
Private Sub Form_Load()
x = 2000
End Sub
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
 
   If KeyCode = vbKeyLeft And blnLeftDown = False Then
       increment = increment - 100
       blnLeftDown = True
   ElseIf KeyCode = vbKeyRight And blnRightDown = False Then
       increment = increment + 100
       blnRightDown = True
   End If
End Sub
 
Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
   If KeyCode = vbKeyLeft Then
       increment = increment + 100
       blnLeftDown = False
 
   ElseIf KeyCode = vbKeyRight Then
       increment = increment - 100
        blnRightDown = False
 
   End If
End Sub
 
 
Private Sub Timer1_Timer()
[B] x = x + increment[/B]
 Line3.X1 = x
 Line3.X2 = x
 Line4.X1 = x - 450
 Line4.X2 = x
 Line5.X1 = x + 450
 Line5.X2 = x
Line2.X1 = x
Line2.X2 = x + 240
Line1.X1 = x
Line1.X2 = x - 240
Shape2.Left = x - 240
Shape3.Left = x - 135
Shape4.Left = x + 45
Shape5.Left = x - 120
 
End Sub

thanks that works perfectly :afrog:

if i put a textbox on my form then this code doesnt work because the left and right keys are used for moving the cursor in the text box rather than
moving the guy. it also happens if i use command buttons. how do i get it to work with commnd buttons and text boxes?