Is there any way to stop Window-Resize Animation for my Form only ?

Is there any way to stop Window-Resize Animation for my Form only ?

I'm changing the Form from vbMaximized/vbNormal mode to fullscreen-mode. The animation looks bad.

VB Code:

Private Sub cmdFullScreen_Click()
 
    If IsFullScreen Then 'change to Maximized
    
        RemoveTitlebar Me.hwnd ' This Sub removes titlebar at runtime
        Me.WindowState = vbMaximized
        IsFullScreen = False
        
    Else
    
        Titlebar False, Me.hwnd
        Me.WindowState = vbNormal ' A maximized/Minimized form
        '                           Can't be moved
        Me.Move 0, 0, Screen.Width, Screen.Height
        IsFullScreen = True
    
    End If
 
End Sub

~BuMp~

you could use LockWindowUpdate I doubt it'll give you the final look you want, but it might go a smidging towards it.

Perhaps instead of removing the titlebar/borders etc, you could subclass the WM_GETMAXMININFO message and position the window with a negative Left and Top properties depending on the GetSystemMetrics values

Thanks for your reply. :thumb:
I have some problems :

1. Can't find any English documentation of WM_GETMAXMININFO.
2. If I don't remove titlebar, the form doesn't fill the taskbar.

VB Code:

Me.Move 0, Me.ScaleHeight - Me.Height, _
                Screen.Width, Screen.Height * 2 ' Doesn't work

ok, i've managed to find a solution.

Subclassing WM_GETMINMAXINFO turned out not to work because you could set the max X < 0 or the max Y < 0 but not both at the same time (useful).

Instead you can set the dimensions of what the window should look like when in a Normal state even when it's in a Maximized state, so it doesn't return to it's previous size it returns to one you set, which in this case will be exactly the same as the dimensions for maximized:

VB Code:

Option Explicit
 
Private Declare Function GetWindowPlacement Lib "user32" (ByVal hwnd As Long, lpwndpl As WINDOWPLACEMENT) As Long
Private Declare Function SetWindowPlacement Lib "user32" (ByVal hwnd As Long, lpwndpl As WINDOWPLACEMENT) As Long
 
Private Declare Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long
 
Private Const SM_CYCAPTION = 4
Private Const SM_CXFRAME = 32
Private Const SM_CYFRAME = 33
 
Private Type POINTAPI
  x As Long
  y As Long
End Type
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
 
Private Type WINDOWPLACEMENT
  Length As Long
  flags As Long
  showCmd As Long
  ptMinPosition As POINTAPI
  ptMaxPosition As POINTAPI
  rcNormalPosition As RECT
End Type
 
Private m_OrigPos As WINDOWPLACEMENT
 
Private Sub CreateMaximizedLook()
  Dim winTempPlace As WINDOWPLACEMENT
  
  winTempPlace.Length = Len(winTempPlace)
  GetWindowPlacement Me.hwnd, winTempPlace
  
  With winTempPlace.rcNormalPosition
    .Left = -GetSystemMetrics(SM_CXFRAME)
    .Top = -GetSystemMetrics(SM_CYFRAME)
    .Right = Screen.Width + GetSystemMetrics(SM_CXFRAME)
    .Bottom = Screen.Height + GetSystemMetrics(SM_CYFRAME)
  End With
  
  winTempPlace.Length = Len(winTempPlace)
  
  SetWindowPlacement Me.hwnd, winTempPlace
End Sub
 
Private Sub Command1_Click()
  If Me.WindowState = vbMaximized Then
    CreateMaximizedLook
    Me.WindowState = vbNormal
  End If
End Sub

obviously you'd have to add a variable that remembers what its true Normal position is for when you want to change back, but SetWindowPlacement and GetWindowPlacement provide the solution you need

