[RESOLVED] Minimize button question.

Hello,

Is there any way to make the minimize button in the top right hand corner of the app's form to minimize it to the system tray?

Currently my program is in the system tray and can minimize it by clicking a cmd button which merely hides the form.

Is there anyway to do something similar with the real minimize button?

Thank you and have a great day!
Stilekid007

just place the system try code in this place:

VB Code:

Private Sub Form_Resize()
If Me.WindowState = 1 Then
            'code here
End If
End Sub

Sure....

VB Code:

Private Sub Form_Resize()
    If Me.WindowState = vbMinimized Then
        Me.Hide
        Me.WindowState = vbNormal
    End If
End Sub

here is how to move it to system tray when your app is mimimized:

also the right click menu in my code is "m" you need to change it to what ever:

VB Code:

'declaration for putting the application to system tray
Private Type NOTIFYICONDATA
    cbSize As Long
    hwnd As Long
    uId As Long
    uFlags As Long
    uCallBackMessage As Long
    hIcon As Long
    szTip As String * 64
End Type
 
    'declare constants
Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
 
'The following constant is the message sent when a mouse event occurs
'within the rectangular boundaries of the icon in the taskbar status area.
 
Private Const WM_MOUSEMOVE = &H200
 
'The following constants are the flags that indicate the valid
'members of the NOTIFYICONDATA data type.
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4
 
'The following constants are used to determine the mouse input on the
'the icon in the taskbar status area.
 
    'Left-click constants.
Private Const WM_LBUTTONDBLCLK = &H203   'Double-click
Private Const WM_LBUTTONDOWN = &H201     'Button down
Private Const WM_LBUTTONUP = &H202       'Button up
 
    'Right-click constants.
Private Const WM_RBUTTONDBLCLK = &H206   'Double-click
Private Const WM_RBUTTONDOWN = &H204     'Button down
Private Const WM_RBUTTONUP = &H205       'Button up
 
    'Declare the API function call.
Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
 
'Dimension a variable as the user-defined data type.
Dim nid As NOTIFYICONDATA
'write the following in the form load event
'if ur application as MDI write in MDI_Load else the first form_load event
 
Private Sub Form_Resize()
If Me.WindowState = 1 Then
Me.Hide
    nid.cbSize = Len(nid)
        nid.hwnd = Me.hwnd
        nid.uId = vbNull
        nid.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
        nid.uCallBackMessage = WM_MOUSEMOVE
        nid.hIcon = Me.Icon
   'u can give a tool tip text here
        nid.szTip = "My System Tray Message" & vbNullChar
       'Call the Shell_NotifyIcon function to add the icon to the System Tray
 
        Shell_NotifyIcon NIM_ADD, nid
        MsgBox "In system tray"
 
End If
End Sub
'create a menu by using menu editor
'   one main menu by Caption"Menu" name "M"
'   one sub menu by name caption "Exit" name "Ex"
'make the Menu invisible by changing the "visibility" option in properties window
 
'write the following in MouseMove event
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim msg As Long
Dim sFilter As String
msg = X / Screen.TwipsPerPixelX
    Select Case msg
        Case WM_LBUTTONDOWN
        '      Me.PopupMenu M   'if u want u can call the popup menu
        Case WM_LBUTTONUP
        Case WM_LBUTTONDBLCLK
        Case WM_RBUTTONDOWN
        Case WM_RBUTTONUP
            Me.PopupMenu m  'call the popup menu
        Case WM_RBUTTONDBLCLK
    End Select
End Sub

@Wiz: I think he already had the icon in the systray and just wanted his app to disappear from the taskbar when it was minimized.

Hey guys!

Ok, thit is exactly what I needed,

VB Code:

Private Sub Form_Resize()
    If Me.WindowState = vbMinimized Then
        Me.Hide
        Me.WindowState = vbNormal
    End If
End Sub

Yes I already have the icon in the system tray. I was working with the form resize option but I was missing a line of code.

Thanks guys!

Stilekid007