How to ping a machine in VB .net

I have a module that will ping a machine given a hostname or an ip address. Is there an eaiser way to ping a machine using vb .net? I know you can use wsh to open a shell and execute the ping command from a command prompt window then use the ReadAll to get the information ping sends back and from there you can determine if the ping was sucessful or not.

How would I do this in VB .Net or is there a better way to ping machines in .net?

This might be a good starting point... (from MSDN)

VB Code:

Try
    Dim siteUri As New System.Uri("http://www.google.com")
    Dim webRequest As System.Net.WebRequest = System.Net.WebRequest.Create(siteUri)
    webRequest.Proxy = New System.Net.WebProxy("YourProxySetting")
    Dim webResponse As System.Net.WebResponse = webRequest.GetResponse()
Catch ex As Exception
    ' The Web request failed.
End Try

that code would probably not work on pining a local machine on our lan here using a host name however.


Correct?

Found some semiFunctional Code @ http://www.developerfusion.com/show/2857/


The Gent failed to include a structure.
So I tweaked it.

Make a new class, and insert this code:
{edited to remove some comments. TOO BIG!}

VB Code:

Option Explicit On 
 
Imports System
Imports System.Net
Imports System.Net.Sockets
 
 
Public Class clsPing
 
    Public Structure stcError
        Dim Number As Integer
        Dim Description As String
    End Structure
    'suggested by sholliday, here: [url]http://www.developerfusion.com/forums/topic.aspx?id=21482[/url]
    'Although, This WAS hidden in the code:
    '* 
    '* --- ICMP Echo Header Format --- 
    '* (first 8 bytes of the data buffer) 
    '* 
    '* Buffer (0) ICMP Type Field 
    '* Buffer (1) ICMP Code Field 
    '*     (must be 0 for Echo and Echo Reply) 
    '* Buffer (2) checksum hi 
    '*     (must be 0 before checksum calc) 
    '* Buffer (3) checksum lo 
    '*     (must be 0 before checksum calc) 
    '* Buffer (4) ID hi 
    '* Buffer (5) ID lo 
    '* Buffer (6) sequence hi 
    '* Buffer (7) sequence lo 
    '* Buffer (8)..(n)  Ping Data 
    '* 
    Public Enum ICMPType
        ICMP_ECHO_REPLY = 0
        ICMP_DESTINATION_UNREACHABLE = 3
        ICMP_REDIRECT = 5
        'ICMP_ECHO_REQUEST = 8 
        ICMP_TIME_EXCEEDED = 11
        ICMP_PARAMETER_PROBLEM = 12
        ICMP_TIMESTAMP_REQUEST = 13
        ICMP_TIMESTAMP_REPLY = 14
        'EchoReply = 0 
        'Unreachable = 3 
        Echo = 8
    End Enum
    Public Const PING_SUCCESS As Long = 0
    Public Const PING_ERROR As Long = (-1)
    Public Const PING_ERROR_BASE As Long = &H8000
    Public Const PING_ERROR_HOST_NOT_FOUND As Long = PING_ERROR_BASE + 1
    Public Const PING_ERROR_SOCKET_DIDNT_SEND As Long = PING_ERROR_BASE + 2
    Public Const PING_ERROR_HOST_NOT_RESPONDING As Long = PING_ERROR_BASE + 3
    Public Const PING_ERROR_TIME_OUT As Long = PING_ERROR_BASE + 4
 
    Private Const ICMP_ECHO As Integer = 8
    Private Const SOCKET_ERROR As Integer = -1
 
    Private udtError As stcError
 
    Private Const intPortICMP As Integer = 7
    Private Const intBufferHeaderSize As Integer = 8
    Private Const intPackageHeaderSize As Integer = 28
 
    Private intDataSize As Byte
    Private ipheLocalHost As System.Net.IPHostEntry
    Private ipheHost As System.Net.IPHostEntry
 
    Public Property DataSize() As Byte
        Get
            Return intDataSize
        End Get
        Set(ByVal Value As Byte)
            intDataSize = Value
        End Set
    End Property
 
    Public ReadOnly Property Identifier() As Byte
        Get
            Return 0
        End Get
    End Property
 
    Public ReadOnly Property Sequence() As Byte
        Get
            Return 0
        End Get
    End Property
 
    Public ReadOnly Property LocalHost() As System.Net.IPHostEntry
        Get
            Return ipheLocalHost
        End Get
    End Property
 
    Public Property Host() As Object
        Get
            Return ipheHost
        End Get
        Set(ByVal Value As Object)
            If (Value.GetType.ToString.ToLower = "system.string") Then
                Try
                    ipheHost = System.Net.Dns.GetHostByName(Value)
                Catch
                    udtError.Number = PING_ERROR_HOST_NOT_FOUND
                    udtError.Description = "Host " & ipheHost.HostName & " not found."
                    ipheHost = Nothing
                End Try
            ElseIf (Value.GetType.ToString.ToLower = "system.net.iphostentry") Then
                ipheHost = (Value)
            Else
                ipheHost = Nothing
            End If
        End Set
    End Property
 
    Public Sub New()
        intDataSize = 32
        udtError = New stcError()
        ipheLocalHost = System.Net.Dns.GetHostByName(System.Net.Dns.GetHostName())
        ipheHost = Nothing
    End Sub
 
    Public Function Ping() As Long
 
        Dim intCount As Integer
        Dim aReplyBuffer(255) As Byte
 
        Dim intNBytes As Integer = 0
 
        Dim intEnd As Integer
        Dim intStart As Integer
 
        Dim epFrom As System.Net.EndPoint
        Dim epServer As System.Net.EndPoint
        Dim ipepServer As System.Net.IPEndPoint
 
        ipepServer = New System.Net.IPEndPoint(ipheHost.AddressList(0), 0)
        epServer = CType(ipepServer, System.Net.EndPoint)
 
        epFrom = New System.Net.IPEndPoint(ipheLocalHost.AddressList(0), 0)
 
 
        DataSize = Convert.ToByte(DataSize + intBufferHeaderSize)
 
        If (DataSize Mod 2 = 1) Then
            DataSize += Convert.ToByte(1)
        End If
        Dim aRequestBuffer(DataSize - 1) As Byte
 
        aRequestBuffer(0) = Convert.ToByte(ICMPType.Echo)
 
 
        BitConverter.GetBytes(Identifier).CopyTo(aRequestBuffer, 4)
 
        BitConverter.GetBytes(Sequence).CopyTo(aRequestBuffer, 6)
 
        Dim i As Integer
        For i = 8 To DataSize - 1
            aRequestBuffer(i) = Convert.ToByte(i Mod 8)
        Next i
 
        Call CreateChecksum(aRequestBuffer, DataSize, aRequestBuffer(2), aRequestBuffer(3))
 
        Try
 
            Dim sckSocket As New System.Net.Sockets.Socket( _
                                            Net.Sockets.AddressFamily.InterNetwork, _
                                            Net.Sockets.SocketType.Raw, _
                                            Net.Sockets.ProtocolType.Icmp)
            sckSocket.Blocking = False
 
 
            intStart = System.Environment.TickCount
            sckSocket.SendTo(aRequestBuffer, 0, DataSize, SocketFlags.None, ipepServer)
            intNBytes = sckSocket.ReceiveFrom(aReplyBuffer, SocketFlags.None, epServer)
            intEnd = System.Environment.TickCount
 
            If (intNBytes > 0) Then
                udtError.Number = (aReplyBuffer(19) * &H100) + aReplyBuffer(20)
                Select Case aReplyBuffer(20)
                    Case 0 : udtError.Description = "Success"
                    Case 1 : udtError.Description = "Buffer too Small"
                    Case 2 : udtError.Description = "Destination Unreahable"
                    Case 3 : udtError.Description = "Dest Host Not Reachable"
                    Case 4 : udtError.Description = "Dest Protocol Not Reachable"
                    Case 5 : udtError.Description = "Dest Port Not Reachable"
                    Case 6 : udtError.Description = "No Resources Available"
                    Case 7 : udtError.Description = "Bad Option"
                    Case 8 : udtError.Description = "Hardware Error"
                    Case 9 : udtError.Description = "Packet too Big"
                    Case 10 : udtError.Description = "Reqested Timed Out"
                    Case 11 : udtError.Description = "Bad Request"
                    Case 12 : udtError.Description = "Bad Route"
                    Case 13 : udtError.Description = "TTL Exprd In Transit"
                    Case 14 : udtError.Description = "TTL Exprd Reassemb"
                    Case 15 : udtError.Description = "Parameter Problem"
                    Case 16 : udtError.Description = "Source Quench"
                    Case 17 : udtError.Description = "Option too Big"
                    Case 18 : udtError.Description = "Bad Destination"
                    Case 19 : udtError.Description = "Address Deleted"
                    Case 20 : udtError.Description = "Spec MTU Change"
                    Case 21 : udtError.Description = "MTU Change"
                    Case 22 : udtError.Description = "Unload"
                    Case Else : udtError.Description = "General Failure"
 
                End Select
            Else
                'NotLKH added this:
                udtError.Number = -2
                udtError.Description = "NoReturnedData"
            End If
            sckSocket.Close()
            sckSocket = Nothing
 
            Return (intEnd - intStart)
        Catch oExcept As Exception
 
        End Try
 
    End Function
 
    Public Function GetLastError() As stcError
        Return udtError
    End Function
 
    Private Sub CreateChecksum(ByRef data() As Byte, ByVal Size As Integer, ByRef HiByte As Byte, ByRef LoByte As Byte)
        Dim i As Integer
        Dim chk As Integer = 0
 
        For i = 0 To Size - 1 Step 2
            chk += Convert.ToInt32(data(i) * &H100 + data(i + 1))
        Next
 
        chk = Convert.ToInt32((chk And &HFFFF&) + Fix(chk / &H10000&))
        chk += Convert.ToInt32(Fix(chk / &H10000&))
        chk = Not (chk)
 
        HiByte = Convert.ToByte((chk And &HFF00) / &H100)
        LoByte = Convert.ToByte(chk And &HFF)
    End Sub
 
