External listview (nearly a year later still no results)

Hi all, I posted this thread nearly a year ago:

http://www.vbforums.com/showthread.p...ernal+listview


Still waiting on a reply, maybe one day.


Well anyway that old thread doesnt matter now. im about crazy, after reading endless threads on what i need and want but never actually any working example.. always a if or but or something.


I need to get the items of a listview in an external program, after over a year of looking for this on and off this is the closest (i think?) bit of code that can do it: (By someone called hax0r i think..)

VB Code:

Public Const PROCESS_QUERY_INFORMATION = 1024
Public Const PROCESS_VM_OPERATION = &H8
Public Const PROCESS_VM_READ = &H10
Public Const PROCESS_VM_WRITE = &H20
Public Const STANDARD_RIGHTS_REQUIRED = &HF0000
Public Const MAX_LVMSTRING As Long = 255
Public Const MEM_COMMIT = &H1000
Public Const PAGE_READWRITE = &H4
Public Const LVIF_TEXT As Long = &H1
 
Public Type LV_ITEMA
   mask         As Long
   iItem        As Long
   iSubItem     As Long
   state        As Long
   stateMask    As Long
   pszText      As Long
   cchTextMax   As Long
   iImage       As Long
   lParam       As Long
   iIndent      As Long
End Type
 
Public Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcId As Long) As Long
Public Declare Function VirtualAllocEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal flAllocationType As Long, ByVal flProtect As Long) As Long
Public Declare Function VirtualFreeEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal dwFreeType As Long) As Long
Public Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByRef lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Public Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByRef lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
 
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByRef lParam As Any) As Long
 
Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
 
Public Function GetListviewItem(ByVal hWindow As Long, ByVal ProcessID As Long, ByVal pColumn As Long, ByVal pRow As Long) As String
    Dim result              As Long
    Dim myItem              As LV_ITEMA
    Dim pHandle             As Long
    Dim pStrBufferMemory    As Long
    Dim pMyItemMemory       As Long
    Dim strBuffer()         As Byte
    Dim index               As Long
    Dim tmpString           As String
    Dim strLength           As Long
    
    '**********************
    'init the string buffer
    '**********************
    ReDim strBuffer(MAX_LVMSTRING)
    
    '***********************************************************
    'open a handle to the process and allocate the string buffer
    '***********************************************************
    pHandle = OpenProcess(PROCESS_VM_OPERATION Or PROCESS_VM_READ Or PROCESS_VM_WRITE, False, ProcessID)
    pStrBufferMemory = VirtualAllocEx(pHandle, 0, MAX_LVMSTRING, MEM_COMMIT, PAGE_READWRITE)
        
    '************************************************************************************
    'initialize the local LV_ITEM structure
    'The myItem.iSubItem member is set to the index of the column that is being retrieved
    '************************************************************************************
    myItem.mask = LVIF_TEXT
    myItem.iSubItem = pColumn
    myItem.pszText = pStrBufferMemory
    myItem.cchTextMax = MAX_LVMSTRING
    
    '**********************************************************
    'write the structure into the remote process's memory space
    '**********************************************************
    pMyItemMemory = VirtualAllocEx(pHandle, 0, Len(myItem), MEM_COMMIT, PAGE_READWRITE)
    result = WriteProcessMemory(pHandle, pMyItemMemory, myItem, Len(myItem), 0)
    
    '*************************************************************
    'send the get the item message and write back the memory space
    '*************************************************************
    result = SendMessage(hWindow, LVM_GETITEMTEXT, pRow, ByVal pMyItemMemory)
    result = ReadProcessMemory(pHandle, pStrBufferMemory, strBuffer(0), MAX_LVMSTRING, 0)
    result = ReadProcessMemory(pHandle, pMyItemMemory, myItem, Len(myItem), 0)
      
    '**************************************************
    'turn the byte array into a string and send it back
    '**************************************************
    For index = LBound(strBuffer) To UBound(strBuffer)
        If Chr(strBuffer(index)) = vbNullChar Then Exit For
        tmpString = tmpString & Chr(strBuffer(index))
    Next index
    
    tmpString = Trim(tmpString)
    
    '**************************************************
    'deallocate the memory and close the process handle
    '**************************************************
    result = VirtualFreeEx(pHandle, pStrBufferMemory, 0, MEM_RELEASE)
    result = VirtualFreeEx(pHandle, pMyItemMemory, 0, MEM_RELEASE)
    
    result = CloseHandle(pHandle)
    
    If Len(tmpString) > 0 Then GetListviewItem = tmpString
 
