[resolved] Problem with FTP Rename

Printable View

May 13th, 2005, 04:06 AM
Ecniv

[resolved] Problem with FTP Rename

My Declarations

Code:

Public Declare Function apiFtpRenameFile Lib "wininet.dll" Alias "FtpRenameFileA" (ByVal hConnect As Long, ByVal lpszExisting As String, ByVal lpszNew As String) As Boolean Public Declare Function apiFtpDeleteFile Lib "wininet.dll" Alias "FtpDeleteFileA" (ByVal hConnect As Long, ByVal lpszFileName As String) As Boolean Public Declare Function apiFtpCreateDirectory Lib "wininet.dll" Alias "FtpCreateDirectoryA" (ByVal hConnect As Long, ByVal lpszDirectory As String) As Boolean Public Declare Function apiFtpRemoveDirectory Lib "wininet.dll" Alias "FtpRemoveDirectoryA" (ByVal hConnect As Long, ByVal lpszDirectory As String) As Boolean

and my rename code

Code:

Public Function RenameFile(ByVal strOldName As String, ByVal strNewName As String, ByVal blnFtpFile As Boolean) As Boolean '---- FTP - '---- will work on the current directory (make sure you are there before calling) '---- Local - '---- Use fill file path names '---- Note: To rename a directory, use this function Dim lngRes As Long On Error Resume Next RenameFile = True If blnFtpFile Then If IntCon.zIntConHandle <> 0 Then lngRes = apiFtpRenameFile(IntCon.zIntConHandle, ByVal strOldName, ByVal strNewName) End If Else '---- local drive rename ' lngRes = apiMoveFile(strOldName, strNewName) 'only api to rename a local file End If '---- repeated error msg/clean up If Err.Number <> 0 Then RenameFile = False MsgBox "Error : " & Err.Number & vbCrLf & Err.Description, vbOKOnly + vbExclamation, "Error" Err.Clear End If If Err.LastDllError <> 0 Then RenameFile = False MsgBox "Last DLL Error : " & Err.LastDllError, vbOKOnly + vbExclamation, "Error Last Error" Err.Clear End If End Function

Now it works fine but still raises an error (lastdll) of 2 - which I think is that it cannot find the file.

