[RESOLVED] Left$ Not Working?

I found this code on these boards, and am at a loss here because for some strange reason I cannot compile this code. I can however run it normally error free. This is in a module by itself btw. The exact error given is.. Type-Declaration character does not match declared data type. What the heck? I've tried different variation, including the sister function Right$. But still no luck. The part that is highlighted is shown in bold in the code below. Any Ideas would be helpful. Sorry for the long code :( Registry w/ the API isn't real fun is it! Oh and BTW I searched through the first few pages of relevent information. Did multiple searches too.

VB Code:

' Possible registry data types
Public Enum InTypes
   ValNull = 0
   ValString = 1
   ValXString = 2
   ValBinary = 3
   ValDWord = 4
   ValLink = 6
   ValMultiString = 7
   ValResList = 8
End Enum
' Registry value type definitions
Public Const REG_NONE As Long = 0
Public Const REG_SZ As Long = 1
Public Const REG_EXPAND_SZ As Long = 2
Public Const REG_BINARY As Long = 3
Public Const REG_DWORD As Long = 4
Public Const REG_LINK As Long = 6
Public Const REG_MULTI_SZ As Long = 7
Public Const REG_RESOURCE_LIST As Long = 8
' Registry section definitions
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Public Const HKEY_PERFORMANCE_DATA = &H80000004
Public Const HKEY_CURRENT_CONFIG = &H80000005
Public Const HKEY_DYN_DATA = &H80000006
' Codes returned by Reg API calls
Private Const ERROR_NONE = 0
Private Const ERROR_BADDB = 1
Private Const ERROR_BADKEY = 2
Private Const ERROR_CANTOPEN = 3
Private Const ERROR_CANTREAD = 4
Private Const ERROR_CANTWRITE = 5
Private Const ERROR_OUTOFMEMORY = 6
Private Const ERROR_INVALID_PARAMETER = 7
Private Const ERROR_ACCESS_DENIED = 8
Private Const ERROR_INVALID_PARAMETERS = 87
Private Const ERROR_NO_MORE_ITEMS = 259
 
Private Declare Function RegQueryValueExString Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long
Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long
Declare Function RegEnumValue Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long
Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, lpSecurityAttributes As Any, phkResult As Long, lpdwDisposition As Long) As Long
Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpValue As String, ByVal cbData As Long) As Long
Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpValue As Long, ByVal cbData As Long) As Long
Declare Function RegFlushKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Declare Function RegEnumKey Lib "advapi32.dll" Alias "RegEnumKeyA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, ByVal cbName As Long) As Long
Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String) As Long
Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long
Declare Function FormatMessage Lib "kernel32" Alias "FormatMessageA" (ByVal dwFlags As Long, lpSource As Any, ByVal dwMessageId As Long, ByVal dwLanguageId As Long, ByVal lpBuffer As String, ByVal nSize As Long, Arguments As Long) As Long
Declare Function GetLastError Lib "kernel32" () As Long
Declare Sub SetLastError Lib "kernel32" (ByVal dwErrCode As Long)
Const FORMAT_MESSAGE_ALLOCATE_BUFFER = &H100
Const FORMAT_MESSAGE_FROM_SYSTEM = &H1000
Const LANG_NEUTRAL = &H0
Const SUBLANG_DEFAULT = &H1
Const REG_OPTION_BACKUP_RESTORE = 4     ' open for backup or restore
Const REG_OPTION_VOLATILE = 1           ' Key is not preserved when system is rebooted
Const REG_OPTION_NON_VOLATILE = 0       ' Key is preserved when system is rebooted
Const STANDARD_RIGHTS_ALL = &H1F0000
Const SYNCHRONIZE = &H100000
Const READ_CONTROL = &H20000
Const STANDARD_RIGHTS_READ = (READ_CONTROL)
Const STANDARD_RIGHTS_WRITE = (READ_CONTROL)
Const KEY_CREATE_LINK = &H20
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_READ = ((STANDARD_RIGHTS_READ Or KEY_QUERY_VALUE Or KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY) And (Not SYNCHRONIZE))
Const KEY_WRITE = ((STANDARD_RIGHTS_WRITE Or KEY_SET_VALUE Or KEY_CREATE_SUB_KEY) And (Not SYNCHRONIZE))
Const KEY_EXECUTE = (KEY_READ)
Const KEY_ALL_ACCESS = ((STANDARD_RIGHTS_ALL Or KEY_QUERY_VALUE Or KEY_SET_VALUE Or KEY_CREATE_SUB_KEY Or KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY Or KEY_CREATE_LINK) And (Not SYNCHRONIZE))
 
 
' This routine allows you to get values from anywhere in the Registry, it currently
' only handles string and double word values.
 
Public Function ReadRegistry(ByVal Group As Long, ByVal Section As String, ByVal Key As String) As String
Dim lResult As Long, lKeyValue As Long, lDataTypeValue As Long, lValueLength As Long, sValue As String, td As Double
  On Error Resume Next
    lResult = RegOpenKeyEx(ByVal Group, ByVal Section, ByVal &O0, &H1, lKeyValue)