End Class

And the following shows how to use it.

VB Code:

Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        MsgBox(PING_OR_DIE("igen1"))             'returns true
        MsgBox(PING_OR_DIE("192.167.33.93"))        'returns false
        MsgBox(PING_OR_DIE("igen3"))                     'returns false
    End Sub
    Public Function PING_OR_DIE(ByRef mIP As String) As Boolean
 
        Try
            Dim MyPing As clsPing
            MyPing = New clsPing()
            MyPing.Host = mIP
            Dim a As Long = MyPing.Ping()
            If MyPing.GetLastError.Number = 29184 Then
                MyPing = Nothing
                Return True
            Else
                MyPing = Nothing
                Return False
            End If
        Catch ex As Exception
        End Try
    End Function

BTW, If the returned Value is Not 29184, then it didn't connect.
29184 = Success!

:wave:
-Lou

http://www.vbforums.com/showthread.php?t=299004

Mendhak,
Is something wrong with the above code?
As far as I know, it works.

the thread you point to ends with:

Quote:

---

Originally Posted by jsun9

The code works identically to the other code on this forum?*** You can ping once, you get some erroneous number then you can't ping after that.

---

***referring to the code posted right at the beginning of that thread
Hmmm, the class you posted is the same, {ICMP is a different tweak, but near'nuff}

Yours works, doesn't it?

Yes, it works, but I've had some problems with it too. I think I had modified it to return a -1 if there was a request timed out. Did you try it?

Yours is more direct, being the first lines of code in the Ping() routine:

VB Code:

Public Function Ping() As Long
 
 
 
        If ipheHost Is Nothing Then
            Return -1
            Exit Function
 
        End If

I think Mine works similarly, as an else in the following:

VB Code:

If (intNBytes > 0) Then
                udtError.Number = (aReplyBuffer(19) * &H100) + aReplyBuffer(20)
                Select Case aReplyBuffer(20)
                    Case 0 : udtError.Description = "Success"
                    Case 1 : udtError.Description = "Buffer too Small"
                    Case 2 : udtError.Description = "Destination Unreahable"
                    [size=1][i]yada yada yada[/i][/size]
            Else
                'NotLKH added this:
                udtError.Number = -2
                udtError.Description = "NoReturnedData"
            End If

You might want to put the error value -1 into the udtError.Number before you return, along with a comment into the udtError.Description.

Your snippet though is good. I think I'll throw a slightly modified version of it into mine.

-Lou

Quote:

---

Originally Posted by mendhak

Yes, it works, but I've had some problems with it too.

---

I am not an expert in Net, but I noticed the following:

VB Code:

End If 
           sckSocket.Close 
 
           Return (intEnd - intStart) 
       Catch oExcept As Exception 
           ' 
       End Try 
 
   End Function

At the end of the ping routine at the website I found the above code at.

the class you posted had this at the end of the Ping routine:

VB Code:

End If
            Return (intEnd - intStart)
        Catch oExcept As Exception
            ' 
        End Try
    End Function

I don't know how important it is, but would the absence of the sckSocket.Close directive leave the socket open, thus potentially causeing problems later on?


BTW, I tweaked that area to the following:

VB Code:

End If
            sckSocket.Close()
            sckSocket = Nothing
 
            Return (intEnd - intStart)
        Catch oExcept As Exception
 
        End Try
 
    End Function

Just an automatic reaction when I saw the .Close().
Think setting the sckSocket to nothing is benificial in any way?

:afrog:

It's just some modified code, so I wasn't thorough with it ;)

