Datagrid cell coloring

I am trying to color individual cells on a datagrid. I am unsure whether you actually can or not but here is what i have. I have a datagrid that gets filled by a dataset upon form loading. I also search the cells one by one for the number 376 and I am trying to color those cells. I can get it to color rows but not a cell. If it cannot be done, or you know of another control that would allow for something like this, please let me know. Here is the code.

VB Code:

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        SqlDataAdapter1.Fill(DataSet11)
        Dim x As Integer
        Dim y As Integer
        Dim CellData As String
        x = 4
        y = 4
        While x < 7
            While y < 7
 
                CellData = DataGrid1.Item(x, y) & ""
 
                If CellData = "" Then
                    y = y + 1
                Else
                    If CellData = "376" Then
                        DataGrid1.BackgroundColor = System.Drawing.Color.Blue
                    End If
                    y = y + 1
                End If
 
            End While
            y = 4
            x = x + 1
        End While
 
    End Sub

Forget all that crap I wrote before. I figured it out. You have to overwrite the paint code for the datagrid. Took awhile and a couple of classes and some code, its all done. I also can move columns, rename, resize. Its rather cool. Thanks for all the posts. :)

I am getting private msgs for the code. Please do not msg me for the code. I will post it here. It is the form and 2 classes. This is a variation of a custom datagrid on msdn. If you do a search on msdn for custom datagrid you will find it. It has other options that are not of use to me.

VB Code:

Public Class Form1
    Inherits System.Windows.Forms.Form
   
    'variables for brush colors
    Private asqn As Brush
    Private bsqn As Brush
    Private fsqn As Brush
    Private gsqn As Brush
    Private ops As Brush
    Private spsqn As Brush
    Private other As Brush
    Private vor As Brush
    Private hitRow As Integer
    Private toolTip1 As System.Windows.Forms.ToolTip
 
#Region " Windows Form Designer generated code "
 
       Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Brush colors
        Me.asqn = Brushes.DeepPink
        Me.bsqn = Brushes.DarkOrange
        Me.fsqn = Brushes.DarkSeaGreen
        Me.gsqn = Brushes.Green
        Me.ops = Brushes.Pink
        Me.spsqn = Brushes.Brown
        Me.vor = Brushes.Red
        'fill datagrid
        Me.SqlDataAdapter1.Fill(Me.DataSet11)
        'create datagridstyle and set to sql table
        Dim tableStyle As New DataGridTableStyle
        tableStyle.MappingName = "VehJul"
 
        'create columns for datagrid using class
        Dim column As New FormattableTextBoxColumn
        column.MappingName = "AssetID"
        column.HeaderText = "ID"
        column.Width = 40
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
        column = New FormattableTextBoxColumn
        column.MappingName = "Asset"
        column.HeaderText = "Asset"
        column.Width = 130
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
 
        column = New FormattableTextBoxColumn
        column.MappingName = "Notes"
        column.HeaderText = "Notes"
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
 
        column = New FormattableTextBoxColumn
        column.MappingName = "1"
        column.HeaderText = "1"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
 
        column = New FormattableTextBoxColumn
        column.MappingName = "2"
        column.HeaderText = "2"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
 
        column = New FormattableTextBoxColumn
        column.MappingName = "3"
        column.HeaderText = "3"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
 
        column = New FormattableTextBoxColumn
        column.MappingName = "4"
        column.HeaderText = "4"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
        'column = New FormattableTextBoxColumn
        column.MappingName = "5"
        column.HeaderText = "5"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
        column = New FormattableTextBoxColumn
        column.MappingName = "6"
        column.HeaderText = "6"
        column.Width = 20
        AddHandler column.SetCellFormat, AddressOf FormatGridRow
        tableStyle.GridColumnStyles.Add(column)
 
        'Add to the datagrid
        Me.DataGrid1.TableStyles.Add(tableStyle)
    End Sub
 
