[RESOLVED] I want task manager waveform graphic on my Form

All,

How can I achieve this? I have serached the forums and been digging around for quite some time on this issue.

Has anyone been able to do this? A little green box like the one you see in the systray would be acceptable, but the green waveform is preferred (like the supplied pic)

Ideally, I would also like to store the values in a file as time goes on.

Thanks!

This will give you a start. I found this piece of code on a web page that isn't there any longer (at least the link I saved no longer works). I thought it was kind of cool, so I popped it in my Code Library in case I ever needed anything like it. Right now it just draws an ever scrolling wave type graph, but I'm sure you can tweak it so that it is graphing based on an actual something. Anyway, play around with this. It uses a Picturebox and a Timer control.

VB Code:

Option Explicit
 
Private Const SRCCOPY = &HCC0020 ' (DWORD) dest = source
Private Const PS_SOLID = 0
 
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long
 
Private Declare Function CreateCompatibleBitmap Lib "gdi32" _
(ByVal hdc As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
 
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, _
ByVal hObject As Long) As Long
 
Private Declare Function CreatePen Lib "gdi32" (ByVal nPenStyle As Long, _
ByVal nWidth As Long, ByVal crColor As Long) As Long
 
Private Declare Function LineTo Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, _
ByVal y As Long) As Long
 
Private Declare Function MoveToEx Lib "gdi32" (ByVal hdc As Long, _
ByVal x As Long, ByVal y As Long, ByVal lpPoint As Long) As Long
 
Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, _
ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, _
ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, _
ByVal dwRop As Long) As Long
 
Private Const pWidth = 250    ' Width of picture box in pixels.
Private Const pHeight = 150   ' Height of picture box in pixels.
Private Const pGrid = 25      ' Distance between grid lines.
Private Const tInterval = 100 ' Interval between timer samplings
                              ' in milliseconds.
Private Const pHeightHalf = pHeight \ 2
Private counter As Long  ' Number of data points logged so far. Used to
                     ' sync grid.
Private oldY As Long     ' Contains the previous y coordinate.
Private hDCh As Long, hPenB As Long, hPenC As Long
 
Private Sub Form_Load()
Dim hBmp As Long
    Dim i As Integer
    Me.Show
    Picture1.ScaleMode = 3
    Picture1.Left = 0
    Picture1.Top = 0
    Form1.ScaleMode = 3
    Picture1.Height = 155
    Picture1.Width = 255
    counter = 0
    hDCh = CreateCompatibleDC(Picture1.hdc)
    hBmp = CreateCompatibleBitmap(Picture1.hdc, pWidth, pHeight)
    Call SelectObject(hDCh, hBmp)
    hPenB = CreatePen(PS_SOLID, 0, vbBlack)
    hPenC = CreatePen(PS_SOLID, 0, vbRed)
    Call SelectObject(hDCh, hPenB)
 
' Plot horizontal grid lines.
    For i = pGrid To pHeight - 1 Step pGrid
        Picture1.Line (0, i)-(pWidth, i)
    Next
 
' Plot vertical grid lines.
    For i = pGrid - (counter Mod pGrid) To pWidth - 1 Step pGrid
        Picture1.Line (i, 0)-(i, pHeight)
    Next
 
    Call BitBlt(hDCh, 0, 0, pWidth, pHeight, Picture1.hdc, 0, 0, SRCCOPY)
    Timer1.Interval = 100
    Timer1.Enabled = True
    oldY = pHeightHalf
End Sub
 
Private Sub Timer1_Timer()
Dim i As Integer
Call BitBlt(hDCh, 0, 0, pWidth - 1, pHeight, hDCh, 1, 0, SRCCOPY)
 
    If counter Mod pGrid = 0 Then
        Call MoveToEx(hDCh, pWidth - 2, 0, 0)
        Call LineTo(hDCh, pWidth - 2, pHeight)
    End If
 
    i = Sin(0.1 * counter) * (pHeightHalf - 1) + pHeightHalf
 
    Call SelectObject(hDCh, hPenC)
    Call MoveToEx(hDCh, pWidth - 3, oldY, 0)
    Call LineTo(hDCh, pWidth - 2, i)
    Call SelectObject(hDCh, hPenB)
    Call BitBlt(Picture1.hdc, 0, 0, pWidth, pHeight, hDCh, 0, 0, SRCCOPY)
    counter = counter + 1
    oldY = i
End Sub

Yes that is a great start! I believe I might be able to dig up some APIs for accessing the system resource usage..?... Once I do, I should be able to plug those results directly into this graph. Cool!

When you get something that you like that is based on actual data (regardless of the source), post a sample project in the CodeBank.

I think others could benefit from something like this as well. :)

I will - my plan is to create a stand-alone OCX that is self-aware of it's source - in this case the Task Manager, but I have other uses for it as well.

The only banana-peel I can see is they set the scale-mode of the sample form to 3... Not sure how that will affect my normal Forms which always use the default scale-mode...

Using the class from this thread:
http://www.vbforums.com/showthread.php?t=324335

I made this:

[Edit] See my next post

Quote:

---

Originally Posted by CVMichael

Using the class from this thread:
http://www.vbforums.com/showthread.php?t=324335

I made this:

---

Put your project in the CodeBank. :thumb:

Quote:

---

Originally Posted by Hack

Put your project in the CodeBank. :thumb:

---

OK..
Done:
VB - Showing the CPU graph like in Windows Task Manager

(I'll delete the attachment in the previous post, since now it's in the CodeBank)

So cool CVMichael! I hope you don't mind I adapted your creation and posted it under your CodeBank post. So cool...

Here is a quick pic of the SmartControls.TaskMonitor as I just dropped it on a blank form and resized it and pressed F5!