What apps am I running???

Hello everybody,

Does anybody know how to get a list of the current applications that are running on a workstation. i.e. the applications that have been started in the current windows session. Once I have this list I need to change the apps Zorder and setfocus where appropriate.

Thanks in advance.
Gibbo

Try this:

Code:

---

Private Declare Function GetWindow Lib "user32" _
(ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function GetParent Lib "user32" _
(ByVal hwnd As Long) As Long
'
Private Declare Function GetWindowTextLength Lib _
"user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long

Private Declare Function GetWindowText Lib "user32" _
Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal _
lpString As String, ByVal cch As Long) As Long

Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

Public Sub LoadTaskList()
Dim CurrWnd As Long
Dim Length As Long
Dim TaskName As String
Dim Parent As Long

Form1.List1.Clear
CurrWnd = GetWindow(Form1.hwnd, GW_HWNDFIRST)

While CurrWnd <> 0
Parent = GetParent(CurrWnd)
Length = GetWindowTextLength(CurrWnd)
TaskName = Space$(Length + 1)
Length = GetWindowText(CurrWnd, TaskName, Length + 1)
TaskName = Left$(TaskName, Len(TaskName) - 1)

If Length > 0 Then
If TaskName <> Form1.Caption Then
Form1.List1.AddItem TaskName
End If
End If
CurrWnd = GetWindow(CurrWnd, GW_HWNDNEXT)
DoEvents

    Wend
   
End Sub

Usage

LoadTaskList

---

And you can use the FindWindow and ShowWindow api functions.

Code:

---

Private Declare Function FindWindow Lib "user32" _
Alias "FindWindowA" (ByVal lpClassName As String, ByVal _
lpWindowName As String) As Long

Declare Function ShowWindow Lib "user32.dll" (ByVal hwnd As _
Long, ByVal nCmdShow As Long) As Long

SW_HIDE = 0
SW_MAXIMIZE = 3
SW_MINIMIZE = 6
SW_RESTORE = 9
SW_SHOW = 5
SW_SHOWMAXIMIZED = 3
SW_SHOWMINIMIZED = 2
SW_SHOWMINNOACTIVE = 7
SW_SHOWNA = 8
SW_SHOWNOACTIVATE = 4
SW_SHOWNORMAL = 1



Private Sub List1_Click()
    handl = FindWindow(vbNullString, List1.text)
    ShowWindow handl, SW_Show
    ShowWindow handl, SW_RESTORE
    ShowWindow handl, SW_SHOWNORMAL
End Sub

---

I believe that will work :rolleyes:.

Use EnumWindowsProc

Code:

---

Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Declare Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long
Declare Function EnumWindows Lib "user32.dll" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long

Public Function EnumWindowsProc(ByVal hwnd As Long, ByVal lParam As Long) As Long
    Dim Length As Long
    Dim sName As String
    Dim Temp As String
    Static iCount As Integer
   
    iCount = iCount + 1
    Length = GetWindowTextLength(hwnd) + 1
   
    If Length > 1 Then
      sName = Space(Length)
      GetWindowText hwnd, sName, Length
      Debug.Print Left(sName, Length - 1)
    End If
   
    EnumWindowsProc = 1
End Function

---

Usage:

Code:

---

EnumWindows AddressOf EnumWindowsProc, 0

---