But the answer to your question depends upon the socket class being used, if the GC comes along, ideally, it shouldn't pose much of a problem. However, what you did is good. Safe. Yes, we likes safe....

Darn!
Its buggy, alright.

If it can't ping something once, it seems determined to be unable to ping just about anything after that.

Unless you shut it down and restart it.

SOMETHING just isn't being completely disposed of!
:sick:

Hi all,

Nub here but,

I visited this webby http://www.developerfusion.co.uk/show/2857/2/ and found that it ping class is working.

not sure isit the sckSocket.close or sckSocket = nothing that is causing some of the bugs of unable to ping after the 1st ping.

I realize this is an old post but I'm using the OPs ping class and it works fine except when run against the local machine.

I have an app I've developed that will run Radia commands as per selected option and run those commands against either a single machine or a list loaded from a text file. Either case, it errors on and tosses the debug to this line:

Code:

---

            ' Send the packet.
            If (SOCKET_ERROR = _socket.SendTo(_packet.Serialize(), _packet.Size(), 0, _server)) Then
                Return PING_ERROR
            End If

---

Anyone able to help me over this one item? I'm not well enough versed in the ICMP or TCP methods and parameters so any insights would be great.

Is there any reason why you cant just use the Ping command that is part of the .NET framework? Its easier to use, requires about 200 less lines of code, and more reliable..