Thanks ! I tried your code. It works almost OK. :thumb:
But still 2 problems, :(

First problem was with titlebar. I solved it by adding,
.Top = -GetSystemMetrics(SM_CYFRAME) + Me.ScaleHeight - (Me.Height / Screen.TwipsPerPixelY)

The second problem is, the tsakbar still stays on top. In case of borderless window, it goes behind the form. Any more ideas ?

The code I supplied was meant to go with your previous code

so if you're window is Maximized and you want it to go to fullscreen then call CreateMaximizedLook and then continue with the stuff you were doing before.

You mean I still have to remove titlebar ?

I have merged your code into mine. If I remove titlebar, the Taskbar goes behind, but if I don't, it stays on top.

what code are you using to remove the titlebar?

Found it somewhere on the web. (may be in mvps.org)

VB Code:

Option Explicit
 
' Win32 APIs used to toggle border styles.
Private Declare Function GetWindowLong Lib "user32" _
    Alias "GetWindowLongA" _
        (ByVal hwnd As Long, _
         ByVal nIndex As Long) As Long
    
Private Declare Function SetWindowPos Lib "user32" _
        (ByVal hwnd As Long, _
         ByVal hWndInsertAfter As Long, _
         ByVal x As Long, _
         ByVal y As Long, _
         ByVal cx As Long, _
         ByVal cy As Long, _
         ByVal wFlags As Long) As Long
 
Private Const GWL_STYLE = (-16)
Private Const WS_CAPTION = &HC00000
 
'Force total pRedraw that shows new styles.
Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOZORDER = &H4
Private Const SWP_NOSIZE = &H1
 
'==================================================================
 
Private Function fStyle(mhWnd As Long, _
                        Optional ByVal NewBits As Long = 0) As Long
 
    ' Set new style bits.
    If NewBits Then
        Call SetWindowLong(mhWnd, GWL_STYLE, NewBits)
    End If
 
    ' Retrieve current style bits.
    fStyle = GetWindowLong(mhWnd, GWL_STYLE)
 
End Function
 
'==================================================================
 
Private Sub pRedraw(mhWnd As Long)
 
    ' Redraw window with new style.
    Const swpFlags As Long = SWP_FRAMECHANGED Or SWP_NOMOVE Or _
       SWP_NOZORDER Or SWP_NOSIZE
    Call SetWindowPos(mhWnd, 0, 0, 0, 0, 0, swpFlags)
 
End Sub
 
'==================================================================
 
Public Sub ShowTitlebar(ByVal Value As Boolean, mhWnd As Long)
 
    ' Set WS_CAPTION On or Off as requested.
    If CBool(fStyle(mhWnd) And WS_CAPTION) And Value = False Then
        'Hide the titkebar
        Call fFlipBit(WS_CAPTION, Value, mhWnd)
    ElseIf Not CBool(fStyle(mhWnd) And WS_CAPTION) And Value = True Then
        'Show the titkebar
        Call fFlipBit(WS_CAPTION, Value, mhWnd)
    End If
 
End Sub
 
'==================================================================
 
Private Function fFlipBit(ByVal Bit As Long, _
                          ByVal Value As Boolean, _
                          mhWnd As Long) As Boolean
 
    Dim lStyle As Long
    ' Retrieve current style bits.
    lStyle = GetWindowLong(mhWnd, GWL_STYLE)
    ' Set requested bit On or Off and Redraw.
 
    If Value Then
        lStyle = lStyle Or Bit
    Else
        lStyle = lStyle And Not Bit
    End If
 
    Call SetWindowLong(mhWnd, GWL_STYLE, lStyle)
    Call pRedraw(mhWnd)
    ' Return success code.
    fFlipBit = (lStyle = GetWindowLong(mhWnd, GWL_STYLE))
 
End Function

Edit: Someone posted this cool tip on VBF a few days ago. I couldn't find the thread.

VB Code:

Me.BorderStyle = vbBSNone
[b]Me.Caption = Me.Caption[/b]

The trick is the second statement.
From User's point of view it doesn't change anything, but it actually forces the TitleBar to be redrawn.

ok, i've merged the two and attached it. It works ok at this end

OK. I tried your code. But it still animates when goes to fullscreen mode from maximized mode. Also, I need to go to fullscreenmode directly from normal mode too.

I tried your original idea (LockWindowUpdate). It works perfectly in normal-to-fullscreen mode, but doesn't work in maximized-to-fullscreen mode. :(

VB Code:

Option Explicit
 
Private Declare Function LockWindowUpdate Lib "user32" _
        (ByVal hwndLock As Long) As Long
 
Private Type MyRECT
  Left As Long
  Top As Long
  Width As Long
  Height As Long
End Type
 
Private bFullScreen As Boolean
Private m_NormalState As MyRECT
Private LastState As VBRUN.FormWindowStateConstants
 
Private Sub Command1_Click()
 
    If Not bFullScreen Then
        bFullScreen = True
        LastState = Me.WindowState
        LockWindowUpdate Me.hwnd
        ShowTitlebar False, Me.hwnd
        Me.WindowState = vbNormal
        Me.Move 0, 0, Screen.Width, Screen.Height
        LockWindowUpdate 0
     Else
        LockWindowUpdate Me.hwnd
        
        If LastState = vbMaximized Then
            Me.WindowState = vbMaximized
        Else
             Me.Move m_NormalState.Left, _
               m_NormalState.Top, _
               m_NormalState.Width, _
               m_NormalState.Height
        End If
        
        ShowTitlebar True, Me.hwnd
        LockWindowUpdate 0
        bFullScreen = False
    End If
 
End Sub
 
Private Sub Form_Load()
 
    LastState = vbNormal
 
End Sub
 
Private Sub Form_Resize()
 
    If Me.WindowState = vbNormal And Not bFullScreen Then
        'Save normal state
        m_NormalState.Top = Me.Top
        m_NormalState.Height = Me.Height
        m_NormalState.Left = Me.Left
        m_NormalState.Width = Me.Width
    End If
 
End Sub

I've fiddled around with the order things, and i've got rid of the sliding that the titlebar was doing, there's still a bit of flickering though.

For some reason there is a little delay covering up the taskbar sometimes a bit longer, perhaps waiting for some paint event.

It's not as good as the IE fullscreen animation (or lack of it), but it's a hell of a lot better than FF :)

Great ! :thumb: Yes. Though it is not as perfect as IE/Opera, it is much better than Fx.

