disable system menu

Hi Someone Can Help Me ???


I want disable system menu in windows upper left corner without disable 3 controls in upper right corner

I want click system menu and i want nothing append.
I want continue to use close minimize and maximize control in upper right corner....

Thanks in advance....

What do you mean by "system menu in windows upper left corner "?

Hi

Windows Menu System

with this option :

Restore
Move
Size
Minimize
Maximize
Close

Thanks

well i am not sure if you can disable the menu form every app, or why do you wana to do this but you can remove it form your app by clicking:

Form Properties --> BoarderStyle --> 0 - None
4 - Fixed Toolwindow

If you want YOUR app to have that menu disabled then set the "ControlBox" property of your form to false.

Quote:

---

Originally Posted by Sir Loin

If you want YOUR app to have that menu disabled then set the "ControlBox" property of your form to false.

---

But he wants to do it "without disable 3 controls in upper right corner".

yep he wants to keep the 3 controls

here is how to make your own item into the menu



PUT THIS IN YOU APP:

VB Code:

Private Sub Command1_Click()
AddToSystemMenu Me.hWnd
End Sub

PUT THIS CODE IN A MODULE:

VB Code:

Private OriginalWindowProc As Long
Public Const MF_STRING = &H0&
Public Const MF_ENABLED = &H0&
Public Const IDM_MYMENUITEM = 2003
Public Const WM_SYSCOMMAND = &H112
Public Const GWL_WNDPROC = (-4)
 
Public Declare Function GetSystemMenu Lib "user32" (ByVal hWnd As Long, ByVal bRevert As Long) As Long
 
Public Declare Function AppendMenu Lib "user32" _
   Alias "AppendMenuA" (ByVal hMenu As Long, _
   ByVal wflags As Long, ByVal wIDNewItem As Long, _
   ByVal lpNewItem As String) As Long
 
Public Declare Function SetWindowLong Lib "user32" _
   Alias "SetWindowLongA" (ByVal hWnd As Long, _
   ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
 
Public Declare Function CallWindowProc Lib "user32" _
   Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
   ByVal hWnd As Long, ByVal msg As Long, ByVal wParam As Long, _
   ByVal lParam As Long) As Long
 
 
Public Sub AddToSystemMenu(ByVal hWnd As Long)
 
Dim hSystemMenu As Long
 
' Get the system menu's handle.
hSystemMenu = GetSystemMenu(hWnd, False)
 
' Append a custom command to the menu.
AppendMenu hSystemMenu, MF_STRING + MF_ENABLED, _
   IDM_MYMENUITEM, "My Menu Item"
 
' Tell Windows to call MyMenuProc when a system
' menu command is selected.
OriginalWindowProc = SetWindowLong(hWnd, GWL_WNDPROC, _
   AddressOf MyMenuProc)
 
End Sub
 
 
Public Function MyMenuProc(ByVal hWnd As Long, ByVal msg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long
 
' If the custom menu item was selected display a message.
If msg = WM_SYSCOMMAND And wParam = IDM_MYMENUITEM Then
   MsgBox "New menu item clicked!"
   Exit Function
End If
 
' Otherwise pass the command on for normal processing.
MyMenuProc = CallWindowProc(OriginalWindowProc, hWnd, msg, _
   wParam, lParam)
 
End Function

is it possible to intercept mouse clic and shortcut for this menu ?????


Thanks

Quote:

---

Originally Posted by JP Labre

is it possible to intercept mouse clic and shortcut for this menu ?????

---

i showed you how to add another item into the menu.
i don't understand what do you mean by "intercept mouse clic "?

Download FormBdr from Karl E. Peterson's SAMPLES SITE .

This will remove everything but Close from the system menu. If you uncomment the line for menu 6 it also disables the X. You could put an exit button on the form and exit that way.

VB Code:

Private Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Private Const MF_BYPOSITION = &H400&
Private Const MF_REMOVE = &H1000&
 
Private Sub Form_Load()
    Dim hSysMenu As Long, nCnt As Long
    ' Get handle to our form's system menu
    ' (Restore, Maximize, Move, close etc.)
    hSysMenu = GetSystemMenu(Me.hwnd, False)
 
    If hSysMenu Then
        ' Get System menu's menu count
        nCnt = GetMenuItemCount(hSysMenu)
        If nCnt Then
            RemoveMenu hSysMenu, 7, MF_BYPOSITION Or MF_REMOVE
            'RemoveMenu hSysMenu, 6, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 5, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 4, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 3, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 2, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 1, MF_BYPOSITION Or MF_REMOVE
            RemoveMenu hSysMenu, 0, MF_BYPOSITION Or MF_REMOVE
 
            DrawMenuBar Me.hwnd
        End If
    End If
End Sub

I want if user click system menu, nothing append....

Quote:

---

Originally Posted by JP Labre

I want if user click system menu, nothing append....

---

you wana to complitly remove the system defult mune for the app without removing the 3 command buttons? is it even posible?

Quote:

---

Originally Posted by wiz126

is it even posible?

---

Kind of :)

