[RESOLVED] Assigning scroll bars to a picture box.

Basically I want to load an image from file into a picture box and keep the picture box at the same size, but be able to scroll around the image using scroll bars.

I have tried using two scroll bar controls for this, but I can't seem to get it working how I would like.

Anyone got a decent method or tips on how I can do this?

Cheers

See Martin's example here.

add 2 scroll bars (1-vert, 1 horz), and 2 picture boxes (first acts like a container and another contains the picture). and try this code: (you may need to modify a bit, not tested)

VB Code:

Private Sub Form_Load()
 
    VScroll1.Height = picture1.Height
    HScroll1.Width = picture1.Width
    VScroll1.Max = picture2.Height - picture1.Height
    HScroll1.Max = picture2.Width - picture1.Width
 
    VScroll1.SmallChange = 100
    HScroll1.SmallChange = 100
    VScroll1.LargeChange = picture1.Height
    HScroll1.LargeChange = picture1.Width    
End Sub
 
Public Sub myKeyCodefunc(KeyCode As Integer)
 
    Dim myScrValue As Double
    Dim pageheight As Integer
    
    pageheight = Me.VScroll1.Height
    
    If KeyCode = vbKeyPageUp Or KeyCode = vbKeyPageDown Then
        If KeyCode = vbKeyPageDown Then
            myScrValue = -Me.picture2.Top + pageheight
        Else
            myScrValue = -Me.picture2.Top - pageheight
        End If
        
        If myScrValue > Me.VScroll1.Max Then
            myScrValue = Me.VScroll1.Max
            Me.picture2.Top = -Me.VScroll1.Max
        End If
        If myScrValue > 0 Then
            Me.VScroll1.Value = myScrValue
        Else
            Me.VScroll1.Value = 0
        End If
    End If
    
End Sub
 
Private Sub HScroll1_Change()
 
    picture2.Left = -(HScroll1.Value)
 
End Sub
 
Private Sub Picture2_KeyDown(KeyCode As Integer, Shift As Integer)
 
    myKeyCodefunc KeyCode
    
End Sub
 
Private Sub VScroll1_Change()
 
    picture2.Top = -(VScroll1.Value)
 
End Sub

Thanks Hack, that's just what I needed. (I should have searched really)

Thanks Harsh Gupta too.

*Solved*