Get IP address and computer name

hi! how can i get the Ip address and name of the computer where the application is running? thanks in advance!

Use the GetComputerName API.

VB Code:

Private Declare Function GetComputerName Lib "kernel32.dll" Alias "GetComputerNameA" (ByVal lpBuffer As String, ByRef nSize As Long) As Long

thanks for that..but how can i display the ipaddress?

VB Code:

Option Explicit
 
Private Const WS_VERSION_REQD = &H101
Private Const WS_VERSION_MAJOR = WS_VERSION_REQD \ &H100 And &HFF&
Private Const WS_VERSION_MINOR = WS_VERSION_REQD And &HFF&
Private Const MIN_SOCKETS_REQD = 1
Private Const SOCKET_ERROR = -1
Private Const WSADescription_Len = 256
Private Const WSASYS_Status_Len = 128
 
Private Type HOSTENT
    hName As Long
    hAliases As Long
    hAddrType As Integer
    hLength As Integer
    hAddrList As Long
End Type
 
Private Type WSADATA
    wversion As Integer
    wHighVersion As Integer
    szDescription(0 To WSADescription_Len) As Byte
    szSystemStatus(0 To WSASYS_Status_Len) As Byte
    iMaxSockets As Integer
    iMaxUdpDg As Integer
    lpszVendorInfo As Long
End Type
 
Private Declare Function WSAGetLastError Lib "WSOCK32.DLL" () As Long
Private Declare Function WSAStartup Lib "WSOCK32.DLL" (ByVal wVersionRequired As Integer, lpWSAData As WSADATA) As Long
Private Declare Function WSACleanup Lib "WSOCK32.DLL" () As Long
 
Private Declare Function gethostname Lib "WSOCK32.DLL" (ByVal hostname$, ByVal HostLen As Long) As Long
Private Declare Function gethostbyname Lib "WSOCK32.DLL" (ByVal hostname$) As Long
Private Declare Sub RtlMoveMemory Lib "KERNEL32" (hpvDest As Any, ByVal hpvSource&, ByVal cbCopy&)
Function hibyte(ByVal wParam As Integer)
    hibyte = wParam \ &H100 And &HFF&
End Function
 
Function lobyte(ByVal wParam As Integer)
    lobyte = wParam And &HFF&
End Function
 
' Return the local host's name.
Private Function LocalHostName() As String
Dim hostname As String * 256
 
    If gethostname(hostname, 256) = SOCKET_ERROR Then
        LocalHostName = "<Error>"
    Else
        LocalHostName = Trim$(hostname)
    End If
End Function
Private Sub InitializeSockets()
Dim WSAD As WSADATA
Dim iReturn As Integer
Dim sLowByte As String, sHighByte As String, sMsg As String
 
    iReturn = WSAStartup(WS_VERSION_REQD, WSAD)
 
    If iReturn <> 0 Then
        MsgBox "Winsock.dll is not responding."
        End
    End If
 
    If lobyte(WSAD.wversion) < WS_VERSION_MAJOR Or (lobyte(WSAD.wversion) = _
        WS_VERSION_MAJOR And hibyte(WSAD.wversion) < WS_VERSION_MINOR) Then
 
        sHighByte = Trim$(Str$(hibyte(WSAD.wversion)))
        sLowByte = Trim$(Str$(lobyte(WSAD.wversion)))
        sMsg = "Windows Sockets version " & sLowByte & "." & sHighByte
        sMsg = sMsg & " is not supported by winsock.dll "
        MsgBox sMsg
        End
    End If
 
    'iMaxSockets is not used in winsock 2. So the following check is only
    'necessary for winsock 1. If winsock 2 is requested,
    'the following check can be skipped.
 
    If WSAD.iMaxSockets < MIN_SOCKETS_REQD Then
        sMsg = "This application requires a minimum of "
        sMsg = sMsg & Trim$(Str$(MIN_SOCKETS_REQD)) & " supported sockets."
        MsgBox sMsg
        End
    End If
 
End Sub
 