I am tempted to ignore that error as it is working, but I wanted to make sure.
I looked on google, but MSDN says it`s a function, and ActiveVB says its a sub. Confused? I am!

The function sounds better (at least you'd know if it worked of not).
Comments?

Re: Problem with FTP Rename

Well, if MSDN says it is a function then is should be a function.

Here is a working example from ALLAPI.net, see is that can help you :)

VB Code:

Const FTP_TRANSFER_TYPE_UNKNOWN = &H0
Const FTP_TRANSFER_TYPE_ASCII = &H1
Const FTP_TRANSFER_TYPE_BINARY = &H2
Const INTERNET_DEFAULT_FTP_PORT = 21               ' default for FTP servers
Const INTERNET_SERVICE_FTP = 1
Const INTERNET_FLAG_PASSIVE = &H8000000            ' used for FTP connections
Const INTERNET_OPEN_TYPE_PRECONFIG = 0                    ' use registry configuration
Const INTERNET_OPEN_TYPE_DIRECT = 1                        ' direct to net
Const INTERNET_OPEN_TYPE_PROXY = 3                         ' via named proxy
Const INTERNET_OPEN_TYPE_PRECONFIG_WITH_NO_AUTOPROXY = 4   ' prevent using java/script/INS
Const MAX_PATH = 260
Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type
Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
Private Declare Function InternetCloseHandle Lib "wininet" (ByRef hInet As Long) As Long
Private Declare Function InternetConnect Lib "wininet.dll" Alias "InternetConnectA" (ByVal hInternetSession As Long, ByVal sServerName As String, ByVal nServerPort As Integer, ByVal sUserName As String, ByVal sPassword As String, ByVal lService As Long, ByVal lFlags As Long, ByVal lContext As Long) As Long
Private Declare Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" (ByVal sAgent As String, ByVal lAccessType As Long, ByVal sProxyName As String, ByVal sProxyBypass As String, ByVal lFlags As Long) As Long
Private Declare Function FtpSetCurrentDirectory Lib "wininet.dll" Alias "FtpSetCurrentDirectoryA" (ByVal hFtpSession As Long, ByVal lpszDirectory As String) As Boolean
Private Declare Function FtpGetCurrentDirectory Lib "wininet.dll" Alias "FtpGetCurrentDirectoryA" (ByVal hFtpSession As Long, ByVal lpszCurrentDirectory As String, lpdwCurrentDirectory As Long) As Long
Private Declare Function FtpCreateDirectory Lib "wininet.dll" Alias "FtpCreateDirectoryA" (ByVal hFtpSession As Long, ByVal lpszDirectory As String) As Boolean
Private Declare Function FtpRemoveDirectory Lib "wininet.dll" Alias "FtpRemoveDirectoryA" (ByVal hFtpSession As Long, ByVal lpszDirectory As String) As Boolean
Private Declare Function FtpDeleteFile Lib "wininet.dll" Alias "FtpDeleteFileA" (ByVal hFtpSession As Long, ByVal lpszFileName As String) As Boolean
Private Declare Function FtpRenameFile Lib "wininet.dll" Alias "FtpRenameFileA" (ByVal hFtpSession As Long, ByVal lpszExisting As String, ByVal lpszNew As String) As Boolean
Private Declare Function FtpGetFile Lib "wininet.dll" Alias "FtpGetFileA" (ByVal hConnect As Long, ByVal lpszRemoteFile As String, ByVal lpszNewFile As String, ByVal fFailIfExists As Long, ByVal dwFlagsAndAttributes As Long, ByVal dwFlags As Long, ByRef dwContext As Long) As Boolean
Private Declare Function FtpPutFile Lib "wininet.dll" Alias "FtpPutFileA" (ByVal hConnect As Long, ByVal lpszLocalFile As String, ByVal lpszNewRemoteFile As String, ByVal dwFlags As Long, ByVal dwContext As Long) As Boolean
Private Declare Function InternetGetLastResponseInfo Lib "wininet.dll" Alias "InternetGetLastResponseInfoA" (lpdwError As Long, ByVal lpszBuffer As String, lpdwBufferLength As Long) As Boolean
Private Declare Function FtpFindFirstFile Lib "wininet.dll" Alias "FtpFindFirstFileA" (ByVal hFtpSession As Long, ByVal lpszSearchFile As String, lpFindFileData As WIN32_FIND_DATA, ByVal dwFlags As Long, ByVal dwContent As Long) As Long
Private Declare Function InternetFindNextFile Lib "wininet.dll" Alias "InternetFindNextFileA" (ByVal hFind As Long, lpvFindData As WIN32_FIND_DATA) As Long
Const PassiveConnection As Boolean = True
Private Sub Form_Load()
    'KPD-Team 2000
    'URL: [url]http://www.allapi.net[/url]
    'E-Mail: [email][email protected][/email]
    Dim hConnection As Long, hOpen As Long, sOrgPath  As String
    'open an internet connection
    hOpen = InternetOpen("API-Guide sample program", INTERNET_OPEN_TYPE_PRECONFIG, vbNullString, vbNullString, 0)
    'connect to the FTP server
    hConnection = InternetConnect(hOpen, "your ftp server", INTERNET_DEFAULT_FTP_PORT, "your login", "your password", INTERNET_SERVICE_FTP, IIf(PassiveConnection, INTERNET_FLAG_PASSIVE, 0), 0)
    'create a buffer to store the original directory
    sOrgPath = String(MAX_PATH, 0)
    'get the directory
    FtpGetCurrentDirectory hConnection, sOrgPath, Len(sOrgPath)
    'create a new directory 'testing'
    FtpCreateDirectory hConnection, "testing"
    'set the current directory to 'root/testing'
    FtpSetCurrentDirectory hConnection, "testing"
    'upload the file 'test.htm'
    FtpPutFile hConnection, "C:\test.htm", "test.htm", FTP_TRANSFER_TYPE_UNKNOWN, 0
    'rename 'test.htm' to 'apiguide.htm'
    FtpRenameFile hConnection, "test.htm", "apiguide.htm"
    'enumerate the file list from the current directory ('root/testing')
    EnumFiles hConnection
    'retrieve the file from the FTP server
    FtpGetFile hConnection, "apiguide.htm", "c:\apiguide.htm", False, 0, FTP_TRANSFER_TYPE_UNKNOWN, 0
    'delete the file from the FTP server
    FtpDeleteFile hConnection, "apiguide.htm"
    'set the current directory back to the root
    FtpSetCurrentDirectory hConnection, sOrgPath
    'remove the direcrtory 'testing'
    FtpRemoveDirectory hConnection, "testing"
    'close the FTP connection
    InternetCloseHandle hConnection
    'close the internet connection
    InternetCloseHandle hOpen
End Sub
Public Sub EnumFiles(hConnection As Long)
    Dim pData As WIN32_FIND_DATA, hFind As Long, lRet As Long
    'set the graphics mode to persistent
    Me.AutoRedraw = True
    'create a buffer
    pData.cFileName = String(MAX_PATH, 0)
    'find the first file
    hFind = FtpFindFirstFile(hConnection, "*.*", pData, 0, 0)
    'if there's no file, then exit sub
    If hFind = 0 Then Exit Sub
    'show the filename
    Me.Print Left(pData.cFileName, InStr(1, pData.cFileName, String(1, 0), vbBinaryCompare) - 1)
    Do
        'create a buffer
        pData.cFileName = String(MAX_PATH, 0)
        'find the next file
        lRet = InternetFindNextFile(hFind, pData)
        'if there's no next file, exit do
        If lRet = 0 Then Exit Do
        'show the filename
        Me.Print Left(pData.cFileName, InStr(1, pData.cFileName, String(1, 0), vbBinaryCompare) - 1)
    Loop
    'close the search handle
    InternetCloseHandle hFind
End Sub
Sub ShowError()
    Dim lErr As Long, sErr As String, lenBuf As Long
    'get the required buffer size
    InternetGetLastResponseInfo lErr, sErr, lenBuf
    'create a buffer
    sErr = String(lenBuf, 0)
    'retrieve the last respons info
    InternetGetLastResponseInfo lErr, sErr, lenBuf
    'show the last response info
    MsgBox "Error " + CStr(lErr) + ": " + sErr, vbOKOnly + vbCritical
End Sub

Cheers,

RyanJ

May 14th, 2005, 05:48 AM
Joacim Andersson

Re: Problem with FTP Rename

No, do not change the ByVal call to ByRef (EDIT: Oh, I see that Ryan has changed his post). A VB string is passed as a pointer to a pointer so passing it ByVal means you're passing a pointer to the string and is the correct way of passing a string to an API function. Furthermore you don't have to check the LastDLLError unless the FtpRenameFile (or apiFtpRenameFile as you have renamed it) function returns 0 (or False) since it's only then an error can have occured. The function returns a BOOL which is not exactly the same as a VB Boolean but in your declaration you have specified that the function will return a Boolean. It will still work since VB will simply cast it as a boolean, however in the code you let a Long variable take care of the return value. You should use either a boolean or a long but you should make up your mind about it :).
May 14th, 2005, 05:58 AM
sciguyryan

Re: Problem with FTP Rename

Quote:

Originally Posted by Joacim Andersson

No, do not change the ByVal call to ByRef (EDIT: Oh, I see that Ryan has changed his post).

Yes, I noticed that - and as you said I changed it :)

Thanks for pointing that out, I realized just before you posted :)

Cheers,

RyanJ
May 17th, 2005, 02:51 AM
Ecniv

Re: Problem with FTP Rename

Thanks for the replies.

Its making the error 2 (file not found I think in dll errors) for Renaming a file and for deleting a file. This, to me, suggests that windoze is (for some reason) looking for the file which has just gone although there is no handles for opening it held.

As to the ByVal, byref bit I know what they mean, however it is unclear in MSDN as all their examples and descriptions are for C++ ... :ehh: and not for vb/vba. Its just that if you put a byref and it should be byval it kills Access. An I was searching for info for vb stuff, which came across a site with declarations etc in vb code, but contradicted MSDN with the sub function and some of the references.

Anyway, as it is actually deleting/renaming but erroring as a missing file, I've ignored the error. My main concern was that this does not impact further on in the program, but the Access as FTP is working fine now.

At least as a single connection download. Not sure I should venture into the multiple connection downloads... :bigyello:

Thanks for the AllApiNet example... Its one I used the first time around when the ftp openinternetfile for downloading etc didn't work, probably due to using the wrong flags. :)

BTW - long or bolean won't matter. if it fails it will be 0 in either case. It only matters with the handle being returned ;)
May 17th, 2005, 08:16 AM
Joacim Andersson

Re: Problem with FTP Rename

Quote:

Originally Posted by Ecniv

BTW - long or bolean won't matter. if it fails it will be 0 in either case. It only matters with the handle being returned ;)

It won't return a handle it only returns TRUE or FALSE. However TRUE is cast as 1 in the APIs not -1 as in VB. However VB will convert that for you. There is another difference and that is that the BOOL datatype is a 32bit integer (a VB long) while a VB boolean is a 16-bit integer.

However don't check the last error unless the function returns false.