[RESOLVED] Control property like .list ( dropdown )

All,

Is there a way to add a property to an activex control that acts like a comboBox's list property ? You know, the dropdown list but in the property box for an activex control.

I can set a variable type as a filename and get the [...] ,the ole_color color picker and even the font chooser. But no list ?

Before you ask, I don't have a particular use but if it's possible I could probably think of a few.

Add a listbox to the conrol.

Hey Al42,

I'm actually just wondering if it's possible to add a dropdown property to the controls properties box. Like the combo.list, but more like an actual dropdown. It's like a list of choices but something that's changeable at design time. Like the UpDown control's BuddyProperty.

I know if you set a properties type in a ActiveX control then the property box for that control reflects that. Like a dropdown with True and False for a Boolean.

I guess I could always use a Propety Page and add a ComboBox on it and copy the contents or just the selected text to a variable in the control, but I just wondered if there was a more direct way through the props instead of the (custom).

Now that I understand what you want, use an Enum in the control and Let/Get something with that Enum.

VB Code:

Public Enum myProp
  [(Default)]
  Name
  Caption
  Index
  BackColor
  Left
  Top
End Enum
 
Public Property Get EnumThing() As myProp
    EnumThing = m_EnumThing
End Property
 
Public Property Let EnumThing(ByVal New_EnumThing As myProp)
  m_EnumThing = New_EnumThing
  PropertyChanged "EnumThing"
End Property

I think that's what you want.

Hey Al42,

Thanks for the reply.

Yeah, I know how to use Enum, I was was looking for a way to make the dropdown's list changeable. Once you set a property as a particular type it's stuck that way.

As I said, I don't currently have a use for it. Although, I'd like to be able to pick something like a list of controls on a form from the dropdown and link it the usercontrol. But that could probably be easier to do in a property sheet. When the property sheet loaded, I could have the control add the controls to a dropdown.

It's just one of those, can it be done things. You never know when I might need it.

I'm learning Visual C++. So, maybe there's a way to do it through C++. It seems a more flexible language but it also requires a lot more coding.

I'll leave this thread unresolved for now, maybe someone will have an idea.Thanks for the help.

Ok, I think I got this working through a property page. After crashing the IDE about 20 times.

Here's my code:

VB Code:

'usercontrol module
Public ParentForm As Form
Public ParentControlName As String
 
'usercontrol code example
 Option Explicit
'Default Property Values:
Const m_def_LinkIndex = -1
Const m_def_LinkName = 0
'Property Variables:
Dim m_LinkIndex As Integer
Dim m_LinkName As Variant
 
 
Private Sub Command1_Click()
    If LinkIndex <> -1 Then
        UserControl.Parent.Controls(LinkIndex).Text = "weqweqweqe"
    End If
End Sub
 
 
Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    Set ParentForm = UserControl.Parent
    ParentControlName = UserControl.Extender.Name
    
    m_LinkName = PropBag.ReadProperty("LinkName", m_def_LinkName)
    m_LinkIndex = PropBag.ReadProperty("LinkIndex", m_def_LinkIndex)
End Sub
'WARNING! DO NOT REMOVE OR MODIFY THE FOLLOWING COMMENTED LINES!
'MemberInfo=14,0,0,0
Public Property Get LinkName() As Variant
    LinkName = m_LinkName
End Property
 
Public Property Let LinkName(ByVal New_LinkName As Variant)
    m_LinkName = New_LinkName
    PropertyChanged "LinkName"
End Property
 
'Initialize Properties for User Control
Private Sub UserControl_InitProperties()
    m_LinkName = m_def_LinkName
    m_LinkIndex = m_def_LinkIndex
End Sub
 
'Write property values to storage
Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
    Call PropBag.WriteProperty("LinkName", m_LinkName, m_def_LinkName)
    Call PropBag.WriteProperty("LinkIndex", m_LinkIndex, m_def_LinkIndex)
End Sub
 
'WARNING! DO NOT REMOVE OR MODIFY THE FOLLOWING COMMENTED LINES!
'MemberInfo=7,0,0,-1
Public Property Get LinkIndex() As Integer
    LinkIndex = m_LinkIndex
End Property
 
Public Property Let LinkIndex(ByVal New_LinkIndex As Integer)
    m_LinkIndex = New_LinkIndex
    PropertyChanged "LinkIndex"
End Property
 
 
'in the property Page
Option Explicit
 
Private Sub List1_Click()
    Changed = True
End Sub
 
 
Private Sub PropertyPage_Initialize()
    On Error GoTo ErrorTrap
    Dim c As Control
    Dim index As Integer
    Dim Count As Integer
    
    List1.Clear
    
    For Each c In ParentForm.Controls 'this variable is set in the usercontrol
        Count = Count + 1
 
        'make sure the control isn't the usercontrol but is a textbox
        If c.Name <> ParentControlName And TypeOf c Is TextBox Then
            'ParentControlName is set in UC
            index = -1
            index = c.index ' part of an array, set to index else after err, index=-1
            If index = -1 Then
                'control is not part of an array
                List1.AddItem c.Name
                List1.ItemData(List1.NewIndex) = Count
            Else
                'control is part on an array
                List1.AddItem c.Name & "(" & index & ")"
                List1.ItemData(List1.NewIndex) = Count
            End If
        End If
    Next c
    Exit Sub
ErrorTrap:
    Resume Next
End Sub
 
 
Private Sub PropertyPage_ApplyChanges()
    SelectedControls(0).LinkName = List1.Text 'this is for show
    SelectedControls(0).LinkIndex = List1.ItemData(List1.ListIndex) - 1 'this is the actual link
End Sub