Change order of listbox

I want to be able to move an entry in a listbox up/down or to the top. I am supposed to have a button with two arrows pointing up to move the entry to the top/two arrows pointing down to move it down and one arrow pointing up to go up one, etc etc.

Is this possible? Thanks

Edit: Using VB 6 by the way :D

It is a matter of deleting the current item and then re-adding the item at its new position.

VB Code:

Private Sub MoveItem(Optional ByVal MoveItemToEnd As Boolean = True)
    Dim lngCurrentIndex As Long
    Dim lngNewIndex As Long
    Dim strItem As String
    
    lngCurrentIndex = List1.ListIndex
    
    If MoveItemToEnd Then
        lngNewIndex = lngCurrentIndex + 1
    Else
        lngNewIndex = lngCurrentIndex - 1
    End If
    
    'make sure item is not already at the beginning or end of list
    If lngNewIndex > -1 And lngNewIndex < List1.ListCount Then
        strItem = List1.List(lngCurrentIndex) 'save the contents to be readded
        
        List1.RemoveItem lngCurrentIndex
        List1.AddItem strItem, lngNewIndex
        
        List1.Selected(lngNewIndex) = True 'make sure the item is still selected
    End If
End Sub
 
Private Sub cmdMoveItem_Click(Index As Integer)
    If Index = 0 Then
        MoveItem
    Else
        MoveItem False
    End If
End Sub

Private Sub cmdFirst_Click()
Dim i As Integer
Dim t As String

i = List1.ListIndex
t = List1.Text
List1.RemoveItem (i)

To get to the first Item
List1.AddItem t, 0

To get to the last item
List1.AddItem t, List1.ListCount

To get to the previous item
List1.AddItem t, i - 1

To get to the next item
List1.AddItem t, i + 1

End Sub

Thanks for the reply, although I am a little fuzzy on it:

I have four buttons: Send item to the top, send item up 1 position, send item down 1 position, send item to bottom...Do I use your (brucevde) code for each button?

HEY I used D.patrick's code and it works fine...thanks guys

Thanks for letting us know that your question was answered, but the best way to do it is to Edit the first post and add the green checkmark.