GetOpenFileName problem (resolved)

Hey All,

I found this code (GetOpenFileName API) that Aaron Young wrote
for multi-selecting files.

click here

This code works great for selecting multiple files, but when I want
to select just one, I can't seem to figure out why it will not work.

Thanks for any help in advance,
Ron

BTW...I use VB5, and I found this nice Split function (I don't
remember, but Aaron might have written this too)...

Code:

---

Private Function Split2(ByVal sString As String, ByVal sSeparator As String) As Variant
    Dim sParts() As String
    Dim lParts As Long
    Dim lPos As Long
   
    lPos = InStr(sString, sSeparator)
    While lPos
        ReDim Preserve sParts(lParts)
        sParts(lParts) = Left(sString, lPos - 1)
        sString = Mid(sString, lPos + Len(sSeparator))
        lPos = InStr(sString, sSeparator)
        lParts = lParts + 1
    Wend
    If Len(sString) Then
        ReDim Preserve sParts(lParts)
        sParts(lParts) = sString
    End If
    Split2 = IIf(lParts, sParts, Array())
End Function

---

What is the problem? It works fine for me :ehh:

manavo11,

When I select one file only, and click the "open" button, it
will not add the file to the listbox. If I select several files, it
adds them perfectly.

Does it work for you if you select one file only?

This seems to work...

Dim OpenDialog As String

Code:

---

If lResult > 0 Then
        With tOPENFILENAME
            vFiles = Split2(Left(.lpstrFile, InStr(.lpstrFile, Chr(0) & Chr(0)) - 1), Chr(0))
        End With
        If UBound(vFiles) = 0 Then
            List1.AddItem vFiles(0)
        Else
            For lIndex = 1 To UBound(vFiles)
                List1.AddItem AddBS(vFiles(0)) & vFiles(lIndex)
            Next
            If List1.List(0) = "" Then
              OpenDialog = Trim$(tOPENFILENAME.lpstrFile)
              List1.AddItem OpenDialog
            End If
        End If
    End If

---

Would someone check to see if this works for them?

Thanks,
Ron

VB Code:

If UBound(vFiles) = 0 Then
            List1.AddItem vFiles(0)

This part of the code is supposed to run when only one file is selected...

manavo11,

That's kinda what I thought, but it doesn't work for me. The code
above is the only way I could get a single file to work.

Does it work for you if you select one file only?

Well, it runs correctly for me... And I couldn't get your version to work... Here is the project I have tested with. Maybe it'll work :ehh:

Well hell, I couldn't get yours to run because of the Split.
Apparently, you are using VB6, and do not have any problems
running the original code.

I use VB5, so I need to use the Split function I posted above.

I don't know what else it could be....do you?

I forgot that! Then it must be the Split2 function that is causing the problem... I'll look and get back to you ;)

That's the problem... When you put only one file, the array gets messed up! It returns an empty array and the UBound is -1. That's why it doesn't run :( But, with this split function, it works ;)

VB Code:

Private Function Split2(ByVal sString As String, ByVal sSeparator As String) As Variant
    Dim sParts() As String
    Dim lParts As Long
    Dim lPos As Long
    
    lPos = InStr(sString, sSeparator)
    If lPos <> 0 Then
        While lPos
            ReDim Preserve sParts(lParts)
            sParts(lParts) = Left(sString, lPos - 1)
            sString = Mid(sString, lPos + Len(sSeparator))
            lPos = InStr(sString, sSeparator)
            lParts = lParts + 1
        Wend
        If Len(sString) Then
            ReDim Preserve sParts(lParts)
            sParts(lParts) = sString
        End If
        Split2 = IIf(lParts, sParts, Array())
    Else
        ReDim sParts(0)
        sParts(0) = sString
        Split2 = sParts
    End If
End Function

Hey manavo11...

Works excellent! I never would have figured it out. I really
appreciate all your help. Have a good one! :bigyello:

Thanks again,
Ron

No problem ;)

Have fun :thumb:

Well when I went to sleep I thought of something... Check the bold line :

VB Code:

Private Function Split2(ByVal sString As String, ByVal sSeparator As String) As Variant
    Dim sParts() As String
    Dim lParts As Long
    Dim lPos As Long
    
    lPos = InStr(sString, sSeparator)
    While lPos
        ReDim Preserve sParts(lParts)
        sParts(lParts) = Left(sString, lPos - 1)
        sString = Mid(sString, lPos + Len(sSeparator))
        lPos = InStr(sString, sSeparator)
        lParts = lParts + 1
    Wend
    If Len(sString) Then
        ReDim Preserve sParts(lParts)
        sParts(lParts) = sString
        [b]lParts = lParts + 1[/b]
    End If
    Split2 = IIf(lParts, sParts, Array())
End Function

I think that it should work now without all the fancy changes I made before :)

Oh yeah.... it works great! I think I am beginning to understand
why it wouldn't work, and how you made it work. I always like
to learn new things. :bigyello:

Thanks again, and have a good one,
Ron

Quote:

---

Originally posted by rdcody
Oh yeah.... it works great! I think I am beginning to understand
why it wouldn't work, and how you made it work. I always like
to learn new things. :bigyello:

Thanks again, and have a good one,
Ron

---

:)