Gathering Local PC information

Im trying to gather the following information using VB.NET and .NET 2

-IP Address - I havent seen any usefull resources about the .NET framework with IP Address collecting

-MAC Address

You can definitely use WMI to get the MAC addresses of any network adapters in your machine:

VB Code:

Dim networkAdapters As New Management.ManagementClass("Win32_NetworkAdapter")
 
        For Each networkAdapter As Management.ManagementObject In networkAdapters.GetInstances()
            MessageBox.Show(String.Format("Name: {1}{0}Type: {2}{0}MAC Address: {3}", _
                                          Environment.NewLine, _
                                          networkAdapter("Name"), _
                                          networkAdapter("AdapterType"), _
                                          networkAdapter("MACAddress")))
        Next networkAdapter

Note that this requires a reference to System.Management. The IP address I don't know as I've never had the pleasure, but the Win32_NetworkAdapterConfiguration class has a property named IPAddress that is a string array.

Edit:
Search for "Win32_NetworkAdapter" on MSDN for more information on that class.

VB Code:

' *****VB2005*****
Option Strict On
 
Public Class Form1
 
    ' add reference to system.management
    Private listview1 As New ListView
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Me.Controls.Add(listview1)
        GetNetworkInfo()
    End Sub
 
    Private Sub GetNetworkInfo()
 
        ' storing Network adapters in this:
        Dim adapters As New ArrayList
 
        Dim pDataCol As System.Management.PropertyDataCollection
        Dim pData As System.Management.PropertyData
        ' Get info from the WIN32_NetworkAdapterConfiguration Class
        Dim networkAdapterConfigurationClass As New System.Management.ManagementClass("Win32_NetworkAdapterConfiguration")
        Dim configurationInstances As Management.ManagementObjectCollection = networkAdapterConfigurationClass.GetInstances
        Dim configurationInstance As Management.ManagementObject
 
        ' Loop through each instance (in this case each adapter)
        For Each configurationInstance In configurationInstances
            pDataCol = configurationInstance.Properties
            pData = pDataCol.Item("IPAddress")
            ' skip anything without an IP:
            If pData.Value Is Nothing Then Continue For
 
            ' we are storing the information in a structure called NetworkAdapter defined later...
            Dim anotherAdapter As New NetworkAdapter
 
            ' There could be more than 1 IP, so the this is an array:
            anotherAdapter.IPAddresses = DirectCast(pData.Value, String())
 
            ' Get the remaining info for this adapter
            ' To get the name we need to use another management class, it also has
            ' the index property of the adapters, so we can find this adapter from its index
            pData = pDataCol.Item("Index")
            If pData.Value IsNot Nothing Then
                ' store the index:
                anotherAdapter.Index = pData.Value.ToString
                ' we have a function to get the name:
                anotherAdapter.Name = GetName(Convert.ToUInt32(pData.Value))
            End If
            ' finally MACAddress:
            pData = pDataCol.Item("MACAddress")
            If pData.Value IsNot Nothing Then
                anotherAdapter.MACAddress = pData.Value.ToString
            End If
            ' store the NetworkAdapter in the arraylist
            adapters.Add(anotherAdapter)
        Next
 
        If adapters.Count = 0 Then Exit Sub ' no network adapters!
 
        FillListView(adapters)
 
    End Sub
 
    Private Function GetName(ByVal index As UInteger) As String
        ' Friendly name is in a different management class
        ' We'll match adapters with the index
        Dim adaptername As String = ""
        Dim pDataCol As System.Management.PropertyDataCollection
        Dim pData As System.Management.PropertyData
        ' same as other class really...
        Dim networkAdapterClass As New System.Management.ManagementClass("Win32_NetworkAdapter")
        Dim networkAdapterInstances As Management.ManagementObjectCollection = networkAdapterClass.GetInstances
        Dim networkAdapterInstance As Management.ManagementObject
        For Each networkAdapterInstance In networkAdapterInstances
            pDataCol = networkAdapterInstance.Properties
            pData = pDataCol.Item("Index")
 
            If index = Convert.ToUInt32(pData.Value) Then
                ' indexes match so this is the same adapter, so get its name
                pData = pDataCol.Item("Name")
                If pData.Value IsNot Nothing Then
                    adaptername = pData.Value.ToString
                    Exit For
                End If
            End If
        Next
 
        Return adaptername
 
    End Function
 
    Private Structure NetworkAdapter
        ' store info for each adapter:
        Public Index As String
        Public MACAddress As String
        Public IPAddresses() As String
        Public Name As String
    End Structure
 
    Private Sub FillListView(ByVal adapters As ArrayList)
 
        ' display results:
        Me.listview1.Dock = DockStyle.Fill
        Me.listview1.View = View.Details
        Me.listview1.Columns.Add("Name", -1, HorizontalAlignment.Left)
        Me.listview1.Columns.Add("IPAddress", -1, HorizontalAlignment.Left)
        Me.listview1.Columns.Add("MACAddress", -1, HorizontalAlignment.Left)
 
        For i As Integer = 0 To adapters.Count - 1
            Dim adapter As NetworkAdapter = DirectCast(adapters(i), NetworkAdapter)
            Dim lvi As New ListViewItem(adapter.Name)
            Dim s As String = ""
            Dim count As Integer = 0
            Do
                s &= adapter.IPAddresses(count)
                count += 1
            Loop Until count = adapter.IPAddresses.Length
 
            lvi.SubItems.Add(s)
            lvi.SubItems.Add(adapter.MACAddress)
            Me.listview1.Items.Add(lvi)
        Next
 
        For i As Integer = 0 To 2
            Me.listview1.Columns(i).AutoResize(ColumnHeaderAutoResizeStyle.ColumnContent)
        Next
 
    End Sub
 
