Radiobutton Cast [RESOLVED]

Hello!
I'm trying to loop through all the radiobuttons of a form, and clear their checks

What I'vo got so far is:

VB Code:

Dim MPrd1 As Control
                For Each MPrd1 In Me.Controls
                    If TypeOf MPrd1 Is RadioButton Then
                          [b]MPrd1.Checked = False[/b]
                    End If
                Next

But now the compiler says that .Checked (the bolded line) is not a member of System.Windows.Forms.Control.
What am I doing wrong?

Well the compiler is correct, Checked is not a member of the Control class, so can't use it. But instead what you can do is this

VB Code:

Dim rbTemp As RadioButton
        For Each MPrd1 As Control In Me.Controls
            If TypeOf MPrd1 Is RadioButton Then
                rbTemp = MPrd1
                rbTemp.Checked = False
            End If
        Next

Or just replace this line...

MPrd1.Checked = False

with...

CType(MPrd1,radiobutton).Checked = False

Bob

How could I forget about CType. Bob's way of doing it is better.

Ok, Thanx for both replies,
I have tried both methods, but the radio buttons do not get unchecked :ehh:
I've got 5 rd buttons in 1 panel, then I have 3 rd buttons in another panel - do you think that it's the panels causing the problems?

Quote:

---

Originally Posted by GrimmReaper

Ok, Thanx for both replies,
I have tried both methods, but the radio buttons do not get unchecked :ehh:
I've got 5 rd buttons in 1 panel, then I have 3 rd buttons in another panel - do you think that it's the panels causing the problems?

---

Well when you have RadioButtons placed on the Panels then you will have to loop through the Controls collection of panel.

VB Code:

For Each ctTemp As Control In Me.Controls
            If TypeOf ctTemp Is Panel Then
                For Each rbTemp As Control In CType(ctTemp, Panel).Controls
                    If TypeOf rbTemp Is RadioButton Then
                        CType(rbTemp, RadioButton).Checked = False
                    End If
                Next
            End If
        Next

You also need to iterate through the controls in each panel. Something along the lines of....

VB Code:

For Each ctl As Control In Me.Controls
'Checks for radiobtns not in panels
            If TypeOf ctl Is RadioButton Then
                CType(ctl, RadioButton).Checked = False
            End If
'checks radion buttons in panels
            If TypeOf ctl Is Panel Then
                For Each pctl As Control In ctl.Controls
                    If TypeOf pctl Is RadioButton Then
                        CType(pctl, RadioButton).Checked = False
                    End If
                Next
            End If
        Next ctl

Bob

ARGH - Beat me to it.

Here's how to visit every control on a form regradless of how deep it's nested, coupled with unchecking RadioButtons:

VB Code:

Dim ctl As Control = Me.GetNextControl(Me, True) 'Get the first control in the tab order.
 
        Do Until ctl Is Nothing
            'Use ctl here.
            If TypeOf ctl Is RadioButton Then
                DirectCast(ctl, RadioButton).Checked = False
            End If
 
            ctl = Me.GetNextControl(ctl, True) 'Get the next control in the tab order.
        Loop

Wow!
I thought that the panel might be the problem - it makes sense to loop through then check if panel etc. because the panel is also a container :blush:
Thanx, my friends - you saved my day!

What if I have two radio buttons in a panel and already check one of them with an specific value or name in run time. I need to know the one checked and in a MsgBox or in a textbox the value or name assing to it.

Dim rbttnM As New RadioButton()
Dim rbttnF As New RadioButton()
For Each ctrl As Control In Me.Controls("pnlMainPanel").Controls
If ctrl.GetType Is GetType(System.Windows.Forms.Panel) Then
For Each subCtrl As Control In ctrl.Controls
If subCtrl.GetType Is GetType(System.Windows.Forms.TextBox) Then
MsgBox(subCtrl.Text)
End If

If subCtrl.GetType Is GetType(System.Windows.Forms.ComboBox) Then
MsgBox(subCtrl.Text)
End If
If subCtrl.GetType Is GetType(System.Windows.Forms.RadioButton) Then
If CType(subCtrl.Controls("rbttnM"), RadioButton).Checked Then
MsgBox("Male")
End If
If CType(subCtrl.Controls("rbttnF"), RadioButton).Checked Then
MsgBox("Female")
End If
End If
Next
End If
Next
End Sub

In code line If CType(subCtrl.Controls("rbttnM"), RadioButton).Checked Then error :