'    If lResult > 0 Then
'      Dim Buffer As String
'      'Create a string buffer
'      Buffer = Space(200)
'      'Set the error number
'      SetLastError lResult
'      'Format the message string
'      FormatMessage FORMAT_MESSAGE_FROM_SYSTEM, ByVal &O0, GetLastError, LANG_NEUTRAL, Buffer, 200, ByVal 0&
'      'Show the message
'      MsgBox Buffer
' End If
 sValue = Space$(2048)
 lValueLength = Len(sValue)
 lResult = RegQueryValueEx(ByVal lKeyValue, ByVal Key, ByVal 0&, ByVal lDataTypeValue, ByVal sValue, lValueLength)
 If (lResult = 0) And (Err.Number = 0) Then
   If lDataTypeValue = REG_DWORD Then
      td = Asc(Mid$(sValue, 1, 1)) + &H100& * Asc(Mid$(sValue, 2, 1)) + &H10000 * Asc(Mid$(sValue, 3, 1)) + &H1000000 * CDbl(Asc(Mid$(sValue, 4, 1)))
      sValue = Format$(td, "000")
   End If
   sValue = [b]Left$[/b](sValue, lValueLength - 1)
Else
  sValue = ""
End If
On Error GoTo 0
lResult = RegCloseKey(lKeyValue)
ReadRegistry = sValue
End Function
 
' This routine allows you to write values into the entire Registry, it currently
' only handles string and double word values.
Public Sub WriteRegistry(ByVal Group As Long, ByVal Section As String, ByVal Key As String, ByVal ValType As InTypes, ByVal Value As Variant)
Dim lResult As Long
Dim lKeyValue As Long
Dim InLen As Long
Dim lNewVal As Long
Dim sNewVal As String
On Error Resume Next
 RegCreateKeyEx Group, Section, 0, "REG_SZ", REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, ByVal 0&, lKeyValue, lResult
 If ValType = ValDWord Then
   lNewVal = CLng(Value)
   InLen = 4
   lResult = RegSetValueExLong(lKeyValue, Key, 0&, ValType, lNewVal, InLen)
 Else
   sNewVal = Value
   InLen = Len(sNewVal)
   lResult = RegSetValueExString(lKeyValue, Key, 0&, 1&, sNewVal, InLen)
 End If
 lResult = RegFlushKey(lKeyValue)
 lResult = RegCloseKey(lKeyValue)
End Sub

Place that code in a Module, and then call it from your code.

Sorry for sounding like a noobie, but how would I do that. I'm already calling the code like this from another form. It is in its own module.

VB Code:

WinKey = Replace(StrReverse(ReadRegistry(HKEY_LOCAL_MACHINE, "SOFTWARE\Microsoft\Windows\CurrentVersion", "ProductID")), "-MEO", "")

While it looks like the line is OK, try using just Left and not Left$.

Just outa curiosity, is this to run in VBA?

Bruce... I got the code from dee-u. Not exactly which forum. That could pose an issue.
Marty... Just using Left will throw "Expected array"

Here is a module that I posted the other night.

http://www.vbforums.com/attachment.p...chmentid=38389

Just place it in your app folder, and then add a module, and point to this one. It contains pretty much the same thing, if it's not identical :wave:

What Bruce is asking is are you using VB6? At this point I'd guess not and that's the problem.

I am using VB6

Quote:

---

Originally Posted by DJHotIce

Bruce... I got the code from dee-u. Not exactly which forum. That could pose an issue.

---

Sorry, I was asking if that code was part of VBA (ie Access or Excel) app as I have
recently lost the use of the Left$ function on a colegues computer that had the OS replaced recently - seems library dependant; hence my question.
Also, you stated that you have had it running sucessfuly too.




Bruce.

OK then the only other thing I can think of (other than a corrupted VB) is that you have a variable somewhere in your program with the name Left.

Quote:

---

Originally Posted by DJHotIce

I am using VB6

---

Ignore my last :)

is there any way to do that via the Debug. Sorry marty. I'm still learning VB. I wasn't real sure what VBA was. I thought that was a reference to the VB Suite.

Do what via debug?

In any case if you want to find out if you have a Left variable just do Ctrl-f and look for Left.

BTW I just did this and got the same error you did.

VB Code:

Dim Left As Integer
 
 Left$ = "xxx"

Quote:

---

Originally Posted by MartinLiss

Do what via debug?

---

Find out all the variables within my project. Add a watch or something right? I'm trying to learn. Please bear with me if that was completly WRONG! Ah.

[edit]Nevermind, I see what your saying[/edit]

No. Without special 3rd-party software there's no way to locate all the variables in your program. Did you look for "Left" (without the quotes)?

Try using Mid instead:

VB Code:

sValue = Mid$(sValue, lValueLength - 1)

If you do have a variable named Left and possibly right as MartinLiss said, it's doubtful you would have a mid variable :p

chem

Oh Also. I mentioned I also tried using the Right$ function as well. chemicalNova. Haven't used Mid Yet. Doubt I would use it as a var.

[edit]Mid. Just spat out Errors on just a simple run through. Not a compile.
Run Through = What's the Correct Name?[/edit]

Please zip up and attach your code.

For what its worth the code (adapted) works for me...

Well. I'd Prefer Not too. Here is the reason. I've already included the activation part. I could privatly mail it if Desired.

I believe a problem could also be this... I have a Drive Serial Function (from the boards) and I haven't fully understood modules yet. So I kinda duplicated function inside of the form. I have removed those as of this writing (now) and still getting errors on that one Left function.

[edit]I seriously hate having other people do the code for me. You know what I mean. I rather learn it and not seem like a stupid noobie moocher! But if you insist :). Just want to get that point across.[/edit]

I sent you a PM.

Recieved.

I found the source of your problem. VB is being confused by the many components you have selected. For example MSAdodcLib (among others) has a Left member and VB is making the wrong assumption about which one you are trying to use when you use Left$. You can correct that problem by doing sValue = VBA.Left$(sValue, lValueLength - 1) for example. A better way however would be to just remove the components that you have selected but that are not actually being used. To do that go to the Project|Components menu and check the Selected Items Only checkbox. Then go through the list of selected components and attempt to uncheck them. If you can uncheck a component that means that you are not actually using it. In your case you'll find that you can uncheck the 1st 7 and last 2 in the list. In the remaining 8 controls I see that you are using both Microsoft Windows Common Controls 5.0 and 6.0 and I don't think you should do that and I suggest you figure out where you are using the 5.0 control and replace it with the equivalent 6.0 control.

Once you've done all that try and compile again. You'll get more errors but if you can't fix them then send me another zip file and we'll work on them together.

Your a genius! Thanks a lot Marty. Props (+ Reputations) to everyone who posted as ya'll all contributed to fixing this problem.

That's a lot of code to read and write to the registry. Why don't you try the VBScript method? It's a hell of a lot less code and very easy to work with:

VB Code:

Private Function Registry_Read(Key_Path, Key_Name) As Variant
    
    On Error Resume Next
    
    Dim Registry As Object
    
    Set Registry = CreateObject("WScript.Shell")
    
    Registry_Read = Registry.RegRead(Key_Path & Key_Name)
    
End Function
 
 
Private Sub Registry_Write(Key_Path As String, Key_Name As String, Key_Value As Variant, Optional Key_Type As String)
    
    On Error Resume Next
 
    '/////////////////////////////////////////////////////////////////////    
    'Key Type list (Use within string, ex. "
    '     REG_DWORD")
    '----------------
    
    'REG_BINARY - This type stores the value as raw binary data. Most hardware component information is stored as binary data, and can be displayed in an editor in hexadecimal format.
    'REG_DWORD - This type represents the data by a four byte number and is commonly used for boolean values, such as "0" is disabled and "1" is enabled. Additionally many parameters for device driver and services are this type, and can be displayed in REGEDT32 in binary, hexadecimal and decimal format, or in REGEDIT in hexadecimal and decimal format.
    'REG_EXPAND_SZ - This type is an expandable data string that is string containing a variable to be replaced when called by an application. For example, for the following value, the string "%SystemRoot%" will replaced by the actual location of the directory containing the Windows NT system files. (This type is only available using an advanced registry editor such as REGEDT32)
    'REG_MULTI_SZ - This type is a multiple string used to represent values that contain lists or multiple values, each entry is separated by a NULL character. (This type is only available using an advanced registry editor such as REGEDT32)
    'REG_SZ - This type is a standard string, used to represent human readable text values.
    
    'Other data types not available through the standard registry editors include:
    
    'REG_DWORD_LITTLE_ENDIAN - A 32-bit number in little-endian format.
    'REG_DWORD_BIG_ENDIAN - A 32-bit number in big-endian format.
    'REG_LINK - A Unicode symbolic link. Used internally; applications should not use this type.
    'REG_NONE - No defined value type.
    'REG_QWORD - A 64-bit number.
    'REG_QWORD_LITTLE_ENDIAN - A 64-bit number in little-endian format.
    'REG_RESOURCE_LIST - A device-driver resource list.
    '///////////////////////////////////////////////////////////////////// 
    Dim Registry As Object
    
    Dim Registry_Value As Variant
    
    Set Registry = CreateObject("WScript.Shell")
    
    Registry_Value = Registry_Read(Key_Path, Key_Name)
    
    If Key_Type = "" Then
        
        'REG_SZ is the default.
        
        Registry.RegWrite Key_Path & Key_Name, Key_Value
        
    Else
        
        Registry.RegWrite Key_Path & Key_Name, Key_Value, Key_Type
        
    End If
    
End Sub
 
 
Private Sub Form_Activate()
    'This is only an example of a registry entry.
    Registry_Write "HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\WINDOWS\CURRENTVERSION\RUN\", "Test", 1, "REG_DWORD"
 
End Sub