End Function

Sadly he didnt mention how to call it or anything about processid :mad: but i searched on "processid" and couldnt find much as im not even sure what im looking for.

So maybe just an example/ more detail on this function would be great..

Im pretty sure the listview i want to get at isnt user drawn, i logged its "listview" messages and didnt see any wm_user msgs... when i logged another listview i seen lots of wm_users, if im only seeing listview messages does this means its not user drawn?


Please help
Regards,

:afrog:

are you using VB6 by the look of those calls?
if so...
you need to be calling GetWindowThreadProcessId first on the listview's handle.
*** note , if you are using VB.NET, you need to be specifying IntPtr's instead of the Long's ***
eg:

VB Code:

[COLOR=Blue]Dim[/COLOR] processID [COLOR=Blue]As Long[/COLOR]
[COLOR=Blue]Dim[/COLOR] proc [COLOR=Blue]As Long[/COLOR]
 
    '/// get the processID of the listview ...
    GetWindowThreadProcessId(" handle to Listview here !!! " , processID)
    '/// now you have the processID ...
    proc = OpenProcess(PROCESS_VM_OPERATION [COLOR=Blue]Or[/COLOR] PROCESS_VM_READ [COLOR=Blue]Or[/COLOR]  PROCESS_VM_WRITE [COLOR=Blue]Or[/COLOR] PROCESS_QUERY_INFORMATION , [COLOR=Blue]False[/COLOR], processID)
 
[COLOR=Green]'/// then continue with your[/COLOR] [B][COLOR=DarkOrange]VirtualAllocEx[/COLOR][/B]

still no joy returns null strings

you didn't confirm if it's vb6 you are using.
you will need to convert the pointer to a string when using readmemory whatever you are using.

if you know C# / VB.NET @ all , here's a link to an example in C# ( also an MFC example ) , which i have tested in C# and it works.
i joined an msn groups chatroom and added the FindWindow / FindWindowEx api's to the linked example, found the Handle for the listview in the msn chatroom & retrieved the names in the listview.
the link to the example is ... Crossing the process boundry with .NET :)

Sorry Im in vb6!

dynamic_sysop I surpose it would be a bit much to ask for an example in vb?

Its Yahoo chat room lists that im messing with by the way.

i don't have vb6 loaded on my pc, i only run vs2003 & vs2005.

what benefits will you gain from tapping in to the nick list on yahoo?
i'm of the understanding that their chat servers are tight run with little scope for sending any additional commands.

i used to run msn chatrooms & made numerous irc bots for msn chat, took me a while to tap in to the msn listview in those days too ;)
but i ended up being one of only 2 people that had managed it :D

if i ever get chance, with havin 5 kids @ home :sick: i can knock an example up in vb.net, but that's as close as i can get with it these days.
so you would have to deal with the pointers to string in the vb6 way ( maybe copymemory to a byte array, then using StrConv will guide you )

Thanks for all your efforts, I'm new to C++ so maybe source files would help me out, I seen the c++ code but don't know enough about c++ to compile it, etc.

Thanks

The Scripit offered here did return 0 as Process Id

VB Code:

Function GetListViewProcId(Ihwnd As Long) As Long
 Dim processID As Long
 Dim proc As Long
 Dim ThreadID As Long
 
    '/// get the processID of the listview ...
    ThreadID = GetWindowThreadProcessId(Ihwnd, processID)
    '/// now you have the processID ...
    proc = OpenProcess(PROCESS_VM_OPERATION Or PROCESS_VM_READ Or PROCESS_VM_WRITE Or PROCESS_QUERY_INFORMATION, False, processID)
    GetListViewProcId = proc
    
End Function

This Script give a correct ThreadID to the listview But processID is 0 can any one give a hint plz

The process ID of the listview should be the same for it's parent window, try getting that process ID.

To select all item in listview, try this:

i used c++ and vb.net

for the c++ dll:

Code:

---

#include "stdafx.h"
#include "Commctrl.h"



#pragma data_seg(".shared")
        HWND _hTarget = 0;
        HHOOK hook=0;
       
#pragma data_seg()
#pragma comment(linker, "/SECTION:.shared,RWS")

LVITEM *lvItem;
char lpText[255];
HINSTANCE hInst;
bool flag = true;;



//send LVM_GETITEMTEXT message from within external app's process
int getLVText(HWND hTarget)
{
        lvItem = new LVITEM;
       
        lvItem->mask = LVIF_STATE;
        lvItem->stateMask = LVIS_SELECTED;
        lvItem->state = 15;

        int res = SendMessage(hTarget, LVM_SETITEMSTATE, -1, (long)lvItem);
       
        if (res != 0)
        {
                flag = false;
                return 1;
        }
        return 0;
}

BOOL APIENTRY DllMain( HANDLE hModule,
                      DWORD  ul_reason_for_call,
                      LPVOID lpReserved
                                        )
{
        hInst = (HINSTANCE)hModule;
    return TRUE;
}


LRESULT CALLBACK hookproc(int nCode, WPARAM wParam, LPARAM lParam)
{
        if(flag)  //I put the flag so it only calls getLVText once
        {
                getLVText(_hTarget);
        }
        return ::CallNextHookEx(hook, nCode, wParam, lParam);
}


//these codes injects the dll into external app's process
__declspec(dllexport) int _stdcall installHook(HWND hTarget)
{
        _hTarget = hTarget;
        DWORD tid;
        tid = ::GetWindowThreadProcessId(hTarget, 0);
        hook = ::SetWindowsHookEx(WH_GETMESSAGE, hookproc, hInst, tid);
        if (hook != NULL)
                return 1;
        return 0;
}

---

now for the vb.net code that calls the dll function installHook():

VB Code:

Public Declare Function installHook Lib "C:\Program Files\Microsoft Visual Studio\MyProjects\getListView\Debug\getListView.dll" (ByVal hwnd As Integer) As Integer
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
     Dim hTarget As Integer 'the handle to the target ListView control, Im sure you could implement the code to get the handle
     Dim res As Integer = installHook(hTarget)
End Sub

Thank for sharing this code benmartin101 . Could u tell me how use your code in visual studio 6 . I want to be able to external list view items from with in m vb6 application so i be happy if u explain to me how i can compile and run it.Thanks

Well, the c++ code can't really be done in vb6 because to inject code, it has to be in a win32 dll. You need to create the dll. I include the c++ project so you can compile it yourself.

For the vb6 code:

VB Code:

Private Declare Function installHook Lib "C:\Program Files\Microsoft Visual Studio\MyProjects\getListView\getListView\getListView.dll" (ByVal hwnd As Long) As Long
Private Declare Function removeHook Lib "C:\Program Files\Microsoft Visual Studio\MyProjects\getListView\getListView\getListView.dll" () As Long
Private Declare Sub doSelect Lib "C:\Program Files\Microsoft Visual Studio\MyProjects\getListView\getListView\getListView.dll" ()
 
 
Private Sub Command1_Click()
Dim x As Long
Dim targetHwnd as Long   'you need the targets window handle
x = installHook(targetHwnd)
 
End Sub
 
Private Sub Command2_Click()  
Call doSelect   'this lets you select all the items after calling installHook
End Sub
 
Private Sub Command3_Click()
Dim x As Long
x = removeHook()  'removes the hook
End Sub

Thank u for u reply. I created a project and placed 3 buttons in the form and when i click on them i get the following errors:

http://i5.photobucket.com/albums/y180/method007/dam.jpg

code :

Code:

---

Private Declare Function installHook Lib "C:\getListView.dll" (ByVal hwnd As Long) As Long
Private Declare Function removeHook Lib "C:\getListView.dll" () As Long
Private Declare Sub doSelect Lib "C:\getListView.dll" ()


Private Sub Command1_Click()
Dim x As Long
Dim targetHwnd As Long  'you need the targets window handle
x = installHook(targetHwnd)

End Sub

Private Sub Command2_Click()
Call doSelect  'this lets you select all the items after calling installHook
End Sub

Private Sub Command3_Click()
Dim x As Long
x = removeHook()  'removes the hook
End Sub

---

Furthermore, how should i display the items that i got from external app to my form if it rurns ?Thanks

I'm not sure what exactly you want it to do, but the program just selects all the items; basically highlights them as if you clicked on the file/folder.

Now for the error, are you using the dll that was in the zip file? If so, that may not be current, you might want to run the project and compile the dll yourself.

Quote:

---

Originally Posted by benmartin101

I'm not sure what exactly you want it to do, but the program just selects all the items; basically highlights them as if you clicked on the file/folder.

Now for the error, are you using the dll that was in the zip file? If so, that may not be current, you might want to run the project and compile the dll yourself.

---

thank u for u reply. well i have an external listview open and tried it with new compiled dll from your above zip file but still i get those errors. Do i need any perticule components or module or my the above code is wrong ?Thanks

Perhaps the path of the dll when you declare the functions is in the wrong path.

Private Declare Function removeHook Lib "C:\getListView.dll" () As Long <- maybe you might want to make sure about the path.

I have now a complete module that Handle the External list view working good and and no crashes. if u are interested plz let me know

Quote:

---

Originally Posted by Servant

I have now a complete module that Handle the External list view working good and and no crashes. if u are interested plz let me know

---

Thanks could u upload the complete project that allow me highlight external listview.

I could really use that example too. Please someone send it to me.
[email protected]

I could really use that example too. Servant, please send it to me.
[email protected]

thx in advance.

benmartin101,

I've got your code and it works fine for me. thx a lot.

Now, I'm trying to get listview subitem text.

So, I've edited your code and ad a new function, getSubItemText:

PS: I don't know C++.

Code:

---

__declspec(dllexport) LPCSTR _stdcall getSubItemText(HWND lvwHwnd, int item, int index)
{
        // LVITEM struct (see MSDN for content) :
    LVITEM lvi;

        // 5000 MAX LENGTH

        // String buffer for pszText member of LVITEM struct :
        unsigned char LVtext[5000];

        memset(&lvi, 0, sizeof(lvi));  // Clean up before action
    // Fill in the members of the LVITEM struct :
    lvi.mask = LVIF_TEXT;
    // Minimum here to take care of the pszText member
    // - see other LVIF_xxx constants in MSDN

    lvi.state = 0;
    lvi.stateMask = 0;
    // lvi.iSubItem : not here, see 'j' loop below
    lvi.cchTextMax = 5000 - 1;
    // Length of string to be copied into pszText member

    lvi.pszText = (LPSTR)LVtext;
    // String buffer for pszText member

        // Important member of LVITEM struct you
    // need to fill in (j=0 : item; j>0 : subitem) :
    lvi.iSubItem = index;
    // Retrieve the text in an item or a subitem of line 'i' :
        SendMessage(lvwHwnd, LVM_GETITEMTEXT, (WPARAM) item, (LPARAM) &lvi);

        return (LPCSTR)LVtext;
}

---

I've edited getListView.def

Code:

---

LIBRARY getListView

EXPORTS
        installHook
        getItemText
        getItemCount
        getSubItemText

---

DLL compiles with success.

In my test app (VB.NET):

Code:

---

    Public Declare Function getSubItemText Lib "C:\getListView\Debug\getListView.dll" (ByVal hwnd As Integer, ByVal item As Integer, ByVal index As Integer) As IntPtr

Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        Dim strPtr As IntPtr = getSubItemText(1447178, 0, 1)  '0 based
        Dim str As String = Marshal.PtrToStringAnsi(strPtr)
        MsgBox(str)
    End Sub

---

So, i click button 1 (hooked!), click button2 (show me the right item text! :) ), and click button 3 and got a lot of special characters, i.e., not the subitem text.

I found this code (merged with your code to get subitem text) here:
http://www.codeproject.com/listctrl/fexportlistview.asp


Please, help me.

Marco, you may want to check this thread:

http://www.vbforums.com/showthread.php?t=397764

Any of you guys no about getting the tooltip text of a listview item? I have some code from a guy here to get the listview items (external program) but no idea bout getting the tooltip text

cr250, please, can you send your code to get external listview items??

I'll search on the net how we can get listview item tooltip.

thx in advance.

best regards,
marco alves

i'll make a post containing it in a minute in new thread

ok, paste the link here, please (other people will can access it easily in the future). thx a lot!

I didn't try the code Cr250 posted but here is similar looking code that works for me. Unfortunately it does not seem to be releasing the allocated memory when I use it.

VB Code:

Option Explicit
 
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcId As Long) As Long
Private Declare Function VirtualAllocEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal flAllocationType As Long, ByVal flProtect As Long) As Long
Private Declare Function VirtualFreeEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal dwFreeType As Long) As Long
Private Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Long, ByRef lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Long, ByRef lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function ReadProcessMemoryStr Lib "kernel32" Alias "ReadProcessMemory" (ByVal hProcess As Long, ByVal lpBaseAddress As Long, ByVal lpBuffer As String, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Const PROCESS_VM_OPERATION = &H8
Private Const PROCESS_VM_READ = &H10
Private Const PROCESS_VM_WRITE = &H20
Private Const MAX_LVMSTRING As Long = 255
Private Const MEM_COMMIT = &H1000
Private Const MEM_DECOMMIT = &H4000
Private Const MEM_RELEASE = &H8000
Private Const PAGE_READWRITE = &H4
Private Const LVIF_TEXT As Long = &H1
Private Const LVM_FIRST = &H1000
Private Const LVM_GETITEMTEXT = LVM_FIRST + 45
Private Const LVM_GETITEMCOUNT = LVM_FIRST + 4
 
Private Type LV_ITEM
   mask         As Long
   iItem        As Long
   iSubItem     As Long
   state        As Long
   stateMask    As Long
   pszText      As Long
   cchTextMax   As Long
   iImage       As Long
   lParam       As Long
   iIndent      As Long
End Type
 
Private Function GetListviewItem(ByVal hWindow As Long, ByVal iItem As Long, ByVal subItem As Long) As String
Dim Result As Long, pHandle As Long, ProcessID As Long, Index As Long
Dim pStrBufferMemory As Long, pMyItemMemory As Long, strLength As Long
Dim strBuffer As String, tmpString As String, LVItem As LV_ITEM
 
    GetWindowThreadProcessId hWindow, ProcessID
 
    pHandle = OpenProcess(PROCESS_VM_OPERATION Or PROCESS_VM_READ Or PROCESS_VM_WRITE, False, ProcessID)
    
    pStrBufferMemory = VirtualAllocEx(pHandle, 0, MAX_LVMSTRING, MEM_COMMIT, PAGE_READWRITE)
 
    LVItem.mask = LVIF_TEXT
    LVItem.iSubItem = subItem
    LVItem.pszText = pStrBufferMemory
    LVItem.cchTextMax = MAX_LVMSTRING
 
    pMyItemMemory = VirtualAllocEx(pHandle, 0, LenB(LVItem), MEM_COMMIT, PAGE_READWRITE)
 
    Result = WriteProcessMemory(pHandle, pMyItemMemory, LVItem, Len(LVItem), 0)
 
    strLength = SendMessage(hWindow, LVM_GETITEMTEXT, iItem, ByVal pMyItemMemory)
    strBuffer = Space(strLength)
    Result = ReadProcessMemoryStr(pHandle, pStrBufferMemory, strBuffer, strLength, 0)
 
    Result = VirtualFreeEx(pHandle, pStrBufferMemory, 0&, MEM_RELEASE)
    Result = VirtualFreeEx(pHandle, pMyItemMemory, 0&, MEM_RELEASE)
    Result = CloseHandle(pHandle)
    
    GetListviewItem = strBuffer
    
End Function
 
Private Function GetHandle(ParentTitle As String, ParentWindow As String, ChildWindow As String) As Long
Dim hWnd1 As Long, hWndEx As Long
 
    hWnd1 = FindWindow(vbNullString, ParentTitle)
    If hWnd1 <> 0 Then
        hWndEx = FindWindowEx(hWnd1, 0&, ParentWindow, vbNullString)
        hWndEx = FindWindowEx(hWndEx, 0&, ChildWindow, vbNullString)
        GetHandle = hWndEx
    Else
        Debug.Print "Could not get handle"
    End If
    
End Function
 
Private Sub Form_Load()
Dim hWnd1 As Long, Count As Integer, i As Integer
    
    hWnd1 = GetHandle("External App Title", "Parent of LV", "SysListView32")
    If hWnd1 <> 0 Then
        Count = SendMessage(hWnd1, LVM_GETITEMCOUNT, 0&, 0&)
        For i = 0 To Count - 1
            Debug.Print GetListviewItem(hWnd1, i, 0)
        Next i
    End If
    
End Sub

yes thats the same one i have

Quote:

---

Originally Posted by Cr250

yes thats the same one i have

---

trying to copy code to try it but can't find out how to copy it. If I just highlight code in box and copy it, all the linefeeds are missing. How do I copy code with all the linefeeds intact. Also did you ever get this working.
Thanks.

Welcome to the forums. :wave:

Quote:

---

Originally Posted by ed08724

trying to copy code to try it but can't find out how to copy it. If I just highlight code in box and copy it, all the linefeeds are missing. How do I copy code with all the linefeeds intact.

---

This is a know issue with the code highlight feature. See these two threads by Martin Liss that address this.

http://www.vbforums.com/showthread.php?t=458328
http://www.vbforums.com/showthread.php?t=458438