An unhandled exception of type 'System.NullReferenceException' occurred

Additional information: Object reference not set to an instance of an object.

Code:

---

Dim rbttnM As New RadioButton()
        Dim rbttnF As New RadioButton()
        For Each ctrl As Control In Me.Controls("pnlMainPanel").Controls
            If ctrl.GetType Is GetType(System.Windows.Forms.Panel) Then
                For Each subCtrl As Control In ctrl.Controls
                    If subCtrl.GetType Is GetType(System.Windows.Forms.TextBox) Then
                        MsgBox(subCtrl.Text)
                    End If

                    If subCtrl.GetType Is GetType(System.Windows.Forms.ComboBox) Then
                        MsgBox(subCtrl.Text)
                    End If
                    If subCtrl.GetType Is GetType(System.Windows.Forms.RadioButton) Then
                        If CType(subCtrl.Controls("rbttnM"), RadioButton).Checked Then
                            MsgBox("Male")
                        End If
                        If CType(subCtrl.Controls("rbttnF"), RadioButton).Checked Then
                            MsgBox("Female")
                        End If
                    End If
                Next
            End If
        Next
    End Sub

---

Quote:

---

Originally Posted by ebellounisoft

In code line If CType(subCtrl.Controls("rbttnM"), RadioButton).Checked Then error :

An unhandled exception of type 'System.NullReferenceException' occurred

Additional information: Object reference not set to an instance of an object.

---

That means that that container has no control with that name in it.

Quote:

---

Originally Posted by ebellounisoft

Code:

---

Dim rbttnM As New RadioButton()
        Dim rbttnF As New RadioButton()
        For Each ctrl As Control In Me.Controls("pnlMainPanel").Controls
            If ctrl.GetType Is GetType(System.Windows.Forms.Panel) Then
                For Each subCtrl As Control In ctrl.Controls
                    If subCtrl.GetType Is GetType(System.Windows.Forms.TextBox) Then
                        MsgBox(subCtrl.Text)
                    End If

                    If subCtrl.GetType Is GetType(System.Windows.Forms.ComboBox) Then
                        MsgBox(subCtrl.Text)
                    End If
                    If subCtrl.GetType Is GetType(System.Windows.Forms.RadioButton) Then
                        If CType(subCtrl.Controls("rbttnM"), RadioButton).Checked Then
                            MsgBox("Male")
                        End If
                        If CType(subCtrl.Controls("rbttnF"), RadioButton).Checked Then
                            MsgBox("Female")
                        End If
                    End If
                Next
            End If
        Next
    End Sub

---

---

That code looks rather nonsensical. For one thing, it starts out by creating two RadioButton objects that will never be used.

Quote:

---

Originally Posted by ebellounisoft

What if I have two radio buttons in a panel and already check one of them with an specific value or name in run time. I need to know the one checked and in a MsgBox or in a textbox the value or name assing to it.

---

That question has a very simple answer. You certainly don't need code nearly as complex as that above. If you only have two RadioButtons then just use a simple If...ElseIf statement. The container is then irrelevant.

vb.net Code:

If firstRadioButton.Checked Then
    '...
ElseIf secondRadioButton.Checked Then
    '...
End If

If you want to handle an arbitrary number of RadioButtons then you can do this:

vb.net Code:

Dim checkedRadioButton = myContainer.Controls.OfType(Of RadioButton)().SingleOrDefault(Function(rb) rb.Checked)
 
If checkedRadioButton IsNot Nothing Then
    '...
End If

You might use the Text property of the RadioButton or, if you want a different value, you can set the Tag in the designer and then use that. If you know for a fact that a RadioButton will be checked then use Single instead of SingleOrDefault and omit the test for Nothing.

CAN SOME ONE HELP ME. HOW DO I START A THREAD. I ASK FOR HELP IN CONTACT US OF VBForums BUT NO ANSWER. WHAT LINK IN MAIN PAGE HAVE TO CLICK TO START NEW THREAD. THANK YOU.

To start a new thread, go to the forum you want to post it in (probably Visual Basic .Net), then click on the "Post New Thread" button.

Got it. Thank you !!!.

I can see if it is checked. That is easy,assining a variable to the checked button but what is the code to get the text of the button checked ?. I Try to use MsgBox (ctrl.Text) for the Male button and MsgBox (ctrl.Text) for the Female button, for example, but get an error that can convert a promt to a string.