End Class

You said .net 2, so I've used vb05 stuff. It's easy enough to translate back to vb03 if thats what you have :p

Quote:

---

Originally Posted by jo0ls

[Highlight=VB]
' *****VB2005*****


You said .net 2, so I've used vb05 stuff. It's easy enough to translate back to vb03 if thats what you have :p

---

.NET 2 is part of VS2005

Yes, I was trying to be clear about what it would compile on, and failed miserably...
It works in vb express 2005, so it will work in any visual basic 2005. It will not work with older versions of the framework as I used IsNot, listview.column.autoresize and a UInteger. So to convert it to work on earlier versions is trivial.
.Net 2 isn't really part as VS2005, you can download just the framework sdk and write programs in notepad if you really want.

I wish MSFT would make it simple like: my.computer.network.localip and my.computer.network.mac

but MSFT would never do that :P

Here's another way to get just the IP address I used once before..

VB Code:

Dim PCName as String = Dns.GetHoseName.ToString
        Dim myIPHost As System.Net.IPHostEntry = Dns.Resolve(PCName)
        Dim myIP As System.Net.IPAddress = myIPHost.AddressList(0)
        MsgBox(myIP.ToString)

It'll also tell you the PC name.. His way is more thorough though.

Bill

Quote:

---

Originally Posted by tylerm

I wish MSFT would make it simple like: my.computer.network.localip and my.computer.network.mac

but MSFT would never do that :P

---

When I use the method I suggested I get about 6 or 7 network adapters with MAC addresses.

Code:

---

        Dim networkAdapters As New Management.ManagementClass("Win32_NetworkAdapter")
        For Each networkAdapter As Management.ManagementObject In networkAdapters.GetInstances()
            net_mac.Text = String.Format("Name: {1}{0}Type: {2}{0}MAC Address: {3}", _
                                          Environment.NewLine, _
                                          networkAdapter("Name"), _
                                          networkAdapter("AdapterType"), _
                                          networkAdapter("MACAddress"))
        Next networkAdapter

---

It displays the Name but the Type and Address do not appear.

That's why I coded it the way I did: to show that there are a number of network adapters of different types in most machines. You need to use the properties of each to determine which one(s) you are interested in. I changed my code to append each output to a TextBox and here's what I got:

Quote:

---

Name: 1394 Net Adapter
Type: Ethernet 802.3
MAC Address: 82:F3:C8:A6:41:BD

Name: RAS Async Adapter
Type:
MAC Address:

Name: WAN Miniport (L2TP)
Type:
MAC Address:

Name: WAN Miniport (PPTP)
Type: Wide Area Network (WAN)
MAC Address: 50:50:54:50:30:30

Name: WAN Miniport (PPPOE)
Type: Wide Area Network (WAN)
MAC Address: 33:50:6F:45:30:30

Name: Direct Parallel
Type:
MAC Address:

Name: WAN Miniport (IP)
Type:
MAC Address:

Name: Packet Scheduler Miniport
Type: Ethernet 802.3
MAC Address: EC:2D:20:52:41:53

Name: Microsoft Tun Miniport Adapter
Type: Ethernet 802.3
MAC Address: 02:00:54:55:4E:01

Name: NVIDIA nForce Networking Controller
Type: Ethernet 802.3
MAC Address: 00:50:8D:D7:89:6D

Name: Packet Scheduler Miniport
Type: Ethernet 802.3
MAC Address: 00:50:8D:D7:89:6D

---

It would only be those with a type of "Ethernet 802.3" that you would be interested in, and I'm guessing that all the "Miniport" ones are software devices rather than hardware. Obviously the 1394 adapter is a FireWire connection, which leaves the second last item as the primary network adapter. This logic is not definitive, so you may need to do some more research to make sure you are using the best criteria to identify the primary network adapter, but I wanted to point out that it is not just a straightforward "GET MAC ADDRESS" kind of thing. There may also be other properties of the Win32_NetworkAdapter class, or indeed other classes, like Win32_NetworkAdapterConfiguration, that will help you to identify just the one you're looking for. I don't know if all the 802.3 adapters would have an IP address assigned, but you could use jo0ls code to work that out, maybe with slight modification to exclude all items with a type other than "Ethernet 802.3".

I just excluded everything without an IP. Attached is a version that gets a few more fields, and which doesn't filter. Another thing to look for to find the primary adapter is the DefaultIPGateway value.

I didn't look too closely at your code jo0ls. Another thing to note is that you can actually generate .NET classes that correspond to WMI classes automatically using the mgmtclassgen.exe utility. That way you can use strongly-typed objects instead of indexing properties of ManagementObject instances.