(RobDog, here is another reason to use IE :D )

I found that there is a SHFullscreen API for PocketPC, but nothing for Win32. :(

bushmobile, I'm using your code in my project. But I'm not making this thread resolved right now. Just in case we find a better solution. :)

I guess an alternative would be to create a copy your form but keep it hidden until it's in the correct position (topmost / no title / over taskbar), then just show it, and hide your original form.

That won't be possible. This application is a Text-to-Speech app (and uses a RTB).

If the control starts reading and user presses Fullscreen button, unloading the original form will stop the TTS too. Also, the new fullscreen form will take long time to initilize the (new) audio data and RTB.

you wouldn't need to unload the original form, just hide it, but yeah, the initialization of the new form could take a while.

Perhaps you could run the two versions of the form side-by-side, and then when you switch, the speech just picks off from where the other form left off.

Here is my complete project. I'll upload it in utility bank after adding some more features.

your zip is missing the xvoice.dll

i downloaded it but am getting 'ActiveX can't create object' on this line:

Engine = DirectSS1.Find("Mfg=Microsoft;Gender=1")

Quote:

---

Originally Posted by bushmobile

you wouldn't need to unload the original form, just hide it, but yeah, the initialization of the new form could take a while.

Perhaps you could run the two versions of the form side-by-side, and then when you switch, the speech just picks off from where the other form left off.

---

Sounds like a good idea. :thumb: That way the TTS engine will not need to me initialized again.
The only problems that may occur is, the new RTB will take long time to initialize.

Re: XVoice.dll:

This program uses Microsoft Speech API 4. You'll need to download SAPI4 engine.
http://www.microsoft.com/speech/download/old/sdk40a.asp
I guess it comes with WinXP or later. I think only installing the engine will work.(spchapi.EXE - 848 KB)

Many free SAPI voices: http://www.bytecool.com/voices.htm
(I like 'Mary' best)

Note: SAPI4 voices will not work with SAPI5

I downloaded the engine & voices and it's now working perfectly. It's a nice program :thumb: :cool:

I was a bit shocked when I saw the fullscreen animation, but then I realised you hadn't put the new stuff in :)

One thing I've noticed is that is doesn't pause when it reaches a vbCrLf, e.g.:

Quote:

---

Visual Basic
Visual C++
Visual FoxPro
Visual InterDev
Visual J++

---

is read as if it's all one sentence.

Quote:

---

Originally Posted by iPrank

The only problems that may occur is, the new RTB will take long time to initialize.

---

What would take a long time to initialize?

As the main form is reading, move the cursor on the fullscreen form. When fullscreen mode is pressed, show fullscreen, press stop on the main form, & press read from cursor on the fullscreen form. And then visa versa.

p.s. Female Whisper sounds like it comes straight out of a horror film :eek:

You should add some checking when you change the pitch and the speed. There is a max for both. The slider passed both max values with the voice of sam (didn't try any other ones).

Quote:

---

Originally Posted by bushmobile

I was a bit shocked when I saw the fullscreen animation, but then I realised you hadn't put the new stuff in :)

---

Sorry. My latest code is a mess after testing all those animation codes. :D

Quote:

---

One thing I've noticed is that is doesn't pause when it reaches a vbCrLf.

---

TTS engine doesn't pause in CrLf. It pauses on punctuation marks. I'll add this feature if you like. :)

Quote:

---

What would take a long time to initialize?

---

If the text in RTB is long, it will take very long time to update. As my app can save last reading paused position and can resume from that position when you restart the app. I expect my users will paste long texts.

I'm planning to add HTML support. Then it may take even longer if the pageis image intensive.

Quote:

---

As the main form is reading, move the cursor on the fullscreen form. When fullscreen mode is pressed, show fullscreen, press stop on the main form, & press read from cursor on the fullscreen form. And then visa versa.

---

That will cause the TTS engine in fullscreen form to initilize. Takes very long time on longet text.
I'm planning to add the TTS engine in only main form.
When user presses fullscreen, the TTS will be paused. (quick)
Then copy rtf from main form to the fullscreen form. (will take time)
Hide the main form, show the fullscreen form.
Resume TTS and highlight RTB in fullscreen form.

Quote:

---

p.s. Female Whisper sounds like it comes straight out of a horror film :eek:

---

I find it very $esy. ;)

Quote:

---

Originally Posted by manavo11

You should add some checking when you change the pitch and the speed. There is a max for both. The slider passed both max values with the voice of sam (didn't try any other ones).

---

Thanks. :thumb: I had tested it only with Mary. I'll try to kill the bug.

Quote:

---

That will cause the TTS engine in fullscreen form to initilize. Takes very long time on longet text.
I'm planning to add the TTS engine in only main form.
When user presses fullscreen, the TTS will be paused. (quick)
Then copy rtf from main form to the fullscreen form. (will take time)
Hide the main form, show the fullscreen form.
Resume TTS and highlight RTB in fullscreen form.

---

oh well, i didn't think it'd be a particularly practical idea when i came up with it anyway. :D

Actually it is your post that gave me the idea. :D

Thank you very much. :thumb: