runtime errors

One of my testers for my new game is saying that my game is giving them an error. They are getting run-time error:

-2147200966 (8004503a)
Method '~' of object '~' failed


What does that mean?

You have an object trying to do something that it is not capable of doing.

Ok, but why is it happening when one of my beta testers trys the game? The game works completely fine on both of my computers and I'm using windows 98se on 1 and windows xp on the other.

98 and XP are very different kernals. Did you create an installation package?

What are your programs references, etc.?

Both of my testers are using Windows 2000. I did create a install package using the Package & Deployment Wizard. I'm mainly using the basic form design tools that come up except for winsock and media player.

When you get the error what is it thatyour clicking or doing?
It may be related to media player?

Do you have the same versions on all systems?

The person that is getting is error is click on a button that checks for a win. Both of my testers should have the same version since I sent them both the game last night. What is the best way that you recommand to play sound files?

I could use another tester to try the game and see if they get any error messages. I know the game is not don't but what I'm haveing them test is done.

If you just need to play a sound you can use the PlaySound API.
Then perhaps you can get rid of Media Player. :thumb:

I forgot about that api. Thanks for reminding me. I'll try that. Do you think that that will get rid of that error message?

Not sure since it could be coming from almost anywhere.

Try addng some logging too. In your error handlers write out to a file the
values of your vars and the procedure the error occurred in. :thumb:

Could that error, -2147200966 (8004503a) Method '~' of object '~' failed, be caused by outdated dll files?

Ever thought about using DirectSound? Heres a tutorial on it:

http://216.5.163.53/DirectX4VB/Tutor...DA_SoundFx.asp

And here is my module engine on it:

VB Code:

Option Explicit
 
Public DirectX8 As New DirectX8
 
Public DirectSound As DirectSound8
 
'Right here is used to hold the sounds. Only holds 2 for now.
Public DirectSound_Buffer(1) As DirectSoundSecondaryBuffer8
 
Public DirectSound_Enum As DirectSoundEnum8
 
Public Sub DirectSound_Initialize()
 
    Dim DirectSound_Buffer_Description As DSBUFFERDESC    'describes our sound file
    
    Set DirectSound_Enum = DirectX8.GetDSEnum
    Set DirectSound = DirectX8.DirectSoundCreate(DirectSound_Enum.GetGuid(1))
    
    DirectSound.SetCooperativeLevel frmMain.hWnd, DSSCL_NORMAL
    DirectSound_Buffer_Description.lFlags = DSBCAPS_CTRLFREQUENCY Or DSBCAPS_CTRLPAN Or DSBCAPS_CTRLVOLUME
    
    Set DirectSound_Buffer(0) = DirectSound.CreateSoundBufferFromFile(App.Path & "\Sounds\laser.wav", DirectSound_Buffer_Description)
    Set DirectSound_Buffer(1) = DirectSound.CreateSoundBufferFromFile(App.Path & "\Sounds\water splashes.wav", DirectSound_Buffer_Description)
 
End Sub
 
Public Sub DirectSound_Play(Buffer As DirectSoundSecondaryBuffer8)
    
    Buffer.SetCurrentPosition 0
    Buffer.Play DSBPLAY_DEFAULT
 
End Sub
 
Public Sub DirectSound_Play_Once(Buffer As DirectSoundSecondaryBuffer8)
 
    Buffer.Play DSBPLAY_DEFAULT
 
End Sub
 
 
Public Sub DirectSound_Play_Loop(Buffer As DirectSoundSecondaryBuffer8)
 
    Buffer.Play DSBPLAY_LOOPING
 
End Sub
 
Public Sub DirectSound_Pause(Buffer As DirectSoundSecondaryBuffer8)
 
    Buffer.Stop
 
End Sub
 
Public Sub DirectSound_Stop(Buffer As DirectSoundSecondaryBuffer8)
 
    Buffer.SetCurrentPosition 0
    Buffer.Stop
 
End Sub
 
Public Sub DirectSound_Shutdown()
    
    Set DirectSound_Buffer(0) = Nothing
    Set DirectSound_Buffer(1) = Nothing
    Set DirectSound_Enum = Nothing
    Set DirectSound = Nothing
    Set DirectX8 = Nothing
    
End Sub

Then in your Form_Load() event just add this:

VB Code:

Private Sub Form_Load()
 
     DirectSound_Initialize
 
End Sub

and in something like a command button do this:

VB Code:

Private Sub Command1_Click()
 
     DirectSound_Play DirectSound_Buffer(0) 'Plays sound 1
 
End Sub
 
Private Sub Command2_Click()
 
     DirectSound_Play DirectSound_Buffer(1) 'Plays sound 2
 
End Sub

Don't forget to unload it from memory though

VB Code:

Private Sub Form_Unload(Cancel As Integer)
 
     DirectSound_Shutdown
 
End Sub

1 of my beta testers for my game is having problems with images. The game is crashing for some reason while trying to set an preset image. The user is running the game on Windows 2000.

Here is the code I'm using.

imgBall.Picture = Image3(3).Picture
imgPattern.Picture = imgPatterns(iIndex).Picture

They work fine for me on both of my computers and a few other beta tester computers. Is there something wrong with that code that is causing the game to crash on Win 2000 computers? Also why is it causing the game to crash?

Thanks