help on browse dialog

hi, i've a browse dialog with the following constants....however i want to get the filename so does anyone know how i can get that.

VB Code:

Public Const BIF_RETURNONLYFSDIRS = &H1         'Only returns file system directories
Public Const BIF_DONTGOBELOWDOMAIN = &H2        'Does not include network folders below the domain level
Public Const BIF_STATUSTEXT = &H4               'Includes a status area in the dialog box. The callback function can set the status text by sending messages to the dialog box.
Public Const BIF_RETURNFSANCESTORS = &H8        'Only returns file system ancestors
Public Const BIF_BROWSEFORCOMPUTER = &H1000     'Only returns computers
Public Const BIF_BROWSEFORPRINTER = &H2000      'Only returns (network) printers
Public Const BIF_BROWSEINCLUDEFILES As Long = &H4000
 
Public Const MAX_PATH = 255

I am not sure exactly what you are doing. Do you mean the Browse for File dialog? Why not use the Common Dialog control to do that?

i'm trying to get the effect of "open file" of microsoft word. I already have the code and everything is functional & i can retrieve the filepath but, I just need to get the fileName. Here's the code I'm using:

VB Code:

Public Function SelectFolder(frm As Form, _Optional sDialTitle As String = "Select a folder") As String
 
    On Error Resume Next
    Dim bi As BROWSEINFO
    Dim pidl As Long
    Dim Path As String
    Dim Pos As Integer
 
        'Fill the BROWSEINFO structure with the needed data.
        With bi
 
            .hOwner = frm.hwnd
            .pidlRoot = 0&                      'Root folder to browse from, or desktop if Null
            .lpszTitle = sDialTitle$             'Message to display in dialog
            .ulFlags = BIF_RETURNONLYFSDIRS     'the type of folder to return
 
        End With
 
        'show the browse for folders dialog
        pidl = SHBrowseForFolder(bi)
 
        'the dialog has closed, so parse & display the user's
        'returned folder selection contained in pidl
        Path = Space$(MAX_PATH)
 
        If SHGetPathFromIDList(ByVal pidl, ByVal Path) Then
            Pos = InStr(Path, Chr$(0))
            SelectFolder = Left$(Path, Pos - 1)
            If StrComp(Mid$(SelectFolder$, Len(SelectFolder$)), "\", vbTextCompare) <> 0 Then SelectFolder$ = SelectFolder$ & "\"
        Else
            SelectFolder$ = ""
        End If
 
        Call CoTaskMemFree(pidl)
 
End Function

and here are the structs used in it

VB Code:

'***************************************************************
'   Opens a common dialog window to browse for a folder
'   Returns the path to the folder selected as a string
'***************************************************************
 
'***************************************************************
'   Browse Dialog Constants
'***************************************************************
Public Type BROWSEINFO
    hOwner           As Long         'Handle to window's owner
    pidlRoot         As Long         'Pointer to an item identifier list
    pszDisplayName   As String       'Pointer to a buffer that receives the display name of the folder selected
    lpszTitle        As String       'Pointer to a null-terminated string that is displayed above the tree view control in the dialog box
    ulFlags          As Long         'Value specifying the types of folders to be listed in the dialog box as well as other options
    lpfn             As Long         'Address an application-defined function that the dialog box calls when events occur
    lParam           As Long         'Application-defined value that the dialog box passes to the callback function (if one is specified).
    iImage           As Long         'Variable that receives the image associated with the selected folder. The image is specified as an index to the system image list.
End Type
 
'***************************************************************
'   Browse Dialog Flags & Constants
'***************************************************************
Public Const BIF_RETURNONLYFSDIRS = &H1         'Only returns file system directories
Public Const BIF_DONTGOBELOWDOMAIN = &H2        'Does not include network folders below the domain level
Public Const BIF_STATUSTEXT = &H4               'Includes a status area in the dialog box. The callback function can set the status text by sending messages to the dialog box.
Public Const BIF_RETURNFSANCESTORS = &H8        'Only returns file system ancestors
Public Const BIF_BROWSEFORCOMPUTER = &H1000     'Only returns computers
Public Const BIF_BROWSEFORPRINTER = &H2000      'Only returns (network) printers
 
Public Const MAX_PATH = 255

this is how you can extract the filename out of the full path:

strFileName = Right$(strPath, Len(strPath) - InStrRev(strPath, "\"))

no that didnt' work, it didnt' give me the fileName still :(

Can you get the path? I mean path including the filename.

Which API are you using? You are only checking for system folders, not file names.

Also, have a look at this control from the CCRP project: http://ccrp.mvps.org/download/controls/ccrpbd10.zip

Sorry about that, wrong control. This is the correct link: http://ccrp.mvps.org/download/controls/ccrpfd6.zip

no i can get the whole path like "C:\Documents and Settings\Owner\My Documents\ShareWorks\Filespree\Current Beta Client\client.txt" but i just want "client.txt" in the variable sPath that i get from this line:

sPath$ = SelectFile(Me, "Select file")

i'm sorry i copied the wrong code, here's the one for selectFile function (there's a difference of one flag only)

VB Code:

Public Function SelectFile(frm As Form, _
                             Optional sDialTitle As String = "Select a file") As String
 
    On Error Resume Next
    Dim bi As BROWSEINFO
    Dim pidl As Long
    Dim Path As String
    Dim Pos As Integer
 
        'Fill the BROWSEINFO structure with the needed data.
        With bi
 
            .hOwner = frm.hwnd
            .pidlRoot = 0&                      'Root folder to browse from, or desktop if Null
            .lpszTitle = sDialTitle$             'Message to display in dialog
            .ulFlags = BIF_BROWSEINCLUDEFILES    'the type of folder to return
 
        End With
 
        'show the browse for folders dialog
        pidl = SHBrowseForFolder(bi)
 
        'the dialog has closed, so parse & display the user's
        'returned folder selection contained in pidl
        Path = Space$(MAX_PATH)
 
        If SHGetPathFromIDList(ByVal pidl, ByVal Path) Then
            Pos = InStr(Path, Chr$(0))
            SelectFile = Left$(Path, Pos - 1)
            If StrComp(Mid$(SelectFile$, Len(SelectFile$)), "\", vbTextCompare) <> 0 Then SelectFile$ = SelectFile$ & "\"
        Else
            SelectFile$ = ""
        End If
 
        Call CoTaskMemFree(pidl)
 
End Function

I fixed it up and its working now.

VB Code:

'In Module1.bas
Option Explicit
 
'***************************************************************
'   Opens a common dialog window to browse for a folder
'   Returns the path to the folder selected as a string
'***************************************************************
 
'***************************************************************
'   Browse Dialog Constants
'***************************************************************
Public Type BROWSEINFO
    hOwner           As Long         'Handle to window's owner
    pidlRoot         As Long         'Pointer to an item identifier list
    pszDisplayName   As Long       'Pointer to a buffer that receives the display name of the folder selected
    lpszTitle        As Long       'Pointer to a null-terminated string that is displayed above the tree view control in the dialog box
    ulFlags          As Long         'Value specifying the types of folders to be listed in the dialog box as well as other options
    lpfn             As Long         'Address an application-defined function that the dialog box calls when events occur
    lParam           As Long         'Application-defined value that the dialog box passes to the callback function (if one is specified).
    iImage           As Long         'Variable that receives the image associated with the selected folder. The image is specified as an index to the system image list.
End Type
 
'***************************************************************
'   Browse Dialog Flags & Constants
'***************************************************************
Public Const BIF_RETURNONLYFSDIRS = &H1         'Only returns file system directories
Public Const BIF_DONTGOBELOWDOMAIN = &H2        'Does not include network folders below the domain level
Public Const BIF_STATUSTEXT = &H4               'Includes a status area in the dialog box. The callback function can set the status text by sending messages to the dialog box.
Public Const BIF_RETURNFSANCESTORS = &H8        'Only returns file system ancestors
Public Const BIF_BROWSEFORCOMPUTER = &H1000     'Only returns computers
Public Const BIF_BROWSEFORPRINTER = &H2000      'Only returns (network) printers
Public Const BIF_BROWSEINCLUDEFILES As Long = &H4000
 
Public Const MAX_PATH = 255
 
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32.dll" (ByRef lpbi As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" (ByRef pidl As Long, ByVal pszPath As String) As Long
 
Public Function SelectFolder(ByRef frm As Form, Optional sDialTitle As String = "Select a folder") As String
 
    On Error Resume Next
    Dim bi As BROWSEINFO
    Dim sPath As String
    Dim lPos As Long
 
        'Fill the BROWSEINFO structure with the needed data.
        With bi
            .hOwner = frm.hWnd
            .pidlRoot = 0&                      'Root folder to browse from, or desktop if Null
            .lpszTitle = lstrcat(sDialTitle, "") 'Message to display in dialog
            .ulFlags = BIF_BROWSEINCLUDEFILES     'the type of folder to return
        End With
        'show the browse for folders dialog
        lPos = SHBrowseForFolder(bi)
        'the dialog has closed, so parse & display the user's
        'returned folder selection contained in pidl
        sPath = Space$(MAX_PATH)
        If lPos Then
            SHGetPathFromIDList ByVal lPos, ByVal sPath
            CoTaskMemFree lPos
            lPos = InStr(sPath, vbNullChar)
            sPath = Left$(sPath, lPos - 1)
            SelectFolder = Right$(sPath, Len(sPath) - InStrRev(sPath, "\"))
        Else
            SelectFolder = ""
        End If
 
End Function
 
 
'Behind Form1.frm
Option Explicit
 
Private Sub Command1_Click()
    Dim sFile As String
    sFile = SelectFolder(Me, "Select File")
    MsgBox sFile
End Sub

After you get the full path, just use this code to extract the file from it:

strFileName = Right$(strPath, Len(strPath) - InStrRev(strPath, "\"))

I borrowed your file parsing code and alread have it in there. ;)

Oh, I didn't see that post. I didnt refresh before replying.

I was debating on if I should just parse on the return of the filepath or parse in the function. It would be best to parse on the
return so you have the option of which one you need at any particular time.

:)

thnxs for ur input but, that's wht i'm trying to figure out too..cuz i want to parse outside cuz i need both the path and file...but i can't call this line:
CoTaskMemFree lPos
outside the module cuz i'm calling selectFile function elsewhere in a different form, or maybe i can :S...actually its not my code so i'm not quite sure what these getPath and browseforFolder functions are doing and how it works (i'm new to VB too :(

Then why not just return the complete file path because its easy to parse outsire the function.

VB Code:

'Change this line from:
SelectFolder = Right$(sPath, Len(sPath) - InStrRev(sPath, "\"))
 
'To
SelectFolder = Left$(sPath, lPos - 1)
 
 
'Then parse in your call in your form if you need just the filename:
SelectFolder = Right$(sPath, Len(sPath) - InStrRev(sPath, "\"))

yep that's how i did it i have this code to get the filename

VB Code:

Pos = InStrRev(Filename, "\") 
    If Pos > 0 Then
        RemovePath = Right$(Filename, Len(Filename) - Pos)
    End If

thanks a lot for your time and help :)