vb Code:

Dim pingsender As New Net.NetworkInformation.Ping
If pingsender.Send("HostnameHere").Status = Net.NetworkInformation.IPStatus.Success Then
     MessageBox.Show("Ping reply received")
End If

Here is what I use in my program:

vb Code:

Private Function IsDestinationReachable(ByVal hostnameOrAddress As String) As Boolean
        Dim reachable As Boolean = False
        Try
            reachable = My.Computer.Network.IsAvailable AndAlso _
                        My.Computer.Network.Ping(hostnameOrAddress, 10000)
        Catch pingException As System.Net.NetworkInformation.PingException
        Catch genericNetworkException As System.Net.NetworkInformation.NetworkInformationException
            ' Fail silently and return false
        End Try
        Return reachable
    End Function

http://stateofidleness.com/?p=89

Quote:

---

Originally Posted by chris128

vb Code:

Dim pingsender As New Net.NetworkInformation.Ping
If pingsender.Send("HostnameHere").Status = Net.NetworkInformation.IPStatus.Success Then
     MessageBox.Show("Ping reply received")
End If

---

I was searching for a very simple way to check my network availability when I stumbled upon this thread. This code snippet accomplished what I was trying to achieve perfectly. Thanks for posting this! :thumb:

My.Computer.Network.IsAvailable will do that for you all by itself

this is what i used

vb Code:

If My.Computer.Network.Ping(TextBox3.Text) Then
            Label5.Text = ("Ping was successful")
            Exit Sub
        Else
            Label5.Text = ("Ping failed")
            Exit Sub
        End If