#Region "columnstyle event handlers"
 
    
 
    Private Sub FormatGridRow(ByVal sender As Object, ByVal e As DataGridFormatCellEventArgs)
        ' Conditionally set properties in e depending upon e.Row and e.Col.
        Dim discontinued As Boolean = CBool(IIf(e.Column <> 0, Me.DataGrid1(e.Row, 0), e.CurrentCellValue)) 'TODO: For performance reasons this should be changed to nested IF statements
 
        Dim a As String
        a = e.CurrentCellValue
          If a = "A" Then e.BackBrush = asqn
        If a = "B" Then e.BackBrush = bsqn
        If a = "F" Then e.BackBrush = fsqn
        If a = "G" Then e.BackBrush = gsqn
        If a = "O" Then e.BackBrush = ops
        If a = "S" Then e.BackBrush = spsqn
        If a = "V" Then e.BackBrush = vor
        If a = "N" Then e.BackBrush = other
 
    End Sub
 
#End Region
 
 
#Region "Helper Methods"
    ' Forces a repaint of given row.
    Private Sub RefreshRow(ByVal row As Integer)
        Dim rect As Rectangle = Me.DataGrid1.GetCellBounds(row, 0)
        rect = New Rectangle(rect.Right, rect.Top, Me.DataGrid1.Width, rect.Height)
        Me.DataGrid1.Invalidate(rect)
    End Sub 'RefreshRow
 
    ' Look back up in the project path for file...
    Private Function GetPathTo(ByVal name As String) As String
        Dim i As Integer
        For i = 0 To 3
            If System.IO.File.Exists(name) Then
                Exit For
            End If
            name = "..\" + name
        Next i
        Return name
    End Function 'GetPathTo
 
#End Region
End Class

and add a class named datagridformatcelleventargs

VB Code:

Public Delegate Sub FormatCellEventHandler(ByVal sender As Object, ByVal e As DataGridFormatCellEventArgs)
 
Public Class DataGridFormatCellEventArgs
    Inherits EventArgs
 
    Public Sub New(ByVal row As Integer, ByVal col As Integer, ByVal cellValue As Object)
        rowNum = row
        colNum = col
        fontVal = Nothing
        backBrushVal = Nothing
        foreBrushVal = Nothing
        fontDisposeVal = False
        backBrushDisposeVal = False
        foreBrushDisposeVal = False
        useBaseClassDrawingVal = True
        currentCellValueVal = cellValue
    End Sub 'New
 
    ' Holds the column number of the cell being painted.
    Public Property Column() As Integer
        Get
            Return colNum
        End Get
        Set(ByVal Value As Integer)
            colNum = Value
        End Set
    End Property
 
    ' Holds the row number of the cell being painted.
    Public Property Row() As Integer
        Get
            Return rowNum
        End Get
        Set(ByVal Value As Integer)
            rowNum = Value
        End Set
    End Property
 
    ' Holds the font to be used to draw text in the cell.
    Public Property TextFont() As Font
        Get
            Return fontVal
        End Get
        Set(ByVal Value As Font)
            fontVal = Value
        End Set
    End Property
 
    ' Holds the brush used to paint the cell's background.
    Public Property BackBrush() As Brush
        Get
            Return backBrushVal
        End Get
        Set(ByVal Value As Brush)
            backBrushVal = Value
        End Set
    End Property
 
    ' Holds the brush used to paint the text in the cell.
    Public Property ForeBrush() As Brush
        Get
            Return foreBrushVal
        End Get
        Set(ByVal Value As Brush)
            foreBrushVal = Value
        End Set
    End Property
 
    ' Set to true if the Dispose method of the TextFont 
    '     should be called by the Paint override.
    Public Property TextFontDispose() As Boolean
        Get
            Return fontDisposeVal
        End Get
        Set(ByVal Value As Boolean)
            fontDisposeVal = Value
        End Set
    End Property
 
    ' Set to true if the Dispose method of the BackBrush 
    '     should be called by the Paint override.
    Public Property BackBrushDispose() As Boolean
        Get
            Return backBrushDisposeVal
        End Get
        Set(ByVal Value As Boolean)
            BackBrushDispose = Value
        End Set
    End Property
 
    ' Set to true if the Dispose method of the ForeBrush 
    '     should be called by the Paint override.
    Public Property ForeBrushDispose() As Boolean
        Get
            Return foreBrushDisposeVal
        End Get
        Set(ByVal Value As Boolean)
            ForeBrushDispose = Value
        End Set
    End Property
 
    ' Set to false if the MyBase.Paint method  
    '     should not be called in the Paint override.
    Public Property UseBaseClassDrawing() As Boolean
        Get
            Return useBaseClassDrawingVal
        End Get
        Set(ByVal Value As Boolean)
            useBaseClassDrawingVal = Value
        End Set
    End Property
 
    ' Holds the current cell value. 
    Public ReadOnly Property CurrentCellValue() As Object
        Get
            Return currentCellValueVal
        End Get
    End Property
 
    ' Private fields to hold the public properties.
    Private colNum As Integer
    Private rowNum As Integer
    Private fontVal As Font
    Private backBrushVal As Brush
    Private foreBrushVal As Brush
    Private fontDisposeVal As Boolean
    Private backBrushDisposeVal As Boolean
    Private foreBrushDisposeVal As Boolean
    Private useBaseClassDrawingVal As Boolean
    Private currentCellValueVal As Object
 