If you subclass you can catch these messages like this :

VB Code:

Case WM_CONTEXTMENU
            Exit Function
        Case WM_SYSCOMMAND
            If (wParam) = 61587 Then
                Exit Function
            End If

and the menu won't appear if you left or right click on the image in the top left. However, if you click on the taskbar on the app, you will get the system menu...

Full code :

VB Code:

'form code
 
Option Explicit
 
Private Sub Form_Load()
    Hook Me.hWnd
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    UnHook
End Sub

VB Code:

'Module code
 
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" _
                                       (ByVal lpPrevWndFunc As Long, _
                                                 ByVal hWnd As Long, _
                                                  ByVal Msg As Long, _
                                               ByVal wParam As Long, _
                                         ByVal lParam As Long) As Long
 
Declare Function SetWindowLong Lib "user32" _
                     Alias "SetWindowLongA" _
                       (ByVal hWnd As Long, _
                      ByVal nIndex As Long, _
             ByVal dwNewLong As Long) As Long
 
Public Const GWL_WNDPROC = -4
Public Const WM_CONTEXTMENU As Long = &H7B
Const WM_SYSCOMMAND As Long = &H112
 
Public lpPrevWndProc As Long
Private lnghWnd As Long
 
Public Sub Hook(hWnd As Long)
    lnghWnd = hWnd
    lpPrevWndProc = SetWindowLong(lnghWnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub
 
Public Sub UnHook()
    Dim lngReturnValue As Long
    lngReturnValue = SetWindowLong(lnghWnd, GWL_WNDPROC, lpPrevWndProc)
End Sub
 
Function WindowProc(ByVal hw As Long, _
                    ByVal uMsg As Long, _
                    ByVal wParam As Long, _
                    ByVal lParam As Long) As Long
 
    Select Case uMsg
        Case WM_CONTEXTMENU
            Exit Function
        Case WM_SYSCOMMAND
            If (wParam) = 61587 Then
                Exit Function
            End If
        Case WM_DESTROY
            UnHook
    End Select
    
    WindowProc = CallWindowProc(lpPrevWndProc, lnghWnd, uMsg, wParam, lParam)
End Function

Thanks manavo11



Your response is 95% good the user can always double click system menu


Thanks!

What do you mean by :

Quote:

---

the user can always double click system menu

---

Double clicking the icon closes the window...

is it posible to complitly remove the menu?

And keep the control box? Probably not, at least not without more hooking so avoid the menu popping up with you right click in the taskbar area...

hi manavo11


if I double click the system menu the window close and i don't want that



Thanks

Add this in the declarations :

VB Code:

Const WM_NCLBUTTONDBLCLK As Long = &HA3

and change the select case statement to this :

VB Code:

Select Case uMsg
        Case WM_CONTEXTMENU
            Exit Function
        Case WM_NCLBUTTONDBLCLK
            Exit Function
        Case WM_SYSCOMMAND
            If (wParam) = 61587 Then
                Exit Function
            End If
        Case WM_DESTROY
            UnHook
    End Select

It's works great


Thanks


JP

You're welcome :)

Nice sample manavo! :thumb:

Not sure if anyboody mentioned yet so here we go: it's simple enough to create your own titlebar so if you're interested I have some sample code I can share.

Thanks RhinoBull :)

I would like to see that, see if it's less trouble then the subclassing... Does it look the same (exactly? kind of?)

OK, as promissed here is a sample project. You can customize as you wish but KIM that it's only a sample. Enjoy it.

NOTE: couldn't find my original so this si a very "freshly made" copy (did it in the past hour).

That's pretty nice RB :thumb: There are a few issues (maximizing/covering taskbar, double clicking titlebar) but it's still pretty cool :) Even got the gradient!

Thanks. As I said I couldn't find my original project which took care of all that stuff so the one I uploaded was "1 hour quicky sample" but general idea is there.

For 1 hour that's pretty impressive :thumb: 1 "problem" is that you lose the XP style visual style, not that it's that important :)

Personally I don't care much for XP styles as I use Windows Classic schema. But for those that do it could be replicated with a little extra work.