[RESOLVED] Finding the relative path of file

I am starting a new thread on this because the last one I posted turned into a debate between randem and I.

I was wondering if anyone knew of a class module/DLL out there that finds the relative path of a file in a reliable manner. For example, I would pass these strings to a method:

"C:\Projects\My Project 1\Forms\MyForm.frm" <--- Path to make relative
"C:\Projects\My Project 1\" <--- Path to use as absolute
... should return ...
"\Forms\MyForm.frm"

Here is another example:
"C:\Common\By wossy\sandpaper.dll" <--- Path to make relative
"C:\Projects\My Project 1\" <--- Path to use as absolute
... should return ...
"..\..\Common\By wossy\sandpaper.dll"

There should also be another sub to unfold the relative paths. For example:
"D:\Another Guy\Coding Stuff\Project 132\" <--- Path to use as absolute
"\Forms\MyForm.frm"<--- Relative Path
... should return ...
"D:\Another Guy\Coding Stuff\Project 132\Forms\MyFrom.frm"

Does anyone know of a way to do this reliably? I have a feeling that if I wrote my own code to do it I would miss a few big things. This has to have been done before.

You might use the Right() and Len() function to kind of subtract the Absolute path from the path in question...

probably u can use Split() by "\" and then append or delete the required part of the path!!!!

I guess I will just write it then. I think I will split() it on "\" (after replacing any "/" with "\") and then loop through and compare and take action when necessary.

Instr() will let you know if you have a folder or not. Don't use anything else first.

What do you mean don't use anything else first?

Okay here is what I came up with. Could you guys help me work out the bugs? I don't see any problems with it, but there must be some:

VB Code:

'---------------------------------------------------------------------------------------
' Module    : modRelativePaths
' DateTime  : 10/16/2005 02:19
' Author    : Jeremy Blanchard
' Purpose   :
'---------------------------------------------------------------------------------------
 
Option Explicit
 