End Class

and add a class named formattabletextboxcolumn

VB Code:

Public Class FormattableTextBoxColumn
    Inherits DataGridTextBoxColumn
 
    Public Event SetCellFormat As FormatCellEventHandler
 
    'used to fire an event to retrieve formatting info
    'and then draw the cell with this formatting info
    Protected Overloads Overrides Sub Paint(ByVal g As System.Drawing.Graphics, ByVal bounds As System.Drawing.Rectangle, ByVal [source] As System.Windows.Forms.CurrencyManager, ByVal rowNum As Integer, ByVal backBrush As System.Drawing.Brush, ByVal foreBrush As System.Drawing.Brush, ByVal alignToRight As Boolean)
        Dim e As DataGridFormatCellEventArgs = Nothing
 
        'fire the formatting event
        Dim col As Integer = Me.DataGridTableStyle.GridColumnStyles.IndexOf(Me)
        e = New DataGridFormatCellEventArgs(rowNum, col, Me.GetColumnValueAtRow([source], rowNum))
        RaiseEvent SetCellFormat(Me, e)
 
        Dim callBaseClass As Boolean = True ' assume we will call the baseclass
 
        If Not (e.BackBrush Is Nothing) Then
            backBrush = e.BackBrush
        End If
        If Not (e.ForeBrush Is Nothing) Then
            foreBrush = e.ForeBrush
        End If
 
        'if TextFont set, then must call drawstring
        If Not (e.TextFont Is Nothing) Then
            g.FillRectangle(backBrush, bounds)
            Try
                Dim charWidth As Integer = Fix(Math.Ceiling(g.MeasureString("c", e.TextFont, 20, StringFormat.GenericTypographic).Width))
 
                Dim s As String = Me.GetColumnValueAtRow([source], rowNum).ToString()
                Dim maxChars As Integer = Math.Min(s.Length, bounds.Width / charWidth)
 
                Try
                    g.DrawString(s.Substring(0, maxChars), e.TextFont, foreBrush, bounds.X, bounds.Y + 2)
                Catch ex As Exception
                    Console.WriteLine(ex.Message.ToString())
                End Try
            Catch 'empty catch
            End Try
            callBaseClass = False
        End If
 
        If Not e.UseBaseClassDrawing Then
            callBaseClass = False
        End If
        If callBaseClass Then
            MyBase.Paint(g, bounds, [source], rowNum, backBrush, foreBrush, alignToRight)
        End If
        'clean up
        If Not (e Is Nothing) Then
            If e.BackBrushDispose Then
                e.BackBrush.Dispose()
            End If
            If e.ForeBrushDispose Then
                e.ForeBrush.Dispose()
            End If
            If e.TextFontDispose Then
                e.TextFont.Dispose()
            End If
        End If
    End Sub 'Paint    
End Class

hmmm... is there a way in print out an document from datagrid???

hmm.. i know it gotta use printpriviewdialog and printDocument...hmm but how to go about doing it?? :confused:

in your toolbox grab the printdocument control and drop it on your form. Add a button and place this code in the click event.

PrintDocument1.Print()