Private Sub CleanupSockets()
Dim lReturn As Long
 
    lReturn = WSACleanup()
 
    If lReturn <> 0 Then
        MsgBox "Socket error " & Trim$(Str$(lReturn)) & " occurred in Cleanup "
        End
    End If
 
End Sub
 
Private Sub cmdGetIPAddress_Click()
    txtIPAddress.Text = IPAddressFromHostName(txtHostName.Text)
End Sub
 
Private Sub Form_Load()
    ' Initialize the sockets library.
    InitializeSockets
 
    ' Display the local host's name.
    txtHostName = LocalHostName()
End Sub
Private Sub Form_Unload(Cancel As Integer)
    ' Clean up the sockets library.
    CleanupSockets
End Sub
' Return this host's IP address.
Private Function IPAddressFromHostName(ByVal hostname As String) As String
Dim hostent_addr As Long
Dim host As HOSTENT
Dim hostip_addr As Long
Dim temp_ip_address() As Byte
Dim i As Integer
Dim ip_address As String
Dim result As String
 
    hostent_addr = gethostbyname(hostname)
    If hostent_addr = 0 Then
        IPAddressFromHostName = "<error>"
        Exit Function
    End If
 
    RtlMoveMemory host, hostent_addr, LenB(host)
    RtlMoveMemory hostip_addr, host.hAddrList, 4
 
    ' Get multiple pieces of the IP address
    ' if machine is multi-homed.
    Do
        ReDim temp_ip_address(1 To host.hLength)
        RtlMoveMemory temp_ip_address(1), hostip_addr, host.hLength
 
        For i = 1 To host.hLength
            ip_address = ip_address & temp_ip_address(i) & "."
        Next
 
        ip_address = Mid$(ip_address, 1, Len(ip_address) - 1)
        result = result & ip_address & vbCrLf
        ip_address = ""
 
        host.hAddrList = host.hAddrList + LenB(host.hAddrList)
        RtlMoveMemory hostip_addr, host.hAddrList, 4
    Loop While (hostip_addr <> 0)
 
    ' Remove the last vbCrLf.
    If Len(result) > 0 Then result = Left$(result, Len(result) - Len(vbCrLf))
 
    IPAddressFromHostName = result
End Function

'make a form draw2 follow and paste above code
'Command Button Name cmdGetIPadd
'Textbox1 name txtHostName
'Textbox2 name txtIPAddress


'make a form draw2 follow and paste above code
'Command Button Name cmdGetIPadd
'Textbox1 name txtHostName
'Textbox2 name txtIPAddress :wave:

Thanks for that..but the code is too complicated...is there easier way to retrive the ip address and name of the computer?..i think the idea/code of RobDog888 is more easier,hope it will work, but how can i display the ip address and name RobDog888?

Hers an example of how to use it. this is just for getting the machine name.

http://vbforums.com/showpost.php?p=1447037&postcount=3

shakti5385 - Command Button Name "cmdGetIPadd" should be "cmdGetIPAddress"

Quote:

---

Originally Posted by schoolbusdriver

shakti5385 - Command Button Name "cmdGetIPadd" should be "cmdGetIPAddress"

---

thanks
but remember there is need of command button

if mistake in code then pass argument :mad:

Sorry :eek2: The code is fine. You can also do this:-

VB Code:

Private Sub Form_Load()
   InitializeSockets ' Initialize the sockets library.
   txtHostName = LocalHostName() ' Display the local host name.
   txtIPAddress.Text = IPAddressFromHostName(txtHostName.Text)' Show IP.
End Sub

its enough thanks

Why not use good ole Winsock

VB Code:

Text1.Text = Winsock1.LocalIp

One thing to bear in mind - all of those get the local address - if the computer is behind a router the address will be 10.x.x.x, 172.18.x.x or 192.x.x.x, regardless of the external address.

if i have 2 ip address for a host name how to take only one IP ?..

if i have 2 ipaddress for 1 hostname how to fetch only one?..

Quote:

---

Originally Posted by subramanian.hari

if i have 2 ipaddress for 1 hostname how to fetch only one?..

---

Take both and discard second.

cheers,
</wqw>