'---------------------------------------------------------------------------------------
' Procedure : MakePathRelative
' DateTime  : 10/16/2005 02:19
' Author    : Jeremy Blanchard
' Purpose   : Make sure to include either a \ at the end or a \filename.txt at the end
'    of the paths
'---------------------------------------------------------------------------------------
'
Public Function MakePathRelative( _
        ByVal sToMakeRelative As String, _
        ByVal sAbsolutePath As String) As String
    Dim i       As Long
    Dim j       As Long
    Dim sRel()  As String
    Dim sAbs()  As String
    Dim sReturn As String
    
    sToMakeRelative = Replace$(sToMakeRelative, "/", "\", , , vbTextCompare)
    sAbsolutePath = Replace$(sAbsolutePath, "/", "\", , , vbTextCompare)
    
    sRel = Split(sToMakeRelative, "\", , vbTextCompare)
    sAbs = Split(sAbsolutePath, "\", , vbTextCompare)
    
    For i = 0 To UBound(sAbs) - 1
        If sRel(i) = sAbs(i) Then
            ' Do nothing but increment i
        Else
            For j = i To UBound(sAbs) - 1
                sReturn = sReturn & "..\"
            Next j
            Exit For
        End If
    Next i
    
    For i = i To UBound(sRel)
        sReturn = sReturn & sRel(i)
        If i <> UBound(sRel) Then _
            sReturn = sReturn & "\"
    Next i
    
    MakePathRelative = sReturn
    
End Function
 
 
'---------------------------------------------------------------------------------------
' Procedure : MakePathAbsolute
' DateTime  : 10/16/2005 02:19
' Author    : Jeremy Blanchard
' Purpose   : Make sure to include either a \ at the end or a \filename.txt at the end
'    of the paths
'---------------------------------------------------------------------------------------
'
Public Function MakePathAbsolute( _
        ByVal sRelativePath As String, _
        ByVal sAbsolutePath As String) As String
    Dim i           As Long
    Dim j           As Long
    Dim sRel()      As String
    Dim sAbs()      As String
    Dim sReturn     As String
    Dim sPartial    As String
    
    sRelativePath = Replace$(sRelativePath, "/", "\", , , vbTextCompare)
    sAbsolutePath = Replace$(sAbsolutePath, "/", "\", , , vbTextCompare)
    
    sRel = Split(sRelativePath, "\", , vbTextCompare)
    sAbs = Split(sAbsolutePath, "\", , vbTextCompare)
    
    For i = 0 To UBound(sRel) - 1
        If sRel(i) = ".." Then
            ' Do nothing but increment i
        Else
            For j = i To UBound(sRel)
                sReturn = sReturn & sRel(j)
                If j <> UBound(sRel) Then _
                    sReturn = sReturn & "\"
            Next j
            Exit For
        End If
    Next i
    
    For i = 0 To UBound(sAbs) - 1 - i
        sPartial = sPartial & sAbs(i)
        If i <> UBound(sAbs) - i Then _
            sPartial = sPartial & "\"
    Next i
    sReturn = sPartial & sReturn
    
    MakePathAbsolute = sReturn
End Function

Attached is the sample project.

I haven't tested your code, but don't you think it would be safer to use the correct API functions instead?

VB Code:

Private Declare Function PathRelativePathTo _
 Lib "shlwapi.dll" Alias "PathRelativePathToA" ( _
 ByVal pszPath As String, _
 ByVal pszFrom As String, _
 ByVal dwAttrFrom As Long, _
 ByVal pszTo As String, _
 ByVal dwAttrTo As Long) As Long
 
Private Declare Function PathCombine _
 Lib "shlwapi.dll" Alias "PathCombineA" ( _
 ByVal szDest As String, _
 ByVal lpszDir As String, _
 ByVal lpszFile As String) As Long
 
Public Function MakePathRelative( _
 ByVal sFrom As String, _
 ByVal sTo As String) As String
    Const FILE_ATTRIBUTE_DIRECTORY As Long = &H10
    Const MAX_PATH As Long = 260
    Dim sRet As String
    Dim nFlagFrom As Long, nFlagTo As Long
    
    If Right$(sFrom, 1) = "\" Then
        nFlagFrom = FILE_ATTRIBUTE_DIRECTORY
        sFrom = Left$(sFrom, Len(sFrom) - 1)
    End If
    If Right$(sTo, 1) = "\" Then
        nFlagTo = FILE_ATTRIBUTE_DIRECTORY
        sTo = Left$(sTo, Len(sTo) - 1)
    End If
    sRet = Space$(MAX_PATH)
    If PathRelativePathTo(sRet, sFrom, nFlagFrom, sTo, nFlagTo) Then
        MakePathRelative = Left$(sRet, InStr(sRet, vbNullChar) - 1)
    End If
End Function
 
Public Function MakePathAbs(ByVal sRel As String, ByVal sAbs As String)
    'sAbs must be the path of a directory and NOT a file
    'The relative path can be a relative path to a file
    Const MAX_PATH As Long = 260
    Dim sRet As String
    sRet = Space$(MAX_PATH)
    If PathCombine(sRet, sAbs, sRel) Then
        MakePathAbs = Left$(sRet, InStr(sRet, vbNullChar) - 1)
    End If
End Function

In this case I did as you and in MakePathRelative you must end the path strings with a backslash to indicate a directory, if not it assumes it is the path to a file. In MakePathAbs the absolute path must be to a directory, but it doesn't matter if it has a trailing backslash or not since a directory is assumed. The relative path could be either to a file or a directory.

Well now you tell me! :)

That is what I had been looking for for the last few days when I started 2 threads on this subject. After I finally get my act together and write some code, you show me what I wanted the whole time.

Thanks though! I'll take a look at it later today.

Well, I beg your pardon for not monitoring all the threads you start and immediatly reply to them :). But the fact is that I didn't see this thread before you sent an e-mail to me about it :)

:lol:

I was just giving you a bad time. :)

Thanks a ton for the code though. :)