Shell Execute

Hello,
We have two separate VB applications and i would like to join these two applications and would like to start the second application from the first one. I am using the Shell command to execute the Exe of the second one but my problem is i want to start the second application in a silent mode without the frontend of the first application and there is a ok button on the second application. So how can i tell my program to move to the OK button code.

Thanks in advance

reg
vbs

I think we need to do this step by step.

Quote:

---

Originally Posted by vbs

Hello,
We have two separate VB applications

---

So far so good

Quote:

---

Originally Posted by vbs

and i would like to join these two applications

---

What do you mean by "join"

Quote:

---

Originally Posted by vbs

and would like to start the second application from the first one. I am using the Shell command to execute the Exe of the second one

---

From the first one I presume

Quote:

---

Originally Posted by vbs

but my problem is i want to start the second application in silent mode without the front end of the first application

---

Here is where you lost me. :confused: If you don't have the front end of the first one how are you planning on shelling the second one?

You have application A.exe and application B.exe

A.exe shells B.exe - now what?

HI,
Thanks for your reply. I am sorry about the text which i had written earlier.
My application which i have written has a frontend and when i click a button on my application it should start the second application(written by my collegue) which also has a gui with a ok button andwhen a user clicks the ok button then a process of the second application starts so i do not want to display the frontend from the second application but want to ensure that the ok button click happens in the background may be by the first program itself.....

Hope that i have been able to explain a bit more.

Thanks again.

Best regards,
vbs

So if you know the name of the process that B.exe is executing then you can possible look for that process in the running processes list in a timer event and when found kill the timer and continue on with your A.exe program.

If I've understood you correctly you want to launch an application in the background and then press a button, to make that application do something.

The easiest way would be to get your collegue to modify their program to allow a command line argument which will automatically run the process.

If you need to do it yourself then something like this should work:

VB Code:

Private Declare Function GetDesktopWindow Lib "user32" () As Long
 
Private Declare Function GetWindow Lib "user32" ( _
                ByVal hwnd As Long, _
                ByVal wCmd As Long) As Long
                
Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
                ByVal hwnd As Long, _
                lpdwProcessId As Long) As Long
 
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" ( _
                ByVal hWnd1 As Long, _
                ByVal hWnd2 As Long, _
                ByVal lpsz1 As String, _
                ByVal lpsz2 As String) As Long
 
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
                ByVal hwnd As Long, _
                ByVal wMsg As Long, _
                ByVal wParam As Long, _
                ByVal lParam As Long) As Long
 
Private Const GW_CHILD = 5
Private Const GW_HWNDNEXT = 2
Private Const WM_LBUTTONDOWN = &H201     'Button down
Private Const WM_LBUTTONUP = &H202       'Button up
 
Private Sub Command1_Click()
    Dim lngHandle1 As Long
    Dim lngButtonHdl As Long
    lngHandle1 = pID2hWnd(Shell("AppB.exe", vbHide))
  
    If (lngHandle1 > 0) Then
        PressHandle FindWindowEx(lngHandle1, 0&, "Button", "OK")
    End If
End Sub
 
Private Function pID2hWnd(ByVal pID As Long) As Long
    'the Shell() function returns the Process ID (PID) for the newly spawned
    'process. Below we loop through every top-level window, get it's PID and
    'compare it to the one returned by the Shell() function. If it's the same,
    'we've found the window-handle (hWnd) to it!
    Dim lngHandle As Long, lngProcID As Long
    lngHandle = GetDesktopWindow
    lngHandle = GetWindow(lngHandle, GW_CHILD)
    Do
        If GetWindowThreadProcessId(lngHandle, lngProcID) <> 0 Then
            If lngProcID = pID Then
                pID2hWnd = lngHandle
                Exit Do
            End If
        End If
        lngHandle = GetWindow(lngHandle, GW_HWNDNEXT)
    Loop Until lngHandle = 0
End Function
 
Private Sub PressHandle(ByVal lHandle As Long)
  Dim lParam As Long
  lParam = MAKELONG(10, 5)
  SendMessage lHandle, WM_LBUTTONDOWN, 0, lParam
  SendMessage lHandle, WM_LBUTTONUP, 0, lParam
End Sub
 
Private Function LOWORD(ByVal dw As Long) As Integer
  If dw And &H8000& Then LOWORD = dw Or &HFFFF0000 Else LOWORD = dw And &HFFFF&
End Function
 
Private Function MAKELONG(wLow As Long, wHigh As Long) As Long
  MAKELONG = LOWORD(wLow) Or (&H10000 * LOWORD(wHigh))
End Function